lib/indirect.pm

   1 package indirect;
   2
   3 use 5.008;
   4
   5 use strict;
   6 use warnings;
   7
   8 =head1 NAME
   9
  10 indirect - Lexically warn about using the indirect object syntax.
  11
  12 =head1 VERSION
  13
  14 Version 0.18
  15
  16 =cut
  17
  18 our $VERSION;
  19 BEGIN {
  20  $VERSION = '0.18';
  21 }
  22
  23 =head1 SYNOPSIS
  24
  25     # In a script
  26     no indirect;
  27     my $x = new Apple 1, 2, 3; # warns
  28     {
  29      use indirect;
  30      my $y = new Pear; # ok
  31      {
  32       no indirect hook => sub { die "You really wanted $_[0]\->$_[1] at $_[2]:$_[3]" };
  33       my $z = new Pineapple 'fresh'; # croaks 'You really wanted Pineapple->new at blurp.pm:13'
  34      }
  35     }
  36     try { ... }; # warns
  37
  38     no indirect ':fatal';
  39     if (defied $foo) { ... } # croaks, note the typo
  40
  41     # From the command-line
  42     perl -M-indirect -e 'my $x = new Banana;' # warns
  43
  44     # Or each time perl is ran
  45     export PERL5OPT="-M-indirect"
  46     perl -e 'my $y = new Coconut;' # warns
  47
  48 =head1 DESCRIPTION
  49
  50 When enabled (or disabled as some may prefer to say, since you actually turn it on by calling C<no indirect>), this pragma warns about indirect object syntax constructs that may have slipped into your code.
  51 This syntax is now considered harmful, since its parsing has many quirks and its use is error prone (when C<swoosh> isn't defined, C<swoosh $x> actually compiles to C<< $x->swoosh >>).
  52
  53 It currently does not warn for core functions (C<print>, C<say>, C<exec> or C<system>).
  54 This may change in the future, or may be added as optional features that would be enabled by passing options to C<unimport>.
  55
  56 This module is B<not> a source filter.
  57
  58 =cut
  59
  60 BEGIN {
  61  if ($ENV{PERL_INDIRECT_PM_DISABLE}) {
  62   *_tag = sub ($) { 1 };
  63   *I_THREADSAFE = sub () { 1 };
  64  } else {
  65   require XSLoader;
  66   XSLoader::load(__PACKAGE__, $VERSION);
  67  }
  68 }
  69
  70 =head1 METHODS
  71
  72 =head2 C<< unimport [ hook => $hook | ':fatal' ] >>
  73
  74 Magically called when C<no indirect @opts> is encountered.
  75 Turns the module on.
  76 The policy to apply depends on what is first found in C<@opts> :
  77
  78 =over 4
  79
  80 =item *
  81
  82 If it's the string C<':fatal'>, the compilation will croak on the first indirect syntax met.
  83
  84 =item *
  85
  86 If the key/value pair C<< hook => $hook >> comes first, C<$hook> will be called for each error with a string representation of the object as C<$_[0]>, the method name as C<$_[1]>, the current file as C<$_[2]> and the line number as C<$_[3]>.
  87 If and only if the object is actually a block, C<$_[0]> is assured to start by C<'{'>.
  88
  89 =item *
  90
  91 Otherwise, a warning will be emitted for each indirect construct.
  92
  93 =back
  94
  95 =cut
  96
  97 sub unimport {
  98  shift;
  99
 100  my $hook;
 101  while (@_) {
 102   my $arg = shift;
 103   if ($arg eq 'hook') {
 104    $hook = shift;
 105   } elsif ($arg eq ':fatal') {
 106    $hook = sub { die msg(@_) };
 107   }
 108   last if $hook;
 109  }
 110  $hook = sub { warn msg(@_) } unless defined $hook;
 111
 112  $^H |= 0x00020000;
 113  $^H{+(__PACKAGE__)} = _tag($hook);
 114
 115  ();
 116 }
 117
 118 =head2 C<import>
 119
 120 Magically called at each C<use indirect>. Turns the module off.
 121
 122 =cut
 123
 124 sub import {
 125  $^H{+(__PACKAGE__)} = undef;
 126  ();
 127 }
 128
 129 =head1 FUNCTIONS
 130
 131 =head2 C<msg $object, $method, $file, $line>
 132
 133 Returns the default error message generated by C<indirect> when an invalid construct is reported.
 134
 135 =cut
 136
 137 sub msg {
 138  my $obj = $_[0];
 139
 140  join ' ', "Indirect call of method \"$_[1]\" on",
 141            ($obj =~ /^\s*\{/ ? "a block" : "object \"$obj\""),
 142            "at $_[2] line $_[3].\n";
 143 };
 144
 145 =head1 CONSTANTS
 146
 147 =head2 C<I_THREADSAFE>
 148
 149 True iff the module could have been built with thread-safety features enabled.
 150
 151 =head1 DIAGNOSTICS
 152
 153 =head2 C<Indirect call of method "%s" on object "%s" at %s line %d.>
 154
 155 The default warning/exception message thrown when an indirect call on an object is found.
 156
 157 =head2 C<Indirect call of method "%s" on a block at %s line %d.>
 158
 159 The default warning/exception message thrown when an indirect call on a block is found.
 160
 161 =head1 ENVIRONMENT
 162
 163 =head2 C<PERL_INDIRECT_PM_DISABLE>
 164
 165 If this environment variable is set to true when the pragma is used for the first time, the XS code won't be loaded and, although the C<'indirect'> lexical hint will be set to true in the scope of use, the pragma itself won't do anything.
 166 In this case, the pragma will always be considered to be thread-safe, and as such L</I_THREADSAFE> will be true.
 167 This is useful for disabling C<indirect> in production environments.
 168
 169 Note that clearing this variable after C<indirect> was loaded has no effect.
 170 If you want to reenable the pragma later, you also need to reload it by deleting the C<'indirect.pm'> entry from C<%INC>.
 171
 172 =head1 CAVEATS
 173
 174 The implementation was tweaked to work around several limitations of vanilla C<perl> pragmas : it's thread safe, and doesn't suffer from a C<perl 5.8.x-5.10.0> bug that causes all pragmas to propagate into C<require>d scopes.
 175
 176 C<meth $obj> (no semicolon) at the end of a file won't be seen as an indirect object syntax, although it will as soon as there is another token before the end (as in C<meth $obj;> or C<meth $obj 1>).
 177
 178 With 5.8 perls, the pragma does not propagate into C<eval STRING>.
 179 This is due to a shortcoming in the way perl handles the hints hash, which is addressed in perl 5.10.
 180
 181 The search for indirect method calls happens before constant folding.
 182 Hence C<my $x = new Class if 0> will be caught.
 183
 184 =head1 DEPENDENCIES
 185
 186 L<perl> 5.8.
 187
 188 L<XSLoader> (standard since perl 5.006).
 189
 190 =head1 AUTHOR
 191
 192 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 193
 194 You can contact me by mail or on C<irc.perl.org> (vincent).
 195
 196 =head1 BUGS
 197
 198 Please report any bugs or feature requests to C<bug-indirect at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=indirect>.
 199 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 200
 201 =head1 SUPPORT
 202
 203 You can find documentation for this module with the perldoc command.
 204
 205     perldoc indirect
 206
 207 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/indirect>.
 208
 209 =head1 ACKNOWLEDGEMENTS
 210
 211 Bram, for motivation and advices.
 212
 213 Andrew Main and Florian Ragwitz, for testing on real-life code and reporting issues.
 214
 215 =head1 COPYRIGHT & LICENSE
 216
 217 Copyright 2008-2009 Vincent Pit, all rights reserved.
 218
 219 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 220
 221 =cut
 222
 223 1; # End of indirect