t/18-opinfo.t

   1 #!perl -T
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More tests => 17 * (3 + 4) + 5 + 1;
   7
   8 use Config qw/%Config/;
   9
  10 use Variable::Magic qw/wizard cast dispell VMG_OP_INFO_NAME VMG_OP_INFO_OBJECT/;
  11
  12 sub Variable::Magic::TestPkg::foo { }
  13
  14 my $is_5130_release = ($] == 5.013 && !$Config{git_describe}) ? 1 : 0;
  15
  16 my $aelem     = $] <= 5.008003 ? 'aelem'
  17                                : ($] < 5.013 or $is_5130_release) ? 'aelemfast'
  18                                                                   : 'sassign';
  19 my $aelemf    = ($] < 5.013 or $is_5130_release) ? 'aelemfast' : 'sassign';
  20 my $aelemf_op = $aelemf eq 'sassign'
  21                    ? 'B::BINOP' : $Config{useithreads} ? 'B::PADOP' : 'B::SVOP';
  22
  23 our @o;
  24
  25 my @tests = (
  26  [ 'len', '@c',    'my @c',     'my $x = @c',      [ 'padav',   'B::OP'     ] ],
  27  [ 'get', '$c[0]', 'my @c',     'my $x = $c[0]',   [ $aelem,    'B::OP'     ] ],
  28  [ 'get', '$o[0]', 'local @o',  'my $x = $o[0]',   [ $aelemf,   $aelemf_op  ] ],
  29  [ 'get', '$c',    'my $c = 1', '++$c',            [ 'preinc',  'B::UNOP'   ] ],
  30  [ 'get', '$c',    'my $c = 1', '$c ** 2',         [ 'pow',     'B::BINOP'  ] ],
  31  [ 'get', '$c',    'my $c = 1', 'my $x = $c',      [ 'sassign', 'B::BINOP'  ] ],
  32  [ 'get', '$c',    'my $c = 1', '1 if $c',         [ 'and',     'B::LOGOP'  ] ],
  33  [ 'get', '$c',    'my $c = []','ref $c',          [ 'ref',     'B::UNOP'   ] ],
  34  [ 'get', '$c',    'my $c = $0','-f $c',           [ 'ftfile',  'B::UNOP'   ] ],
  35  [ 'get', '$c',    'my $c = "Z"',
  36                    'my $i = 1; Z:goto $c if $i--', [ 'goto',    'B::UNOP'   ] ],
  37  [ 'set', '$c',    'my $c = 1', 'bless \$c, "main"',
  38                                                    [ 'bless',   'B::LISTOP' ] ],
  39  [ 'get', '$c',    'my $c = ""','$c =~ /x/',       [ 'match',   'B::PMOP'   ] ],
  40  [ 'get', '$c',    'my $c = "Variable::Magic::TestPkg"',
  41                                 '$c->foo()',  [ 'method_named', 'B::SVOP'   ] ],
  42  [ 'get', '$c',    'my $c = ""','$c =~ y/x/y/',    [ 'trans',   'B::PVOP'   ] ],
  43  [ 'get', '$c',    'my $c = 1', '1 for 1 .. $c',
  44                                                  [ 'enteriter', 'B::LOOP'   ] ],
  45  [ 'free','$c',    'my $c = 1', 'last',            [ 'last',    'B::OP'     ] ],
  46  [ 'free','$c', 'L:{my $c = 1', 'last L}',         [ 'last',    'B::OP'     ] ],
  47 );
  48
  49 our $done;
  50
  51 for (@tests) {
  52  my ($key, $var, $init, $test, $exp) = @$_;
  53
  54  for my $op_info (VMG_OP_INFO_NAME, VMG_OP_INFO_OBJECT) {
  55   my $wiz;
  56
  57   # We must test for the $op correctness inside the callback because, if we
  58   # bring it out, it will go outside of the eval STRING scope, and what it
  59   # points to will no longer exist.
  60   eval {
  61    $wiz = wizard $key => sub {
  62     return if $done;
  63     my $op = $_[-1];
  64     my $desc = "$key magic with op_info == $op_info";
  65     if ($op_info == VMG_OP_INFO_NAME) {
  66      is $op, $exp->[0], "$desc gets the right op info";
  67     } elsif ($op_info == VMG_OP_INFO_OBJECT) {
  68      isa_ok $op, $exp->[1], $desc;
  69      is $op->name, $exp->[0], "$desc gets the right op info";
  70     } else {
  71      is $op, undef, "$desc gets the right op info";
  72     }
  73     $done = 1;
  74     ()
  75    }, op_info => $op_info
  76   };
  77   is $@, '', "$key wizard with op_info == $op_info doesn't croak";
  78
  79   local $done = 0;
  80
  81   my $testcase = "{ $init; cast $var, \$wiz; $test }";
  82
  83   eval $testcase;
  84   is $@, '', "$key magic with op_info == $op_info doesn't croak";
  85   diag $testcase if $@;
  86  }
  87 }
  88
  89 {
  90  my $c;
  91
  92  my $wiz = eval {
  93   wizard get => sub {
  94     is $_[-1], undef, 'get magic with out of bounds op_info';
  95    },
  96    op_info => 3;
  97  };
  98  is $@, '', "get wizard with out of bounds op_info doesn't croak";
  99
 100  eval { cast $c, $wiz };
 101  is $@, '', "get cast with out of bounds op_info doesn't croak";
 102
 103  eval { my $x = $c };
 104  is $@, '', "get magic with out of bounds op_info doesn't croak";
 105
 106  eval { dispell $c, $wiz };
 107  is $@, '', "get dispell with out of bounds op_info doesn't croak";
 108 }
 109
 110 {
 111  local $@;
 112  my $wiz = eval {
 113   local $SIG{__WARN__} = sub { die @_ };
 114   wizard op_info => "hlagh";
 115  };
 116  like $@, qr/^Argument "hlagh" isn't numeric in subroutine entry at \Q$0\E/,
 117       'wizard(op_info => "text") throws numeric warnings';
 118 }