t/41-clone.t

   1 #!perl -T
   2
   3 use strict;
   4 use warnings;
   5
   6 use Config qw/%Config/;
   7
   8 BEGIN {
   9  if (!$Config{useithreads}) {
  10   require Test::More;
  11   Test::More->import;
  12   plan(skip_all => 'This perl wasn\'t built to support threads');
  13  }
  14 }
  15
  16 use threads; # Before Test::More
  17 use threads::shared;
  18
  19 use Test::More;
  20
  21 use Variable::Magic qw/wizard cast dispell getdata getsig VMG_THREADSAFE/;
  22
  23 if (VMG_THREADSAFE) {
  24  plan tests => 3 + 2 * (2 * 8 + 2) + 2 * (2 * 5 + 2);
  25  diag 'This will leak a few scalars';
  26 } else {
  27  plan skip_all => 'This Variable::Magic isn\'t thread safe';
  28 }
  29
  30 my $destroyed : shared = 0;
  31 my $c         : shared = 0;
  32 my $wiz = wizard get  => sub { ++$c },
  33                  data => sub { $_[1] + threads->tid() },
  34                  free => sub { ++$destroyed };
  35 is($@,     '',    "wizard in main thread doesn't croak");
  36 isnt($wiz, undef, "wizard in main thread is defined");
  37 is($c,     0,     "wizard in main thread doesn't trigger magic");
  38
  39 my $sig;
  40
  41 sub try {
  42  my ($dispell) = @_;
  43  my $tid = threads->tid();
  44  my $a   = 3;
  45  my $res = eval { cast $a, $sig, sub { 5 }->() };
  46  is($@, '', "cast in thread $tid doesn't croak");
  47  my $b;
  48  eval { $b = $a };
  49  is($@, '', "get in thread $tid doesn't croak");
  50  is($b, 3,  "get in thread $tid returns the right thing");
  51  my $d = eval { getdata $a, $sig };
  52  is($@, '',       "getdata in thread $tid doesn't croak");
  53  is($d, 5 + $tid, "getdata in thread $tid returns the right thing");
  54  if ($dispell) {
  55   $res = eval { dispell $a, $sig };
  56   is($@, '', "dispell in thread $tid doesn't croak");
  57   undef $b;
  58   eval { $b = $a };
  59   is($@, '', "get in thread $tid after dispell doesn't croak");
  60   is($b, 3,  "get in thread $tid after dispell returns the right thing");
  61  }
  62  return; # Ugly if not here
  63 }
  64
  65 for my $dispell (1, 0) {
  66  $c = 0;
  67  $destroyed = 0;
  68  $sig = $wiz;
  69
  70  my @t = map { threads->create(\&try, $dispell) } 1 .. 2;
  71  $t[0]->join;
  72  $t[1]->join;
  73
  74  is($c, 2, "get triggered twice");
  75  is($destroyed, (1 - $dispell) * 2, 'destructors');
  76
  77  $c = 0;
  78  $destroyed = 0;
  79  $sig = getsig $wiz;
  80
  81  @t = map { threads->create(\&try, $dispell) } 1 .. 2;
  82  $t[0]->join;
  83  $t[1]->join;
  84
  85  is($c, 2, "get triggered twice");
  86  is($destroyed, (1 - $dispell) * 2, 'destructors');
  87 }