lib/subs/auto.pm

   1 package subs::auto;
   2
   3 use 5.010;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp qw/croak/;
   9 use Symbol qw/gensym/;
  10
  11 use Variable::Magic qw/wizard cast dispell getdata/;
  12
  13 =head1 NAME
  14
  15 subs::auto - Read barewords as subroutine names.
  16
  17 =head1 VERSION
  18
  19 Version 0.02
  20
  21 =cut
  22
  23 our $VERSION = '0.02';
  24
  25 =head1 SYNOPSIS
  26
  27     {
  28      use subs::auto;
  29      foo;             # Compile to "foo()"     instead of "'foo'"
  30                       #                        or croaking on strict subs
  31      foo $x;          # Compile to "foo($x)"   instead of "$x->foo"
  32      foo 1;           # Compile to "foo(1)"    instead of croaking
  33      foo 1, 2;        # Compile to "foo(1, 2)" instead of croaking
  34      foo(@a);         # Still ok
  35      foo->meth;       # "'foo'->meth" if you have use'd foo somewhere,
  36                       #  or "foo()->meth" otherwise
  37      print foo 'wut'; # print to the filehandle foo if it's actually one,
  38                       #  or "foo()->print('wut')" otherwise
  39     } # ... but function calls will fail at run-time if you don't
  40       # actually define foo somewhere
  41
  42     foo; # BANG
  43
  44 =head1 DESCRIPTION
  45
  46 This pragma lexically enables the parsing of any bareword as a subroutine name, except those which corresponds to an entry in C<%INC> (expected to be class names) or whose symbol table entry has a IO slot (expected to be filehandles).
  47
  48 You can pass options to C<import> as key / value pairs :
  49
  50 =over 4
  51
  52 =item *
  53
  54 C<< in => $pkg >>
  55
  56 Specifies on which package the pragma should act. Setting C<$pkg> to C<Some::Package> allows you to resolve all functions name of the type C<Some::Package::func ...> in the current scope. You can use the pragma several times with different package names to allow resolution of all the corresponding barewords. Defaults to the current package.
  57
  58 =back
  59
  60 =cut
  61
  62 BEGIN {
  63  croak 'uvar magic not available' unless Variable::Magic::VMG_UVAR;
  64 }
  65
  66 my @core = qw/abs accept alarm atan2 bind binmode bless break caller chdir
  67               chmod chomp chop chown chr chroot close closedir connect
  68               continue cos crypt dbmclose dbmopen default defined delete die
  69               do dump each endgrent endhostent endnetent endprotoent endpwent
  70               endservent eof eval exec exists exit exp fcntl fileno flock fork
  71               format formline getc getgrent getgrgid getgrnam gethostbyaddr
  72               gethostbyname gethostent getlogin getnetbyaddr getnetbyname
  73               getnetent getpeername getpgrp getppid getpriority getprotobyname
  74               getprotobynumber getprotoent getpwent getpwnam getpwuid
  75               getservbyname getservbyport getservent getsockname getsockopt
  76               given glob gmtime goto grep hex index int ioctl join keys kill
  77               last lc lcfirst length link listen local localtime lock log
  78               lstat map mkdir msgctl msgget msgrcv msgsnd my next no oct open
  79               opendir ord our pack package pipe pop pos print printf prototype
  80               push quotemeta rand read readdir readline readlink readpipe recv
  81               redo ref rename require reset return reverse rewinddir rindex
  82               rmdir say scalar seek seekdir select semctl semget semop send
  83               setgrent sethostent setnetent setpgrp setpriority setprotoent
  84               setpwent setservent setsockopt shift shmctl shmget shmread
  85               shmwrite shutdown sin sleep socket socketpair sort splice split
  86               sprintf sqrt srand stat state study sub substr symlink syscall
  87               sysopen sysread sysseek system syswrite tell telldir tie tied
  88               time times truncate uc ucfirst umask undef unlink unpack unshift
  89               untie use utime values vec wait waitpid wantarray warn when
  90               write/;
  91 push @core,qw/not __LINE__ __FILE__ DATA/;
  92
  93 my %core;
  94 @core{@core} = ();
  95 delete @core{qw/my local/};
  96 undef @core;
  97
  98 my $tag = wizard data => sub { 1 };
  99
 100 sub _reset {
 101  my ($pkg, $func) = @_;
 102  my $fqn = join '::', @_;
 103  my $cb = do {
 104   no strict 'refs';
 105   no warnings 'once';
 106   *$fqn{CODE};
 107  };
 108  if ($cb and getdata(&$cb, $tag)) {
 109   no strict 'refs';
 110   my $sym = gensym;
 111   for (qw/SCALAR ARRAY HASH IO FORMAT/) {
 112    no warnings 'once';
 113    *$sym = *$fqn{$_} if defined *$fqn{$_}
 114   }
 115   undef *$fqn;
 116   *$fqn = *$sym;
 117  }
 118 }
 119
 120 sub _fetch {
 121  (undef, my $data, my $func) = @_;
 122  return if $data->{guard} or $func =~ /::/ or exists $core{$func};
 123  $data->{guard} = 1;
 124  my $hints = (caller 0)[10];
 125  if ($hints and $hints->{subs__auto}) {
 126   my $mod = $func . '.pm';
 127   if (not exists $INC{$mod}) {
 128    my $fqn = $data->{pkg} . '::' . $func;
 129    if (do { no strict 'refs'; not *$fqn{CODE} || *$fqn{IO}}) {
 130     my $cb = sub {
 131      my ($file, $line) = (caller 0)[1, 2];
 132      ($file, $line) = ('(eval 0)', 0) unless $file && $line;
 133      die "Undefined subroutine &$fqn called at $file line $line\n";
 134     };
 135     cast &$cb, $tag;
 136     no strict 'refs';
 137     *$fqn = $cb;
 138    }
 139   }
 140  } else {
 141   _reset($data->{pkg}, $func);
 142  }
 143  $data->{guard} = 0;
 144  return;
 145 }
 146
 147 sub _store {
 148  (undef, my $data, my $func) = @_;
 149  return if $data->{guard};
 150  $data->{guard} = 1;
 151  _reset($data->{pkg}, $func);
 152  $data->{guard} = 0;
 153  return;
 154 }
 155
 156 my $wiz = wizard data  => sub { +{ pkg => $_[1] } },
 157                  fetch => \&_fetch,
 158                  store => \&_store;
 159
 160 my %pkgs;
 161
 162 sub _validate_pkg {
 163  my ($pkg, $cur) = @_;
 164  return $cur unless $pkg;
 165  croak 'Invalid package name' if ref $pkg
 166                               or $pkg =~ /(?:-|[^\w:])/
 167                               or $pkg =~ /(?:\A\d|\b:(?::\d|(?:::+)?\b))/;
 168  $pkg =~ s/::$//;
 169  $pkg = $cur . $pkg if $pkg eq '' or $pkg =~ /^::/;
 170  $pkg;
 171 }
 172
 173 sub import {
 174  shift;
 175  croak 'Optional arguments must be passed as keys/values pairs' if @_ % 2;
 176  my %args = @_;
 177  my $cur  = (caller 1)[0];
 178  my $in   = _validate_pkg $args{in}, $cur;
 179  $^H{subs__auto} = 1;
 180  ++$pkgs{$in};
 181  no strict 'refs';
 182  cast %{$in . '::'}, $wiz, $in;
 183 }
 184
 185 sub unimport {
 186  $^H{subs__auto} = 0;
 187 }
 188
 189 {
 190  no warnings 'void';
 191  CHECK {
 192   no strict 'refs';
 193   dispell %{$_ . '::'}, $wiz for keys %pkgs;
 194  }
 195 }
 196
 197 =head1 EXPORT
 198
 199 None.
 200
 201 =head1 CAVEATS
 202
 203 C<*{'::foo'}{CODE}> will appear as defined in a scope where the pragma is enabled, C<foo> is used as a bareword, but is never actually defined afterwards. This may or may not be considered as Doing The Right Thing. However, C<*{'::foo'}{CODE}> will always return the right value if you fetch it outside the pragma's scope. Actually, you can make it return the right value even in the pragma's scope by reading C<*{'::foo'}{CODE}> outside (or by actually defining C<foo>, which is ultimately why you use this pragma, right ?).
 204
 205 You have to open global filehandles outside of the scope of this pragma if you want them not to be treated as function calls. Or just use lexical filehandles and default ones as you should be.
 206
 207 =head1 DEPENDENCIES
 208
 209 L<perl> 5.10.0.
 210
 211 L<Carp> (standard since perl 5), L<Symbol> (since 5.002).
 212
 213 L<Variable::Magic> with C<uvar> magic enabled (this should be assured by the required perl version).
 214
 215 =head1 AUTHOR
 216
 217 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 218
 219 You can contact me by mail or on #perl @ FreeNode (vincent or Prof_Vince).
 220
 221 =head1 BUGS
 222
 223 Please report any bugs or feature requests to C<bug-subs-auto at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=subs-auto>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 224
 225 =head1 SUPPORT
 226
 227 You can find documentation for this module with the perldoc command.
 228
 229     perldoc subs::auto
 230
 231 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/subs-auto>.
 232
 233 =head1 ACKNOWLEDGEMENTS
 234
 235 Thanks to Sebastien Aperghis-Tramoni for helping to name this pragma.
 236
 237 =head1 COPYRIGHT & LICENSE
 238
 239 Copyright 2008 Vincent Pit, all rights reserved.
 240
 241 This program is free software; you can redistribute it and/or modify it
 242 under the same terms as Perl itself.
 243
 244 =cut
 245
 246 1; # End of subs::auto