lib/VPIT/TestHelpers.pm

   1 package VPIT::TestHelpers;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Config ();
   7
   8 sub export_to_pkg {
   9  my ($subs, $pkg) = @_;
  10
  11  while (my ($name, $code) = each %$subs) {
  12   no strict 'refs';
  13   *{$pkg.'::'.$name} = $code;
  14  }
  15
  16  return 1;
  17 }
  18
  19 my %default_exports = (
  20  load_or_skip     => \&load_or_skip,
  21  load_or_skip_all => \&load_or_skip_all,
  22  run_perl         => \&run_perl,
  23  skip_all         => \&skip_all,
  24 );
  25
  26 my %features = ();
  27
  28 sub import {
  29  shift;
  30  my @opts = @_;
  31
  32  my %exports = %default_exports;
  33
  34  for (my $i = 0; $i <= $#opts; ++$i) {
  35   my $feature = $opts[$i];
  36   next unless defined $feature;
  37
  38   my $args;
  39   if ($i < $#opts and defined $opts[$i+1] and ref $opts[$i+1] eq 'ARRAY') {
  40    ++$i;
  41    $args = $opts[$i];
  42   } else {
  43    $args = [ ];
  44   }
  45
  46   my $handler = $features{$feature};
  47   die "Unknown feature '$feature'" unless defined $handler;
  48
  49   my %syms = $handler->(@$args);
  50
  51   $exports{$_} = $syms{$_} for sort keys %syms;
  52  }
  53
  54  export_to_pkg \%exports => scalar caller;
  55 }
  56
  57 my $test_sub = sub {
  58  my $sub = shift;
  59
  60  my $stash;
  61  if ($INC{'Test/Leaner.pm'}) {
  62   $stash = \%Test::Leaner::;
  63  } else {
  64   require Test::More;
  65   $stash = \%Test::More::;
  66  }
  67
  68  my $glob = $stash->{$sub};
  69  return $glob ? *$glob{CODE} : undef;
  70 };
  71
  72 sub skip { $test_sub->('skip')->(@_) }
  73
  74 sub skip_all { $test_sub->('plan')->(skip_all => $_[0]) }
  75
  76 sub diag {
  77  my $diag = $test_sub->('diag');
  78  $diag->($_) for @_;
  79 }
  80
  81 our $TODO;
  82 local $TODO;
  83
  84 sub load {
  85  my ($pkg, $ver, $imports) = @_;
  86
  87  my $spec = $ver && $ver !~ /^[0._]*$/ ? "$pkg $ver" : $pkg;
  88  my $err;
  89
  90  local $@;
  91  if (eval "use $spec (); 1") {
  92   $ver = do { no strict 'refs'; ${"${pkg}::VERSION"} };
  93   $ver = 'undef' unless defined $ver;
  94
  95   if ($imports) {
  96    my @imports = @$imports;
  97    my $caller  = (caller 1)[0];
  98    local $@;
  99    my $res = eval <<"IMPORTER";
 100 package
 101         $caller;
 102 BEGIN { \$pkg->import(\@imports) }
 103 1;
 104 IMPORTER
 105    $err = "Could not import '@imports' from $pkg $ver: $@" unless $res;
 106   }
 107  } else {
 108   (my $file = "$pkg.pm") =~ s{::}{/}g;
 109   delete $INC{$file};
 110   $err = "Could not load $spec";
 111  }
 112
 113  if ($err) {
 114   return wantarray ? (0, $err) : 0;
 115  } else {
 116   diag "Using $pkg $ver";
 117   return 1;
 118  }
 119 }
 120
 121 sub load_or_skip {
 122  my ($pkg, $ver, $imports, $tests) = @_;
 123
 124  die 'You must specify how many tests to skip' unless defined $tests;
 125
 126  my ($loaded, $err) = load($pkg, $ver, $imports);
 127  skip $err => $tests unless $loaded;
 128
 129  return $loaded;
 130 }
 131
 132 sub load_or_skip_all {
 133  my ($pkg, $ver, $imports) = @_;
 134
 135  my ($loaded, $err) = load($pkg, $ver, $imports);
 136  skip_all $err unless $loaded;
 137
 138  return $loaded;
 139 }
 140
 141 sub run_perl {
 142  my $code = shift;
 143
 144  my ($SystemRoot, $PATH) = @ENV{qw<SystemRoot PATH>};
 145  my $ld_name  = $Config::Config{ldlibpthname};
 146  my $ldlibpth = $ENV{$ld_name};
 147
 148  local %ENV;
 149  $ENV{$ld_name}   = $ldlibpth   if                      defined $ldlibpth;
 150  $ENV{SystemRoot} = $SystemRoot if $^O eq 'MSWin32' and defined $SystemRoot;
 151  $ENV{PATH}       = $PATH       if $^O eq 'cygwin'  and defined $PATH;
 152
 153  system { $^X } $^X, '-T', map("-I$_", @INC), '-e', $code;
 154 }
 155
 156 package VPIT::TestHelpers::Guard;
 157
 158 sub new {
 159  my ($class, $code) = @_;
 160
 161  bless { code => $code }, $class;
 162 }
 163
 164 sub DESTROY { $_[0]->{code}->() }
 165
 166 1;