bin/rgit

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use Carp   qw<croak>;
   7 use Config qw<%Config>;
   8 use Cwd    qw<cwd>;
   9
  10 use App::Rgit;
  11 use App::Rgit::Utils qw<:levels>;
  12 use App::Rgit::Policy;
  13
  14 our $VERSION;
  15 BEGIN {
  16  $VERSION = '0.08';
  17 }
  18
  19 my %opts;
  20 my $cmd;
  21
  22 BEGIN {
  23  @ARGV = grep {
  24   defined $cmd ? $_
  25                : ( /^-([DIKV]+)$/ ? do { $opts{$_} = 1 for split //, $1; () }
  26                                   : do { $cmd = $_ unless /^-/; $_ } )
  27  } @ARGV;
  28  $cmd = ' ' unless defined $cmd;
  29 }
  30
  31 my $policy;
  32
  33 if (-t && $opts{I}) {
  34  $policy = 'Interactive';
  35 } elsif ($opts{K}) {
  36  $policy = 'Keep';
  37 }
  38 $policy = eval { App::Rgit::Policy->new(policy => $policy) };
  39 if (not defined $policy) {
  40  print STDERR $@ if $@;
  41  $policy = App::Rgit::Policy->new(policy => 'Default');
  42 }
  43
  44 setpgrp 0, 0 if $Config{d_setpgrp};
  45
  46 my $ar = App::Rgit->new(
  47  git    => undef, # Autodiscovery
  48  root   => undef, # Autodiscovery
  49  cmd    => $cmd,
  50  args   => \@ARGV,
  51  policy => $policy,
  52  debug  => $opts{D} ? INFO : WARN,
  53 );
  54
  55 print STDOUT "rgit $VERSION\n" if $opts{V};
  56
  57 exit $ar->run;
  58
  59 __END__
  60
  61 =head1 NAME
  62
  63 rgit - Recursively execute a command on all the git repositories in a directory tree.
  64
  65 =head1 VERSION
  66
  67 Version 0.08
  68
  69 =head1 SYNOPSIS
  70
  71     rgit [-K|-I|-D|-V] [GIT_OPTIONS] COMMAND [COMMAND_ARGS]
  72
  73 =head1 DESCRIPTION
  74
  75 This utility recursively searches in a root directory (which may be the current working directory or - if it has been set - the directory given by the C<GIT_DIR> environment variable) for all git repositories, sort this list by the repository path, C<chdir> into each of them, and executes the specified git command.
  76 For efficiency reasons, repositories located inside a bare repository or under the F<.git> directory of a work repository won't be searched for.
  77
  78 Moreover, those formats are substituted in the arguments before running the command :
  79
  80 =over 4
  81
  82 =item *
  83
  84 C<%n> with the current repository name.
  85
  86 =item *
  87
  88 C<%g> with the relative path (based from the root directory) to the current repository.
  89
  90 =item *
  91
  92 C<%G> with the absolute path to the current repository.
  93
  94 =item *
  95
  96 C<%w> with the relative path (based from the root directory) to the current repository's working directory.
  97
  98 =item *
  99
 100 C<%W> with the absolute path to the current repository's working directory.
 101
 102 =item *
 103
 104 C<%b> with a "bareified" relative path, i.e. C<%g> if this is a bare repository, and C<%w.git> otherwise.
 105
 106 =item *
 107
 108 C<%B> with an absolute version of the "bareified" path.
 109
 110 =item *
 111
 112 C<%R> with the absolute path to the root directory.
 113
 114 =item *
 115
 116 C<%%> with a bare C<%>.
 117
 118 =back
 119
 120 There are actually a few commands that are only executed once in the root directory : C<daemon>, C<gui>, C<help>, C<init> and C<version>.
 121 For any of those, no format substitution is done.
 122
 123 You can specify which C<git> executable to use with the C<GIT_EXEC_PATH> environment variable.
 124
 125 =head1 COMMAND LINE SWITCHES
 126
 127 C<rgit> takes its options as the capital switches that comes before the git command.
 128 It's possible to bundle them together.
 129 They are removed from the argument list before calling C<git>.
 130
 131 =over 4
 132
 133 =item *
 134
 135 C<-K>
 136
 137 Keep processing on error.
 138 The default policy is to stop whenever an error occured.
 139
 140 =item *
 141
 142 C<-I>
 143
 144 Enables interactive mode when the standard input is a tty.
 145 Requires L<Term::ReadKey> to be installed.
 146 This lets you choose interactively what to do when one of the commands returns a non-zero status.
 147
 148 =item *
 149
 150 C<-D>
 151
 152 Outputs diagnostics.
 153
 154 =item *
 155
 156 C<-V>
 157
 158 Outputs the version.
 159
 160 =back
 161
 162 =head1 EXAMPLES
 163
 164 Execute C<git gc> on all the repositories below the current directory :
 165
 166     rgit gc
 167
 168 Tag all the repositories with their name :
 169
 170     rgit tag %n
 171
 172 Add a remote to all repositories in "/foo/bar" to their bare counterpart in C<qux> on F<host> :
 173
 174     GIT_DIR="/foo/bar" rgit remote add host git://host/qux/%b
 175
 176 =head1 DEPENDENCIES
 177
 178 The core modules L<Carp>, L<Config>, L<Cwd>, L<Exporter>, L<File::Find>, L<File::Spec> and L<POSIX>.
 179
 180 =head1 AUTHOR
 181
 182 Vincent Pit, C<< <perl at profvince.com> >>, L<http://profvince.com>.
 183
 184 You can contact me by mail or on C<irc.perl.org> (vincent).
 185
 186 =head1 BUGS
 187
 188 Please report any bugs or feature requests to C<bug-rgit at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=rgit>.
 189 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 190
 191 =head1 SUPPORT
 192
 193 You can find documentation for this module with the perldoc command.
 194
 195     perldoc rgit
 196
 197 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/rgit>.
 198
 199 =head1 COPYRIGHT & LICENSE
 200
 201 Copyright 2008,2009,2010 Vincent Pit, all rights reserved.
 202
 203 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 204
 205 =cut