lib/Variable/Magic.pm

   1 package Variable::Magic;
   2
   3 use 5.008;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp qw/croak/;
   9
  10 =head1 NAME
  11
  12 Variable::Magic - Associate user-defined magic to variables from Perl.
  13
  14 =head1 VERSION
  15
  16 Version 0.30
  17
  18 =cut
  19
  20 our $VERSION;
  21 BEGIN {
  22  $VERSION = '0.30';
  23 }
  24
  25 =head1 SYNOPSIS
  26
  27     use Variable::Magic qw/wizard cast dispell/;
  28
  29     my $wiz = wizard set => sub { print STDERR "now set to ${$_[0]}!\n" };
  30     my $a = 1;
  31     cast $a, $wiz;
  32     $a = 2;          # "now set to 2!"
  33     dispell $a, $wiz;
  34     $a = 3           # (nothing)
  35
  36 =head1 DESCRIPTION
  37
  38 Magic is Perl way of enhancing objects.
  39 This mechanism lets the user add extra data to any variable and hook syntaxical operations (such as access, assignment or destruction) that can be applied to it.
  40 With this module, you can add your own magic to any variable without having to write a single line of XS.
  41
  42 You'll realize that these magic variables look a lot like tied variables.
  43 It's not surprising, as tied variables are implemented as a special kind of magic, just like any 'irregular' Perl variable : scalars like C<$!>, C<$(> or C<$^W>, the C<%ENV> and C<%SIG> hashes, the C<@ISA> array,  C<vec()> and C<substr()> lvalues, L<thread::shared> variables...
  44 They all share the same underlying C API, and this module gives you direct access to it.
  45
  46 Still, the magic made available by this module differs from tieing and overloading in several ways :
  47
  48 =over 4
  49
  50 =item *
  51
  52 It isn't copied on assignment.
  53
  54 You attach it to variables, not values (as for blessed references).
  55
  56 =item *
  57
  58 It doesn't replace the original semantics.
  59
  60 Magic callbacks trigger before the original action take place, and can't prevent it to happen.
  61 This makes catching individual events easier than with C<tie>, where you have to provide fallbacks methods for all actions by usually inheriting from the correct C<Tie::Std*> class and overriding individual methods in your own class.
  62
  63 =item *
  64
  65 It's type-agnostic.
  66
  67 The same magic can be applied on scalars, arrays, hashes, subs or globs.
  68 But the same hook (see below for a list) may trigger differently depending on the the type of the variable.
  69
  70 =item *
  71
  72 It's mostly invisible at the Perl level.
  73
  74 Magical and non-magical variables cannot be distinguished with C<ref>, C<tied> or another trick.
  75
  76 =item *
  77
  78 It's notably faster.
  79
  80 Mainly because perl's way of handling magic is lighter by nature, and because there's no need for any method resolution.
  81 Also, since you don't have to reimplement all the variable semantics, you only pay for what you actually use.
  82
  83 =back
  84
  85 The operations that can be overloaded are :
  86
  87 =over 4
  88
  89 =item *
  90
  91 C<get>
  92
  93 This magic is invoked when the variable is evaluated (does not include array/hash subscripts and slices).
  94
  95 =item *
  96
  97 C<set>
  98
  99 This one is triggered each time the value of the variable changes (includes array/hash subscripts and slices).
 100
 101 =item *
 102
 103 C<len>
 104
 105 This magic is a little special : it is called when the 'size' or the 'length' of the variable has to be known by Perl.
 106 Typically, it's the magic involved when an array is evaluated in scalar context, but also on array assignment and loops (C<for>, C<map> or C<grep>).
 107 The callback has then to return the length as an integer.
 108
 109 =item *
 110
 111 C<clear>
 112
 113 This magic is invoked when the variable is reset, such as when an array is emptied.
 114 Please note that this is different from undefining the variable, even though the magic is called when the clearing is a result of the undefine (e.g. for an array, but actually a bug prevent it to work before perl 5.9.5 - see the L<history|/PERL MAGIC HISTORY>).
 115
 116 =item *
 117
 118 C<free>
 119
 120 This one can be considered as an object destructor.
 121 It happens when the variable goes out of scope (with the exception of global scope), but not when it is undefined.
 122
 123 =item *
 124
 125 C<copy>
 126
 127 This magic only applies to tied arrays and hashes.
 128 It fires when you try to access or change their elements.
 129 It is available on your perl iff C<MGf_COPY> is true.
 130
 131 =item *
 132
 133 C<dup>
 134
 135 Invoked when the variable is cloned across threads.
 136 Currently not available.
 137
 138 =item *
 139
 140 C<local>
 141
 142 When this magic is set on a variable, all subsequent localizations of the variable will trigger the callback.
 143 It is available on your perl iff C<MGf_LOCAL> is true.
 144
 145 =back
 146
 147 The following actions only apply to hashes and are available iff C<VMG_UVAR> is true.
 148 They are referred to as C<uvar> magics.
 149
 150 =over 4
 151
 152 =item *
 153
 154 C<fetch>
 155
 156 This magic happens each time an element is fetched from the hash.
 157
 158 =item *
 159
 160 C<store>
 161
 162 This one is called when an element is stored into the hash.
 163
 164 =item *
 165
 166 C<exists>
 167
 168 This magic fires when a key is tested for existence in the hash.
 169
 170 =item *
 171
 172 C<delete>
 173
 174 This last one triggers when a key is deleted in the hash, regardless of whether the key actually exists in it.
 175
 176 =back
 177
 178 You can refer to the tests to have more insight of where the different magics are invoked.
 179
 180 To prevent any clash between different magics defined with this module, an unique numerical signature is attached to each kind of magic (i.e. each set of callbacks for magic operations).
 181
 182 =head1 FUNCTIONS
 183
 184 =cut
 185
 186 BEGIN {
 187  require XSLoader;
 188  XSLoader::load(__PACKAGE__, $VERSION);
 189 }
 190
 191 =head2 C<wizard>
 192
 193     wizard sig      => ...,
 194            data     => sub { ... },
 195            get      => sub { my ($ref, $data [, $op]) = @_; ... },
 196            set      => sub { my ($ref, $data [, $op]) = @_; ... },
 197            len      => sub { my ($ref, $data, $len [, $op]) = @_; ... ; return $newlen; },
 198            clear    => sub { my ($ref, $data [, $op]) = @_; ... },
 199            free     => sub { my ($ref, $data [, $op]) = @_, ... },
 200            copy     => sub { my ($ref, $data, $key, $elt [, $op]) = @_; ... },
 201            local    => sub { my ($ref, $data [, $op]) = @_; ... },
 202            fetch    => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 203            store    => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 204            exists   => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 205            delete   => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 206            copy_key => $bool,
 207            op_info  => [ 0 | VMG_OP_INFO_NAME | VMG_OP_INFO_OBJECT ]
 208
 209 This function creates a 'wizard', an opaque type that holds the magic information.
 210 It takes a list of keys / values as argument, whose keys can be :
 211
 212 =over 4
 213
 214 =item *
 215
 216 C<sig>
 217
 218 The numerical signature.
 219 If not specified or undefined, a random signature is generated.
 220 If the signature matches an already defined magic, then the existant magic object is returned.
 221
 222 =item *
 223
 224 C<data>
 225
 226 A code reference to a private data constructor.
 227 It is called each time this magic is cast on a variable, and the scalar returned is used as private data storage for it.
 228 C<$_[0]> is a reference to the magic object and C<@_[1 .. @_-1]> are all extra arguments that were passed to L</cast>.
 229
 230 =item *
 231
 232 C<get>, C<set>, C<len>, C<clear>, C<free>, C<copy>, C<local>, C<fetch>, C<store>, C<exists> and C<delete>
 233
 234 Code references to the corresponding magic callbacks.
 235 You don't have to specify all of them : the magic associated with undefined entries simply won't be hooked.
 236 In those callbacks, C<$_[0]> is always a reference to the magic object and C<$_[1]> is always the private data (or C<undef> when no private data constructor was supplied).
 237
 238 Moreover, when you pass C<< op_info => $num >> to C<wizard>, the last element of C<@_> will be the current op name if C<$num == VMG_OP_INFO_NAME> and a C<B::OP> object representing the current op if C<$num == VMG_OP_INFO_OBJECT>.
 239 Both have a performance hit, but just getting the name is lighter than getting the op object.
 240
 241 Other arguments are specific to the magic hooked :
 242
 243 =over 8
 244
 245 =item *
 246
 247 C<len>
 248
 249 When the variable is an array or a scalar, C<$_[2]> contains the non-magical length.
 250 The callback can return the new scalar or array length to use, or C<undef> to default to the normal length.
 251
 252 =item *
 253
 254 C<copy>
 255
 256 C<$_[2]> is a either a copy or an alias of the current key, which means that it is useless to try to change or cast magic on it.
 257 C<$_[3]> is an alias to the current element (i.e. the value).
 258
 259 =item *
 260
 261 C<fetch>, C<store>, C<exists> and C<delete>
 262
 263 C<$_[2]> is an alias to the current key.
 264 Nothing prevents you from changing it, but be aware that there lurk dangerous side effects.
 265 For example, it may righteously be readonly if the key was a bareword.
 266 You can get a copy instead by passing C<< copy_key => 1 >> to L</wizard>, which allows you to safely assign to C<$_[2]> in order to e.g. redirect the action to another key.
 267 This however has a little performance drawback because of the copy.
 268
 269 =back
 270
 271 All the callbacks are expected to return an integer, which is passed straight to the perl magic API.
 272 However, only the return value of the C<len> callback currently holds a meaning.
 273
 274 =back
 275
 276     # A simple scalar tracer
 277     my $wiz = wizard get  => sub { print STDERR "got ${$_[0]}\n" },
 278                      set  => sub { print STDERR "set to ${$_[0]}\n" },
 279                      free => sub { print STDERR "${$_[0]} was deleted\n" }
 280
 281 =cut
 282
 283 sub wizard {
 284  croak 'Wrong number of arguments for wizard()' if @_ % 2;
 285  my %opts = @_;
 286  my @keys = qw/sig data op_info get set len clear free/;
 287  push @keys, 'copy'  if MGf_COPY;
 288  push @keys, 'dup'   if MGf_DUP;
 289  push @keys, 'local' if MGf_LOCAL;
 290  push @keys, qw/fetch store exists delete copy_key/ if VMG_UVAR;
 291  my $ret = eval { _wizard(map $opts{$_}, @keys) };
 292  if (my $err = $@) {
 293   $err =~ s/\sat\s+.*?\n//;
 294   croak $err;
 295  }
 296  return $ret;
 297 }
 298
 299 =head2 C<gensig>
 300
 301 With this tool, you can manually generate random magic signature between SIG_MIN and SIG_MAX inclusive.
 302 That's the way L</wizard> creates them when no signature is supplied.
 303
 304     # Generate a signature
 305     my $sig = gensig;
 306
 307 =head2 C<getsig>
 308
 309     getsig $wiz
 310
 311 This accessor returns the magic signature of this wizard.
 312
 313     # Get $wiz signature
 314     my $sig = getsig $wiz;
 315
 316 =head2 C<cast>
 317
 318     cast [$@%&*]var, [$wiz|$sig], ...
 319
 320 This function associates C<$wiz> magic to the variable supplied, without overwriting any other kind of magic.
 321 You can also supply the numeric signature C<$sig> instead of C<$wiz>.
 322 It returns true on success or when C<$wiz> magic is already present, C<0> on error, and C<undef> when no magic corresponds to the given signature (in case C<$sig> was supplied).
 323 All extra arguments specified after C<$wiz> are passed to the private data constructor.
 324 If the variable isn't a hash, any C<uvar> callback of the wizard is safely ignored.
 325
 326     # Casts $wiz onto $x. If $wiz isn't a signature, undef can't be returned.
 327     my $x;
 328     die 'error' unless cast $x, $wiz;
 329
 330 The C<var> argument can be an array or hash value.
 331 Magic for those behaves like for any other scalar, except that it is dispelled when the entry is deleted from the container.
 332 For example, if you want to call C<POSIX::tzset> each time the C<'TZ'> environment variable is changed in C<%ENV>, you can use :
 333
 334     use POSIX;
 335     cast $ENV{TZ}, wizard set => sub { POSIX::tzset(); () };
 336
 337 If you want to overcome the possible deletion of the C<'TZ'> entry, you have no choice but to rely on C<store> uvar magic.
 338
 339 =head2 C<getdata>
 340
 341     getdata [$@%&*]var, [$wiz|$sig]
 342
 343 This accessor fetches the private data associated with the magic C<$wiz> (or the signature C<$sig>) in the variable.
 344 C<undef> is returned when no such magic or data is found, or when C<$sig> does not represent a current valid magic object.
 345
 346     # Get the attached data.
 347     my $data = getdata $x, $wiz or die 'no such magic or magic has no data';
 348
 349 =head2 C<dispell>
 350
 351     dispell [$@%&*]variable, [$wiz|$sig]
 352
 353 The exact opposite of L</cast> : it dissociates C<$wiz> magic from the variable.
 354 You can also pass the magic signature C<$sig> as the second argument.
 355 True is returned on success, C<0> on error or when no magic represented by C<$wiz> could be found in the variable, and C<undef> when no magic corresponds to the given signature (in case C<$sig> was supplied).
 356
 357     # Dispell now. If $wiz isn't a signature, undef can't be returned.
 358     die 'no such magic or error' unless dispell $x, $wiz;
 359
 360 =head1 CONSTANTS
 361
 362 =head2 C<SIG_MIN>
 363
 364 The minimum integer used as a signature for user-defined magic.
 365
 366 =head2 C<SIG_MAX>
 367
 368 The maximum integer used as a signature for user-defined magic.
 369
 370 =head2 C<SIG_NBR>
 371
 372     SIG_NBR = SIG_MAX - SIG_MIN + 1
 373
 374 =head2 C<MGf_COPY>
 375
 376 Evaluates to true iff the 'copy' magic is available.
 377
 378 =head2 C<MGf_DUP>
 379
 380 Evaluates to true iff the 'dup' magic is available.
 381
 382 =head2 C<MGf_LOCAL>
 383
 384 Evaluates to true iff the 'local' magic is available.
 385
 386 =head2 C<VMG_UVAR>
 387
 388 When this constant is true, you can use the C<fetch,store,exists,delete> callbacks on hashes.
 389
 390 =head2 C<VMG_COMPAT_ARRAY_PUSH_NOLEN>
 391
 392 True for perls that don't call 'len' magic when you push an element in a magical array.
 393
 394 =head2 C<VMG_COMPAT_ARRAY_UNSHIFT_NOLEN_VOID>
 395
 396 True for perls that don't call 'len' magic when you unshift in void context an element in a magical array.
 397
 398 =head2 C<VMG_COMPAT_ARRAY_UNDEF_CLEAR>
 399
 400 True for perls that call 'clear' magic when undefining magical arrays.
 401
 402 =head2 C<VMG_COMPAT_SCALAR_LENGTH_NOLEN>
 403
 404 True for perls that don't call 'len' magic when taking the C<length> of a magical scalar.
 405
 406 =head2 C<VMG_PERL_PATCHLEVEL>
 407
 408 The perl patchlevel this module was built with, or C<0> for non-debugging perls.
 409
 410 =head2 C<VMG_THREADSAFE>
 411
 412 True iff this module could have been built with thread-safety features enabled.
 413
 414 =head2 C<VMG_OP_INFO_NAME>
 415
 416 Value to pass with C<op_info> to get the current op name in the magic callbacks.
 417
 418 =head2 C<VMG_OP_INFO_OBJECT>
 419
 420 Value to pass with C<op_info> to get a C<B::OP> object representing the current op in the magic callbacks.
 421
 422 =head1 PERL MAGIC HISTORY
 423
 424 The places where magic is invoked have changed a bit through perl history.
 425 Here's a little list of the most recent ones.
 426
 427 =over 4
 428
 429 =item *
 430
 431 B<5.6.x>
 432
 433 I<p14416> : 'copy' and 'dup' magic.
 434
 435 =item *
 436
 437 B<5.8.9>
 438
 439 I<p28160> : Integration of I<p25854> (see below).
 440
 441 I<p32542> : Integration of I<p31473> (see below).
 442
 443 =item *
 444
 445 B<5.9.3>
 446
 447 I<p25854> : 'len' magic is no longer called when pushing an element into a magic array.
 448
 449 I<p26569> : 'local' magic.
 450
 451 =item *
 452
 453 B<5.9.5>
 454
 455 I<p31064> : Meaningful 'uvar' magic.
 456
 457 I<p31473> : 'clear' magic wasn't invoked when undefining an array.
 458 The bug is fixed as of this version.
 459
 460 =item *
 461
 462 B<5.10.0>
 463
 464 Since C<PERL_MAGIC_uvar> is uppercased, C<hv_magic_check()> triggers 'copy' magic on hash stores for (non-tied) hashes that also have 'uvar' magic.
 465
 466 =item *
 467
 468 B<5.11.x>
 469
 470 I<p32969> : 'len' magic is no longer invoked when calling C<length> with a magical scalar.
 471
 472 I<p34908> : 'len' magic is no longer called when pushing / unshifting an element into a magical array in void context.
 473 The C<push> part was already covered by I<p25854>.
 474
 475 =back
 476
 477 =head1 EXPORT
 478
 479 The functions L</wizard>, L</gensig>, L</getsig>, L</cast>, L</getdata> and L</dispell> are only exported on request.
 480 All of them are exported by the tags C<':funcs'> and C<':all'>.
 481
 482 All the constants are also only exported on request, either individually or by the tags C<':consts'> and C<':all'>.
 483
 484 =cut
 485
 486 use base qw/Exporter/;
 487
 488 our @EXPORT         = ();
 489 our %EXPORT_TAGS    = (
 490  'funcs' =>  [ qw/wizard gensig getsig cast getdata dispell/ ],
 491  'consts' => [
 492                qw/SIG_MIN SIG_MAX SIG_NBR MGf_COPY MGf_DUP MGf_LOCAL VMG_UVAR/,
 493                qw/VMG_COMPAT_ARRAY_PUSH_NOLEN VMG_COMPAT_ARRAY_UNSHIFT_NOLEN_VOID VMG_COMPAT_ARRAY_UNDEF_CLEAR VMG_COMPAT_SCALAR_LENGTH_NOLEN/,
 494                qw/VMG_PERL_PATCHLEVEL/,
 495                qw/VMG_THREADSAFE/,
 496                qw/VMG_OP_INFO_NAME VMG_OP_INFO_OBJECT/
 497              ]
 498 );
 499 our @EXPORT_OK      = map { @$_ } values %EXPORT_TAGS;
 500 $EXPORT_TAGS{'all'} = [ @EXPORT_OK ];
 501
 502 =head1 CAVEATS
 503
 504 If you store a magic object in the private data slot, the magic won't be accessible by L</getdata> since it's not copied by assignment.
 505 The only way to address this would be to return a reference.
 506
 507 If you define a wizard with a C<free> callback and cast it on itself, this destructor won't be called because the wizard will be destroyed first.
 508
 509 =head1 DEPENDENCIES
 510
 511 L<perl> 5.8.
 512
 513 L<Carp> (standard since perl 5), L<XSLoader> (standard since perl 5.006).
 514
 515 Copy tests need L<Tie::Array> (standard since perl 5.005) and L<Tie::Hash> (since 5.002).
 516
 517 Some uvar tests need L<Hash::Util::FieldHash> (standard since perl 5.009004).
 518
 519 Glob tests need L<Symbol> (standard since perl 5.002).
 520
 521 Threads tests need L<threads> and L<threads::shared>.
 522
 523 =head1 SEE ALSO
 524
 525 L<perlguts> and L<perlapi> for internal information about magic.
 526
 527 L<perltie> and L<overload> for other ways of enhancing objects.
 528
 529 =head1 AUTHOR
 530
 531 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 532
 533 You can contact me by mail or on C<irc.perl.org> (vincent).
 534
 535 =head1 BUGS
 536
 537 Please report any bugs or feature requests to C<bug-variable-magic at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Variable-Magic>. I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 538
 539 =head1 SUPPORT
 540
 541 You can find documentation for this module with the perldoc command.
 542
 543     perldoc Variable::Magic
 544
 545 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Variable-Magic>.
 546
 547 =head1 COPYRIGHT & LICENSE
 548
 549 Copyright 2007-2009 Vincent Pit, all rights reserved.
 550
 551 This program is free software; you can redistribute it and/or modify it
 552 under the same terms as Perl itself.
 553
 554 =cut
 555
 556 1; # End of Variable::Magic