t/40-threads.t

   1 #!perl -T
   2
   3 use strict;
   4 use warnings;
   5
   6 sub skipall {
   7  my ($msg) = @_;
   8  require Test::More;
   9  Test::More::plan(skip_all => $msg);
  10 }
  11
  12 use Config qw/%Config/;
  13
  14 BEGIN {
  15  my $t_v  = '1.67';
  16  my $ts_v = '1.14';
  17  skipall 'This perl wasn\'t built to support threads'
  18                                                     unless $Config{useithreads};
  19  skipall 'perl 5.13.4 required to test thread safety' unless $] >= 5.013004;
  20  skipall "threads $t_v required to test thread safety"
  21                                               unless eval "use threads $t_v; 1";
  22  skipall "threads::shared $ts_v required to test thread safety"
  23                                      unless eval "use threads::shared $ts_v; 1";
  24 }
  25
  26 use Test::More; # after threads
  27
  28 use Variable::Magic qw/wizard cast dispell getdata VMG_THREADSAFE VMG_OP_INFO_NAME VMG_OP_INFO_OBJECT/;
  29
  30 BEGIN {
  31  skipall 'This Variable::Magic isn\'t thread safe' unless VMG_THREADSAFE;
  32  plan tests => (4 * 18 + 1) + (4 * 13 + 1);
  33  my $v = $threads::VERSION;
  34  diag "Using threads $v" if defined $v;
  35  $v = $threads::shared::VERSION;
  36  diag "Using threads::shared $v" if defined $v;
  37 }
  38
  39 my $destroyed : shared = 0;
  40
  41 sub try {
  42  my ($dispell, $op_info) = @_;
  43  my $tid = threads->tid();
  44  my $c   = 0;
  45  my $wiz = eval {
  46   wizard data    => sub { $_[1] + $tid },
  47          get     => sub { ++$c; 0 },
  48          set     => sub {
  49                      my $op = $_[-1];
  50                      if ($op_info == VMG_OP_INFO_OBJECT) {
  51                       is_deeply { class => ref($op),   name => $op->name },
  52                                 { class => 'B::BINOP', name => 'sassign' },
  53                                 "op object in thread $tid is correct";
  54                      } else {
  55                       is $op, 'sassign', "op name in thread $tid is correct";
  56                      }
  57                      0
  58                     },
  59          free    => sub { lock $destroyed; ++$destroyed; 0 },
  60          op_info => $op_info
  61  };
  62  is($@,     '',    "wizard in thread $tid doesn't croak");
  63  isnt($wiz, undef, "wizard in thread $tid is defined");
  64  is($c,     0,     "wizard in thread $tid doesn't trigger magic");
  65  my $a = 3;
  66  my $res = eval { cast $a, $wiz, sub { 5 }->() };
  67  is($@, '', "cast in thread $tid doesn't croak");
  68  is($c, 0,  "cast in thread $tid doesn't trigger magic");
  69  my $b;
  70  eval { $b = $a };
  71  is($@, '', "get in thread $tid doesn't croak");
  72  is($b, 3,  "get in thread $tid returns the right thing");
  73  is($c, 1,  "get in thread $tid triggers magic");
  74  my $d = eval { getdata $a, $wiz };
  75  is($@, '',       "getdata in thread $tid doesn't croak");
  76  is($d, 5 + $tid, "getdata in thread $tid returns the right thing");
  77  is($c, 1,        "getdata in thread $tid doesn't trigger magic");
  78  eval { $a = 9 };
  79  is($@, '', "set in thread $tid (check opname) doesn't croak");
  80  if ($dispell) {
  81   $res = eval { dispell $a, $wiz };
  82   is($@, '', "dispell in thread $tid doesn't croak");
  83   is($c, 1,  "dispell in thread $tid doesn't trigger magic");
  84   undef $b;
  85   eval { $b = $a };
  86   is($@, '', "get in thread $tid after dispell doesn't croak");
  87   is($b, 9,  "get in thread $tid after dispell returns the right thing");
  88   is($c, 1,  "get in thread $tid after dispell doesn't trigger magic");
  89  }
  90  return; # Ugly if not here
  91 }
  92
  93 for my $dispell (1, 0) {
  94  {
  95   lock $destroyed;
  96   $destroyed = 0;
  97  }
  98
  99  my @t = map { threads->create(\&try, $dispell, $_) }
 100                               (VMG_OP_INFO_NAME) x 2, (VMG_OP_INFO_OBJECT) x 2;
 101  $_->join for @t;
 102
 103  {
 104   lock $destroyed;
 105   is $destroyed, (1 - $dispell) * 4, 'destructors';
 106  }
 107 }