lib/subs/auto.pm

   1 package subs::auto;
   2
   3 use 5.010;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp qw/croak/;
   9 use Symbol qw/gensym/;
  10
  11 use Variable::Magic qw/wizard cast dispell getdata/;
  12
  13 =head1 NAME
  14
  15 subs::auto - Read barewords as subroutine names.
  16
  17 =head1 VERSION
  18
  19 Version 0.04
  20
  21 =cut
  22
  23 our $VERSION = '0.04';
  24
  25 =head1 SYNOPSIS
  26
  27     {
  28      use subs::auto;
  29      foo;             # Compile to "foo()"     instead of "'foo'"
  30                       #                        or croaking on strict subs
  31      foo $x;          # Compile to "foo($x)"   instead of "$x->foo"
  32      foo 1;           # Compile to "foo(1)"    instead of croaking
  33      foo 1, 2;        # Compile to "foo(1, 2)" instead of croaking
  34      foo(@a);         # Still ok
  35      foo->meth;       # "'foo'->meth" if you have use'd foo somewhere,
  36                       #  or "foo()->meth" otherwise
  37      print foo 'wut'; # print to the filehandle foo if it's actually one,
  38                       #  or "print(foo('wut'))" otherwise
  39     } # ... but function calls will fail at run-time if you don't
  40       # actually define foo somewhere
  41
  42     foo; # BANG
  43
  44 =head1 DESCRIPTION
  45
  46 This pragma lexically enables the parsing of any bareword as a subroutine name, except those which corresponds to an entry in C<%INC> (expected to be class names) or whose symbol table entry has a IO slot (expected to be filehandles).
  47
  48 You can pass options to C<import> as key / value pairs :
  49
  50 =over 4
  51
  52 =item *
  53
  54 C<< in => $pkg >>
  55
  56 Specifies on which package the pragma should act. Setting C<$pkg> to C<Some::Package> allows you to resolve all functions name of the type C<Some::Package::func ...> in the current scope. You can use the pragma several times with different package names to allow resolution of all the corresponding barewords. Defaults to the current package.
  57
  58 =back
  59
  60 This module is B<not> a source filter.
  61
  62 =cut
  63
  64 BEGIN {
  65  croak 'uvar magic not available' unless Variable::Magic::VMG_UVAR;
  66 }
  67
  68 my @core = qw/abs accept alarm atan2 bind binmode bless break caller chdir
  69               chmod chomp chop chown chr chroot close closedir connect
  70               continue cos crypt dbmclose dbmopen default defined delete die
  71               do dump each endgrent endhostent endnetent endprotoent endpwent
  72               endservent eof eval exec exists exit exp fcntl fileno flock fork
  73               format formline getc getgrent getgrgid getgrnam gethostbyaddr
  74               gethostbyname gethostent getlogin getnetbyaddr getnetbyname
  75               getnetent getpeername getpgrp getppid getpriority getprotobyname
  76               getprotobynumber getprotoent getpwent getpwnam getpwuid
  77               getservbyname getservbyport getservent getsockname getsockopt
  78               given glob gmtime goto grep hex index int ioctl join keys kill
  79               last lc lcfirst length link listen local localtime lock log
  80               lstat map mkdir msgctl msgget msgrcv msgsnd my next no oct open
  81               opendir ord our pack package pipe pop pos print printf prototype
  82               push quotemeta rand read readdir readline readlink readpipe recv
  83               redo ref rename require reset return reverse rewinddir rindex
  84               rmdir say scalar seek seekdir select semctl semget semop send
  85               setgrent sethostent setnetent setpgrp setpriority setprotoent
  86               setpwent setservent setsockopt shift shmctl shmget shmread
  87               shmwrite shutdown sin sleep socket socketpair sort splice split
  88               sprintf sqrt srand stat state study sub substr symlink syscall
  89               sysopen sysread sysseek system syswrite tell telldir tie tied
  90               time times truncate uc ucfirst umask undef unlink unpack unshift
  91               untie use utime values vec wait waitpid wantarray warn when
  92               write/;
  93 push @core,qw/not __LINE__ __FILE__ DATA/;
  94
  95 my %core;
  96 @core{@core} = ();
  97 delete @core{qw/my local/};
  98 undef @core;
  99
 100 my $tag = wizard data => sub { 1 };
 101
 102 sub _reset {
 103  my ($pkg, $func) = @_;
 104  my $fqn = join '::', @_;
 105  my $cb = do {
 106   no strict 'refs';
 107   no warnings 'once';
 108   *$fqn{CODE};
 109  };
 110  if ($cb and getdata(&$cb, $tag)) {
 111   no strict 'refs';
 112   my $sym = gensym;
 113   for (qw/SCALAR ARRAY HASH IO FORMAT/) {
 114    no warnings 'once';
 115    *$sym = *$fqn{$_} if defined *$fqn{$_}
 116   }
 117   undef *$fqn;
 118   *$fqn = *$sym;
 119  }
 120 }
 121
 122 sub _fetch {
 123  (undef, my $data, my $func) = @_;
 124  return if $data->{guard} or $func =~ /::/ or exists $core{$func};
 125  $data->{guard} = 1;
 126  my $hints = (caller 0)[10];
 127  if ($hints and $hints->{subs__auto}) {
 128   my $mod = $func . '.pm';
 129   if (not exists $INC{$mod}) {
 130    my $fqn = $data->{pkg} . '::' . $func;
 131    if (do { no strict 'refs'; not *$fqn{CODE} || *$fqn{IO}}) {
 132     my $cb = sub {
 133      my ($file, $line) = (caller 0)[1, 2];
 134      ($file, $line) = ('(eval 0)', 0) unless $file && $line;
 135      die "Undefined subroutine &$fqn called at $file line $line\n";
 136     };
 137     cast &$cb, $tag;
 138     no strict 'refs';
 139     *$fqn = $cb;
 140    }
 141   }
 142  } else {
 143   _reset($data->{pkg}, $func);
 144  }
 145  $data->{guard} = 0;
 146  return;
 147 }
 148
 149 sub _store {
 150  (undef, my $data, my $func) = @_;
 151  return if $data->{guard};
 152  $data->{guard} = 1;
 153  _reset($data->{pkg}, $func);
 154  $data->{guard} = 0;
 155  return;
 156 }
 157
 158 my $wiz = wizard data  => sub { +{ pkg => $_[1] } },
 159                  fetch => \&_fetch,
 160                  store => \&_store;
 161
 162 my %pkgs;
 163
 164 sub _validate_pkg {
 165  my ($pkg, $cur) = @_;
 166  return $cur unless $pkg;
 167  croak 'Invalid package name' if ref $pkg
 168                               or $pkg =~ /(?:-|[^\w:])/
 169                               or $pkg =~ /(?:\A\d|\b:(?::\d|(?:::+)?\b))/;
 170  $pkg =~ s/::$//;
 171  $pkg = $cur . $pkg if $pkg eq '' or $pkg =~ /^::/;
 172  $pkg;
 173 }
 174
 175 sub import {
 176  shift;
 177  croak 'Optional arguments must be passed as keys/values pairs' if @_ % 2;
 178  my %args = @_;
 179  my $cur  = (caller 1)[0];
 180  my $in   = _validate_pkg $args{in}, $cur;
 181  $^H{subs__auto} = 1;
 182  ++$pkgs{$in};
 183  no strict 'refs';
 184  cast %{$in . '::'}, $wiz, $in;
 185 }
 186
 187 sub unimport {
 188  $^H{subs__auto} = 0;
 189 }
 190
 191 {
 192  no warnings 'void';
 193  CHECK {
 194   no strict 'refs';
 195   dispell %{$_ . '::'}, $wiz for keys %pkgs;
 196  }
 197 }
 198
 199 =head1 EXPORT
 200
 201 None.
 202
 203 =head1 CAVEATS
 204
 205 C<*{'::foo'}{CODE}> will appear as defined in a scope where the pragma is enabled, C<foo> is used as a bareword, but is never actually defined afterwards. This may or may not be considered as Doing The Right Thing. However, C<*{'::foo'}{CODE}> will always return the right value if you fetch it outside the pragma's scope. Actually, you can make it return the right value even in the pragma's scope by reading C<*{'::foo'}{CODE}> outside (or by actually defining C<foo>, which is ultimately why you use this pragma, right ?).
 206
 207 You have to open global filehandles outside of the scope of this pragma if you want them not to be treated as function calls. Or just use lexical filehandles and default ones as you should be.
 208
 209 =head1 DEPENDENCIES
 210
 211 L<perl> 5.10.0.
 212
 213 L<Carp> (standard since perl 5), L<Symbol> (since 5.002).
 214
 215 L<Variable::Magic> with C<uvar> magic enabled (this should be assured by the required perl version).
 216
 217 =head1 AUTHOR
 218
 219 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 220
 221 You can contact me by mail or on C<irc.perl.org> (vincent).
 222
 223 =head1 BUGS
 224
 225 Please report any bugs or feature requests to C<bug-subs-auto at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=subs-auto>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 226
 227 =head1 SUPPORT
 228
 229 You can find documentation for this module with the perldoc command.
 230
 231     perldoc subs::auto
 232
 233 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/subs-auto>.
 234
 235 =head1 ACKNOWLEDGEMENTS
 236
 237 Thanks to Sebastien Aperghis-Tramoni for helping to name this pragma.
 238
 239 =head1 COPYRIGHT & LICENSE
 240
 241 Copyright 2008 Vincent Pit, all rights reserved.
 242
 243 This program is free software; you can redistribute it and/or modify it
 244 under the same terms as Perl itself.
 245
 246 =cut
 247
 248 1; # End of subs::auto