lib/App/Rgit/Command.pm

   1 package App::Rgit::Command;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Carp qw/croak/;
   7
   8 use Object::Tiny qw/cmd args/;
   9
  10 use App::Rgit::Utils qw/validate/;
  11
  12 =head1 NAME
  13
  14 App::Rgit::Command - Base class for App::Rgit commands.
  15
  16 =head1 VERSION
  17
  18 Version 0.02
  19
  20 =cut
  21
  22 our $VERSION = '0.02';
  23
  24 =head1 DESCRIPTION
  25
  26 Base class for L<App::Rgit> commands.
  27
  28 This is an internal class to L<rgit>.
  29
  30 =head1 METHODS
  31
  32 =head2 C<< new cmd => $cmd, args => \@args >>
  33
  34 Creates a new command object for C<$cmd> that is bound to be called with arguments C<@args>.
  35
  36 =cut
  37
  38 my %commands;
  39 __PACKAGE__->action($_ => 'Once') for qw/version help daemon init/, ' ';
  40
  41 sub new {
  42  my ($class, %args) = &validate;
  43  my $cmd = $args{cmd};
  44  $cmd = ' ' unless defined $cmd;
  45  my $action = $class->action($cmd);
  46  if ($class eq __PACKAGE__) {
  47   $class = $action;
  48  } else {
  49   croak "Command $cmd should be executed as a $action"
  50                                unless $class->isa($action);
  51  }
  52  eval "require $action; 1" or croak "Couldn't load $action: $@";
  53  $class->SUPER::new(
  54   cmd  => $cmd,
  55   args => $args{args} || [ ],
  56  );
  57 }
  58
  59 =head2 C<< action $cmd [ => $pkg ] >>
  60
  61 If C<$pkg> is supplied, handles command C<$cmd> with C<$pkg> objects.
  62 Otherwise, returns the current class for C<$cmd>.
  63
  64 =cut
  65
  66 sub action {
  67  my ($self, $cmd, $pkg) = @_;
  68  if (not defined $cmd) {
  69   return unless defined $self and ref $self and $self->isa(__PACKAGE__);
  70   $cmd = $self->cmd;
  71  }
  72  unless (defined $pkg) {
  73   return __PACKAGE__ . '::Each' unless defined $commands{$cmd};
  74   return $commands{$cmd}
  75  }
  76  $pkg = __PACKAGE__ . '::' . $pkg unless $pkg =~ /:/;
  77  $commands{$cmd} = $pkg;
  78 }
  79
  80 =head2 C<cmd>
  81
  82 =head2 C<args>
  83
  84 Accessors.
  85
  86 =head2 C<run $conf>
  87
  88 Runs the command with a L<App::Rgit::Config> configuration object.
  89 Stops as soon as one of the executed commands fails, and returns the corresponding exit code.
  90 Returns zero when all went fine.
  91 Implemented in subclasses.
  92
  93 =head1 SEE ALSO
  94
  95 L<rgit>.
  96
  97 =head1 AUTHOR
  98
  99 Vincent Pit, C<< <perl at profvince.com> >>, L<http://profvince.com>.
 100
 101 You can contact me by mail or on C<irc.perl.org> (vincent).
 102
 103 =head1 BUGS
 104
 105 Please report any bugs or feature requests to C<bug-rgit at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=rgit>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 106
 107 =head1 SUPPORT
 108
 109 You can find documentation for this module with the perldoc command.
 110
 111     perldoc App::Rgit::Command
 112
 113 =head1 COPYRIGHT & LICENSE
 114
 115 Copyright 2008 Vincent Pit, all rights reserved.
 116
 117 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 118
 119 =cut
 120
 121 1; # End of App::Rgit::Command