lib/VPIT/TestHelpers.pm

   1 package VPIT::TestHelpers;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Config ();
   7
   8 =head1 NAME
   9
  10 VPIT::TestHelpers
  11
  12 =head1 SYNTAX
  13
  14     use VPIT::TestHelpers (
  15      feature1 => \@feature1_args,
  16      feature2 => \@feature2_args,
  17     );
  18
  19 =cut
  20
  21 sub export_to_pkg {
  22  my ($subs, $pkg) = @_;
  23
  24  while (my ($name, $code) = each %$subs) {
  25   no strict 'refs';
  26   *{$pkg.'::'.$name} = $code;
  27  }
  28
  29  return 1;
  30 }
  31
  32 sub sanitize_prefix {
  33  my $prefix = shift;
  34
  35  if (defined $prefix) {
  36   if (length $prefix and $prefix !~ /_$/) {
  37    $prefix .= '_';
  38   }
  39  } else {
  40   $prefix = '';
  41  }
  42
  43  return $prefix;
  44 }
  45
  46 my %default_exports = (
  47  load_or_skip     => \&load_or_skip,
  48  load_or_skip_all => \&load_or_skip_all,
  49  skip_all         => \&skip_all,
  50 );
  51
  52 my %features = (
  53  threads  => \&init_threads,
  54  usleep   => \&init_usleep,
  55  run_perl => \&init_run_perl,
  56  capture  => \&init_capture,
  57 );
  58
  59 sub import {
  60  shift;
  61  my @opts = @_;
  62
  63  my %exports = %default_exports;
  64
  65  for (my $i = 0; $i <= $#opts; ++$i) {
  66   my $feature = $opts[$i];
  67   next unless defined $feature;
  68
  69   my $args;
  70   if ($i < $#opts and defined $opts[$i+1] and ref $opts[$i+1] eq 'ARRAY') {
  71    ++$i;
  72    $args = $opts[$i];
  73   } else {
  74    $args = [ ];
  75   }
  76
  77   my $handler = $features{$feature};
  78   die "Unknown feature '$feature'" unless defined $handler;
  79
  80   my %syms = $handler->(@$args);
  81
  82   $exports{$_} = $syms{$_} for sort keys %syms;
  83  }
  84
  85  export_to_pkg \%exports => scalar caller;
  86 }
  87
  88 my $test_sub = sub {
  89  my $sub = shift;
  90
  91  my $stash;
  92  if ($INC{'Test/Leaner.pm'}) {
  93   $stash = \%Test::Leaner::;
  94  } else {
  95   require Test::More;
  96   $stash = \%Test::More::;
  97  }
  98
  99  my $glob = $stash->{$sub};
 100  return $glob ? *$glob{CODE} : undef;
 101 };
 102
 103 sub skip { $test_sub->('skip')->(@_) }
 104
 105 sub skip_all { $test_sub->('plan')->(skip_all => $_[0]) }
 106
 107 sub diag {
 108  my $diag = $test_sub->('diag');
 109  $diag->($_) for @_;
 110 }
 111
 112 our $TODO;
 113 local $TODO;
 114
 115 sub load {
 116  my ($pkg, $ver, $imports) = @_;
 117
 118  my $spec = $ver && $ver !~ /^[0._]*$/ ? "$pkg $ver" : $pkg;
 119  my $err;
 120
 121  local $@;
 122  if (eval "use $spec (); 1") {
 123   $ver = do { no strict 'refs'; ${"${pkg}::VERSION"} };
 124   $ver = 'undef' unless defined $ver;
 125
 126   if ($imports) {
 127    my @imports = @$imports;
 128    my $caller  = (caller 1)[0];
 129    local $@;
 130    my $res = eval <<"IMPORTER";
 131 package
 132         $caller;
 133 BEGIN { \$pkg->import(\@imports) }
 134 1;
 135 IMPORTER
 136    $err = "Could not import '@imports' from $pkg $ver: $@" unless $res;
 137   }
 138  } else {
 139   (my $file = "$pkg.pm") =~ s{::}{/}g;
 140   delete $INC{$file};
 141   $err = "Could not load $spec";
 142  }
 143
 144  if ($err) {
 145   return wantarray ? (0, $err) : 0;
 146  } else {
 147   diag "Using $pkg $ver";
 148   return 1;
 149  }
 150 }
 151
 152 sub load_or_skip {
 153  my ($pkg, $ver, $imports, $tests) = @_;
 154
 155  die 'You must specify how many tests to skip' unless defined $tests;
 156
 157  my ($loaded, $err) = load($pkg, $ver, $imports);
 158  skip $err => $tests unless $loaded;
 159
 160  return $loaded;
 161 }
 162
 163 sub load_or_skip_all {
 164  my ($pkg, $ver, $imports) = @_;
 165
 166  my ($loaded, $err) = load($pkg, $ver, $imports);
 167  skip_all $err unless $loaded;
 168
 169  return $loaded;
 170 }
 171
 172 =head1 FEATURES
 173
 174 =head2 C<run_perl>
 175
 176 =over 4
 177
 178 =item *
 179
 180 Import :
 181
 182     use VPIT::TestHelpers run_perl => [ $p ]
 183
 184 where :
 185
 186 =over 8
 187
 188 =item -
 189
 190 C<$p> is prefixed to the constants exported by this feature (defaults to C<''>).
 191
 192 =back
 193
 194 =item *
 195
 196 Dependencies : none
 197
 198 =item *
 199
 200 Exports :
 201
 202 =over 8
 203
 204 =item -
 205
 206 C<run_perl $code>
 207
 208 =item -
 209
 210 C<RUN_PERL_FAILED> (possibly prefixed by C<$p>)
 211
 212 =back
 213
 214 =back
 215
 216 =cut
 217
 218 sub fresh_perl_env (&) {
 219  my $handler = shift;
 220
 221  my ($SystemRoot, $PATH) = @ENV{qw<SystemRoot PATH>};
 222  my $ld_name  = $Config::Config{ldlibpthname};
 223  my $ldlibpth = $ENV{$ld_name};
 224
 225  local %ENV;
 226  $ENV{$ld_name}   = $ldlibpth   if                      defined $ldlibpth;
 227  $ENV{SystemRoot} = $SystemRoot if $^O eq 'MSWin32' and defined $SystemRoot;
 228  $ENV{PATH}       = $PATH       if $^O eq 'cygwin'  and defined $PATH;
 229
 230  my $perl = $^X;
 231  unless (-e $perl and -x $perl) {
 232   $perl = $Config::Config{perlpath};
 233   unless (-e $perl and -x $perl) {
 234    return undef;
 235   }
 236  }
 237
 238  return $handler->($perl, '-T', map("-I$_", @INC));
 239 }
 240
 241 sub init_run_perl {
 242  my $p = sanitize_prefix(shift);
 243
 244  return (
 245   run_perl              => \&run_perl,
 246   "${p}RUN_PERL_FAILED" => sub () { 'Could not execute perl subprocess' },
 247  );
 248 }
 249
 250 sub run_perl {
 251  my $code = shift;
 252
 253  if ($code =~ /"/) {
 254   die 'Double quotes in evaluated code are not portable';
 255  }
 256
 257  fresh_perl_env {
 258   my ($perl, @perl_args) = @_;
 259   system { $perl } $perl, @perl_args, '-e', $code;
 260  };
 261 }
 262
 263 =head2 C<capture>
 264
 265 =over 4
 266
 267 =item *
 268
 269 Import :
 270
 271     use VPIT::TestHelpers 'capture'
 272
 273 =item *
 274
 275 Dependencies :
 276
 277 =over 8
 278
 279 =item -
 280
 281 Not VMS
 282
 283 =item -
 284
 285 L<IO::Handle>, L<IO::Select>, L<IPC::Open3>
 286
 287 =item -
 288
 289 On MSWin32 : L<Socket>
 290
 291 =back
 292
 293 =item *
 294
 295 Exports :
 296
 297 =over 8
 298
 299 =item -
 300
 301 C<capture @command>
 302
 303 =item -
 304
 305 C<capture_perl $code>
 306
 307 =back
 308
 309 =back
 310
 311 =cut
 312
 313 sub init_capture {
 314  skip_all 'Cannot capture output on VMS' if $^O eq 'VMS';
 315
 316  load_or_skip_all 'IO::Handle', '0', [ ];
 317  load_or_skip_all 'IO::Select', '0', [ ];
 318  load_or_skip_all 'IPC::Open3', '0', [ ];
 319  if ($^O eq 'MSWin32') {
 320   load_or_skip_all 'Socket', '0', [ ];
 321  }
 322
 323  return (
 324   capture      => \&capture,
 325   capture_perl => \&capture_perl,
 326  );
 327 }
 328
 329 # Inspired from IPC::Cmd
 330
 331 sub capture {
 332  my @cmd = @_;
 333
 334  my $want = wantarray;
 335
 336  my $fail = sub {
 337   my $err     = $!;
 338   my $ext_err = $^O eq 'MSWin32' ? $^E : undef;
 339
 340   my $syscall = shift;
 341   my $args    = join ', ', @_;
 342
 343   my $msg = "$syscall($args) failed: ";
 344
 345   if (defined $err) {
 346    no warnings 'numeric';
 347    my ($err_code, $err_str) = (int $err, "$err");
 348    $msg .= "$err_str ($err_code)";
 349   }
 350
 351   if (defined $ext_err) {
 352    no warnings 'numeric';
 353    my ($ext_err_code, $ext_err_str) = (int $ext_err, "$ext_err");
 354    $msg .= ", $ext_err_str ($ext_err_code)";
 355   }
 356
 357   die "$msg\n";
 358  };
 359
 360  my ($status, $content_out, $content_err);
 361
 362  local $@;
 363  my $ok = eval {
 364   my ($pid, $out, $err);
 365
 366   if ($^O eq 'MSWin32') {
 367    my $pipe = sub {
 368     socketpair $_[0], $_[1],
 369                &Socket::AF_UNIX, &Socket::SOCK_STREAM, &Socket::PF_UNSPEC
 370                       or $fail->(qw<socketpair reader writer>);
 371     shutdown $_[0], 1 or $fail->(qw<shutdown reader>);
 372     shutdown $_[1], 0 or $fail->(qw<shutdown writer>);
 373     return 1;
 374    };
 375    local (*IN_R,  *IN_W);
 376    local (*OUT_R, *OUT_W);
 377    local (*ERR_R, *ERR_W);
 378    $pipe->(*IN_R,  *IN_W);
 379    $pipe->(*OUT_R, *OUT_W);
 380    $pipe->(*ERR_R, *ERR_W);
 381
 382    $pid = IPC::Open3::open3('>&IN_R', '<&OUT_W', '<&ERR_W', @cmd);
 383
 384    close *IN_W or $fail->(qw<close input>);
 385    $out = *OUT_R;
 386    $err = *ERR_R;
 387   } else {
 388    my $in = IO::Handle->new;
 389    $out   = IO::Handle->new;
 390    $out->autoflush(1);
 391    $err   = IO::Handle->new;
 392    $err->autoflush(1);
 393
 394    $pid = IPC::Open3::open3($in, $out, $err, @cmd);
 395
 396    close $in;
 397   }
 398
 399   # Forward signals to the child (except SIGKILL)
 400   my %sig_handlers;
 401   foreach my $s (keys %SIG) {
 402    $sig_handlers{$s} = sub {
 403     kill "$s" => $pid;
 404     $SIG{$s} = $sig_handlers{$s};
 405    };
 406   }
 407   local $SIG{$_} = $sig_handlers{$_} for keys %SIG;
 408
 409   unless ($want) {
 410    close $out or $fail->(qw<close output>);
 411    close $err or $fail->(qw<close error>);
 412    waitpid $pid, 0;
 413    $status = $?;
 414    return 1;
 415   }
 416
 417   my $sel = IO::Select->new();
 418   $sel->add($out, $err);
 419
 420   my $fd_out = fileno $out;
 421   my $fd_err = fileno $err;
 422
 423   my %contents;
 424   $contents{$fd_out} = '';
 425   $contents{$fd_err} = '';
 426
 427   while (my @ready = $sel->can_read) {
 428    for my $fh (@ready) {
 429     my $buf;
 430     my $bytes_read = sysread $fh, $buf, 4096;
 431     if (not defined $bytes_read) {
 432      $fail->('sysread', 'fd(' . fileno($fh) . ')');
 433     } elsif ($bytes_read) {
 434      $contents{fileno($fh)} .= $buf;
 435     } else {
 436      $sel->remove($fh);
 437      close $fh or $fail->('close', 'fd(' . fileno($fh) . ')');
 438      last unless $sel->count;
 439     }
 440    }
 441   }
 442
 443   waitpid $pid, 0;
 444   $status = $?;
 445
 446   if ($^O eq 'MSWin32') {
 447    # Manual CRLF translation that couldn't be done with sysread.
 448    s/\x0D\x0A/\n/g for values %contents;
 449   }
 450
 451   $content_out = $contents{$fd_out};
 452   $content_err = $contents{$fd_err};
 453
 454   1;
 455  };
 456
 457  if ($ok) {
 458   return ($status, $content_out, $content_err);
 459  } else {
 460   my $err = $@;
 461   chomp $err;
 462   return (undef, $err);
 463  }
 464 }
 465
 466 sub capture_perl {
 467  my $code = shift;
 468
 469  if ($code =~ /"/) {
 470   die 'Double quotes in evaluated code are not portable';
 471  }
 472
 473  fresh_perl_env {
 474   my @perl = @_;
 475   capture @perl, '-e', $code;
 476  };
 477 }
 478
 479 =head2 C<threads>
 480
 481 =over 4
 482
 483 =item *
 484
 485 Import :
 486
 487     use VPIT::TestHelpers threads => [
 488      $pkg, $is_threadsafe, $force_var
 489     ];
 490
 491 where :
 492
 493 =over 8
 494
 495 =item -
 496
 497 C<$pkg> is the target package name to be used in error messages (defaults to C<'package'>) ;
 498
 499 =item -
 500
 501 C<$is_threadsafe> is a boolean telling whether the target module is thread-safe (not tested if C<undef>) ;
 502
 503 =item -
 504
 505 C<$force_var> is the name of the environment variable that can be used to force the thread tests (defaults to C<PERL_FORCE_TEST_THREADS>).
 506
 507 =back
 508
 509 =item *
 510
 511 Dependencies :
 512
 513 =over 8
 514
 515 =item -
 516
 517 C<perl> 5.13.4
 518
 519 =item -
 520
 521 L<threads> 1.67
 522
 523 =item -
 524
 525 L<threads::shared> 1.14
 526
 527 =item -
 528
 529 L<Test::Leaner>
 530
 531 =back
 532
 533 =item *
 534
 535 Exports :
 536
 537 =over 8
 538
 539 =item -
 540
 541 C<spawn $coderef>
 542
 543 =back
 544
 545 =back
 546
 547 =cut
 548
 549 sub init_threads {
 550  my ($pkg, $threadsafe, $force_var) = @_;
 551
 552  skip_all 'This perl wasn\'t built to support threads'
 553                                             unless $Config::Config{useithreads};
 554
 555  $pkg = 'package' unless defined $pkg;
 556  skip_all "This $pkg isn't thread safe" if defined $threadsafe and !$threadsafe;
 557
 558  $force_var = 'PERL_FORCE_TEST_THREADS' unless defined $force_var;
 559  my $force  = $ENV{$force_var} ? 1 : !1;
 560  skip_all 'perl 5.13.4 required to test thread safety'
 561                                              unless $force or "$]" >= 5.013_004;
 562
 563  if (($INC{'Test/More.pm'} || $INC{'Test/Leaner.pm'}) && !$INC{'threads.pm'}) {
 564   die 'Test::More/Test::Leaner was loaded too soon';
 565  }
 566
 567  load_or_skip_all 'threads',         $force ? '0' : '1.67', [ ];
 568  load_or_skip_all 'threads::shared', $force ? '0' : '1.14', [ ];
 569
 570  require Test::Leaner;
 571
 572  diag "Threads testing forced by \$ENV{$force_var}" if $force;
 573
 574  return spawn => \&spawn;
 575 }
 576
 577 sub spawn {
 578  local $@;
 579  my @diag;
 580  my $thread = eval {
 581   local $SIG{__WARN__} = sub { push @diag, "Thread creation warning: @_" };
 582   threads->create(@_);
 583  };
 584  push @diag, "Thread creation error: $@" if $@;
 585  diag @diag;
 586  return $thread ? $thread : ();
 587 }
 588
 589 =head2 C<usleep>
 590
 591 =over 4
 592
 593 =item *
 594
 595 Import :
 596
 597     use VPIT::TestHelpers 'usleep'
 598
 599 =item *
 600
 601 Dependencies : none
 602
 603 =item *
 604
 605 Exports :
 606
 607 =over 8
 608
 609 =item -
 610
 611 C<usleep $microseconds>
 612
 613 =back
 614
 615 =back
 616
 617 =cut
 618
 619 sub init_usleep {
 620  my $usleep;
 621
 622  if (do { local $@; eval { require Time::HiRes; 1 } }) {
 623   defined and diag "Using usleep() from Time::HiRes $_"
 624                                                       for $Time::HiRes::VERSION;
 625   $usleep = \&Time::HiRes::usleep;
 626  } else {
 627   diag 'Using fallback usleep()';
 628   $usleep = sub {
 629    my $s = int($_[0] / 1e6);
 630    sleep $s if $s;
 631   };
 632  }
 633
 634  return usleep => $usleep;
 635 }
 636
 637 =head1 CLASSES
 638
 639 =head2 C<VPIT::TestHelpers::Guard>
 640
 641 Syntax :
 642
 643     {
 644      my $guard = VPIT::TestHelpers::Guard->new($coderef);
 645      ...
 646     } # $codref called here
 647
 648 =cut
 649
 650 package VPIT::TestHelpers::Guard;
 651
 652 sub new {
 653  my ($class, $code) = @_;
 654
 655  bless { code => $code }, $class;
 656 }
 657
 658 sub DESTROY { $_[0]->{code}->() }
 659
 660 =head1 AUTHOR
 661
 662 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 663
 664 =head1 COPYRIGHT & LICENSE
 665
 666 Copyright 2012,2013,2014,2015 Vincent Pit, all rights reserved.
 667
 668 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 669
 670 =cut
 671
 672 1;