lib/Variable/Magic.pm

   1 package Variable::Magic;
   2
   3 use 5.007003;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp qw/croak/;
   9
  10 =head1 NAME
  11
  12 Variable::Magic - Associate user-defined magic to variables from Perl.
  13
  14 =head1 VERSION
  15
  16 Version 0.27
  17
  18 =cut
  19
  20 our $VERSION;
  21 BEGIN {
  22  $VERSION = '0.27';
  23 }
  24
  25 =head1 SYNOPSIS
  26
  27     use Variable::Magic qw/wizard cast dispell/;
  28
  29     my $wiz = wizard set => sub { print STDERR "now set to ${$_[0]}!\n" };
  30     my $a = 1;
  31     cast $a, $wiz;
  32     $a = 2;          # "now set to 2!"
  33     dispell $a, $wiz;
  34     $a = 3           # (nothing)
  35
  36 =head1 DESCRIPTION
  37
  38 Magic is Perl way of enhancing objects.
  39 This mechanism let the user add extra data to any variable and hook syntaxical operations (such as access, assignation or destruction) that can be applied to it.
  40 With this module, you can add your own magic to any variable without the pain of the C API.
  41
  42 Magic differs from tieing and overloading in several ways :
  43
  44 =over 4
  45
  46 =item *
  47
  48 Magic isn't copied on assignation (as for blessed references) : you attach it to variables, not values.
  49
  50 =item *
  51
  52 It doesn't replace the original semantics : magic callbacks trigger before the original action take place, and can't prevent it to happen.
  53
  54 =item *
  55
  56 It's mostly invisible at the Perl level : magical and non-magical variables cannot be distinguished with C<ref>, C<reftype> or another trick.
  57
  58 =item *
  59
  60 It's notably faster, since perl's way of handling magic is lighter by nature, and there's no need for any method resolution.
  61
  62 =back
  63
  64 The operations that can be overloaded are :
  65
  66 =over 4
  67
  68 =item *
  69
  70 C<get>
  71
  72 This magic is invoked when the variable is evaluated (does not include array/hash subscripts and slices).
  73
  74 =item *
  75
  76 C<set>
  77
  78 This one is triggered each time the value of the variable changes (includes array/hash subscripts and slices).
  79
  80 =item *
  81
  82 C<len>
  83
  84 This magic is a little special : it is called when the 'size' or the 'length' of the variable has to be known by Perl.
  85 Typically, it's the magic involved when an array is evaluated in scalar context, but also on array assignation and loops (C<for>, C<map> or C<grep>).
  86 The callback has then to return the length as an integer.
  87
  88 =item *
  89
  90 C<clear>
  91
  92 This magic is invoked when the variable is reset, such as when an array is emptied.
  93 Please note that this is different from undefining the variable, even though the magic is called when the clearing is a result of the undefine (e.g. for an array, but actually a bug prevent it to work before perl 5.9.5 - see the L<history|/PERL MAGIC HISTORY>).
  94
  95 =item *
  96
  97 C<free>
  98
  99 This one can be considered as an object destructor.
 100 It happens when the variable goes out of scope (with the exception of global scope), but not when it is undefined.
 101
 102 =item *
 103
 104 C<copy>
 105
 106 This magic only applies to tied arrays and hashes.
 107 It fires when you try to access or change their elements.
 108 It is available on your perl iff C<MGf_COPY> is true.
 109
 110 =item *
 111
 112 C<dup>
 113
 114 Invoked when the variable is cloned across threads.
 115 Currently not available.
 116
 117 =item *
 118
 119 C<local>
 120
 121 When this magic is set on a variable, all subsequent localizations of the variable will trigger the callback.
 122 It is available on your perl iff C<MGf_LOCAL> is true.
 123
 124 =back
 125
 126 The following actions only apply to hashes and are available iff C<VMG_UVAR> is true.
 127 They are referred to as C<uvar> magics.
 128
 129 =over 4
 130
 131 =item *
 132
 133 C<fetch>
 134
 135 This magic happens each time an element is fetched from the hash.
 136
 137 =item *
 138
 139 C<store>
 140
 141 This one is called when an element is stored into the hash.
 142
 143 =item *
 144
 145 C<exists>
 146
 147 This magic fires when a key is tested for existence in the hash.
 148
 149 =item *
 150
 151 C<delete>
 152
 153 This last one triggers when a key is deleted in the hash, regardless of whether the key actually exists in it.
 154
 155 =back
 156
 157 You can refer to the tests to have more insight of where the different magics are invoked.
 158
 159 To prevent any clash between different magics defined with this module, an unique numerical signature is attached to each kind of magic (i.e. each set of callbacks for magic operations).
 160
 161 =head1 PERL MAGIC HISTORY
 162
 163 The places where magic is invoked have changed a bit through perl history.
 164 Here's a little list of the most recent ones.
 165
 166 =over 4
 167
 168 =item *
 169
 170 B<5.6.x>
 171
 172 I<p14416> : 'copy' and 'dup' magic.
 173
 174 =item *
 175
 176 B<5.8.9>
 177
 178 I<p28160> : Integration of I<p25854> (see below).
 179
 180 I<p32542> : Integration of I<p31473> (see below).
 181
 182 =item *
 183
 184 B<5.9.3>
 185
 186 I<p25854> : 'len' magic is no longer called when pushing an element into a magic array.
 187
 188 I<p26569> : 'local' magic.
 189
 190 =item *
 191
 192 B<5.9.5>
 193
 194 I<p31064> : Meaningful 'uvar' magic.
 195
 196 I<p31473> : 'clear' magic wasn't invoked when undefining an array.
 197 The bug is fixed as of this version.
 198
 199 =item *
 200
 201 B<5.10.0>
 202
 203 Since C<PERL_MAGIC_uvar> is uppercased, C<hv_magic_check()> triggers 'copy' magic on hash stores for (non-tied) hashes that also have 'uvar' magic.
 204
 205 =item *
 206
 207 B<5.11.x>
 208
 209 I<p32969> : 'len' magic is no longer invoked when calling C<length> with a magical scalar.
 210
 211 I<p34908> : 'len' magic is no longer called when pushing / unshifting an element into a magical array in void context.
 212 The C<push> part was already covered by I<p25854>.
 213
 214 =back
 215
 216 =head1 CONSTANTS
 217
 218 =head2 C<SIG_MIN>
 219
 220 The minimum integer used as a signature for user-defined magic.
 221
 222 =head2 C<SIG_MAX>
 223
 224 The maximum integer used as a signature for user-defined magic.
 225
 226 =head2 C<SIG_NBR>
 227
 228     SIG_NBR = SIG_MAX - SIG_MIN + 1
 229
 230 =head2 C<MGf_COPY>
 231
 232 Evaluates to true iff the 'copy' magic is available.
 233
 234 =head2 C<MGf_DUP>
 235
 236 Evaluates to true iff the 'dup' magic is available.
 237
 238 =head2 C<MGf_LOCAL>
 239
 240 Evaluates to true iff the 'local' magic is available.
 241
 242 =head2 C<VMG_UVAR>
 243
 244 When this constant is true, you can use the C<fetch,store,exists,delete> callbacks on hashes.
 245
 246 =head2 C<VMG_COMPAT_ARRAY_PUSH_NOLEN>
 247
 248 True for perls that don't call 'len' magic when you push an element in a magical array.
 249
 250 =head2 C<VMG_COMPAT_ARRAY_UNSHIFT_NOLEN_VOID>
 251
 252 True for perls that don't call 'len' magic when you unshift in void context an element in a magical array.
 253
 254 =head2 C<VMG_COMPAT_ARRAY_UNDEF_CLEAR>
 255
 256 True for perls that call 'clear' magic when undefining magical arrays.
 257
 258 =head2 C<VMG_COMPAT_SCALAR_LENGTH_NOLEN>
 259
 260 True for perls that don't call 'len' magic when taking the C<length> of a magical scalar.
 261
 262 =head2 C<VMG_PERL_PATCHLEVEL>
 263
 264 The perl patchlevel this module was built with, or C<0> for non-debugging perls.
 265
 266 =head2 C<VMG_THREADSAFE>
 267
 268 True iff this module could have been built with thread-safety features enabled.
 269
 270 =head1 FUNCTIONS
 271
 272 =cut
 273
 274 BEGIN {
 275  require XSLoader;
 276  XSLoader::load(__PACKAGE__, $VERSION);
 277 }
 278
 279 =head2 C<wizard>
 280
 281     wizard sig    => ...,
 282            data   => sub { ... },
 283            get    => sub { my ($ref, $data) = @_; ... },
 284            set    => sub { my ($ref, $data) = @_; ... },
 285            len    => sub { my ($ref, $data, $len) = @_; ... ; return $newlen; },
 286            clear  => sub { my ($ref, $data) = @_; ... },
 287            free   => sub { my ($ref, $data) = @_, ... },
 288            copy   => sub { my ($ref, $data, $key, $elt) = @_; ... },
 289            local  => sub { my ($ref, $data) = @_; ... },
 290            fetch  => sub { my ($ref, $data, $key) = @_; ... },
 291            store  => sub { my ($ref, $data, $key) = @_; ... },
 292            exists => sub { my ($ref, $data, $key) = @_; ... },
 293            delete => sub { my ($ref, $data, $key) = @_; ... }
 294
 295 This function creates a 'wizard', an opaque type that holds the magic information.
 296 It takes a list of keys / values as argument, whose keys can be :
 297
 298 =over 4
 299
 300 =item *
 301
 302 C<sig>
 303
 304 The numerical signature.
 305 If not specified or undefined, a random signature is generated.
 306 If the signature matches an already defined magic, then the existant magic object is returned.
 307
 308 =item *
 309
 310 C<data>
 311
 312 A code reference to a private data constructor.
 313 It is called each time this magic is cast on a variable, and the scalar returned is used as private data storage for it.
 314 C<$_[0]> is a reference to the magic object and C<@_[1 .. @_-1]> are all extra arguments that were passed to L</cast>.
 315
 316 =item *
 317
 318 C<get>, C<set>, C<len>, C<clear>, C<free>, C<copy>, C<local>, C<fetch>, C<store>, C<exists> and C<delete>
 319
 320 Code references to the corresponding magic callbacks.
 321 You don't have to specify all of them : the magic associated with undefined entries simply won't be hooked.
 322 In those callbacks, C<$_[0]> is always a reference to the magic object and C<$_[1]> is always the private data (or C<undef> when no private data constructor was supplied).
 323 Other arguments are specific to the magic hooked :
 324
 325 =over 8
 326
 327 =item -
 328
 329 C<len>
 330
 331 When the variable is an array, C<$_[2]> contains the normal length.
 332 The callback is also expected to return the new scalar or array length.
 333
 334 =item -
 335
 336 C<copy>
 337
 338 C<$_[2]> is a either a copy or an alias of the current key, which means that it is useless to try to change or cast magic on it.
 339 C<$_[3]> is an alias to the current element (i.e. the value).
 340
 341 =item -
 342
 343 C<fetch>, C<store>, C<exists> and C<delete>
 344
 345 C<$_[2]> is an alias to the current key.
 346 Nothing prevents you from changing it, but be aware that there lurk dangerous side effects.
 347 For example, it may righteously be readonly if the key was a bareword.
 348 You can get a copy instead by passing C<< copy_key => 1 >> to L</wizard>, which allows you to safely assign to C<$_[2]> in order to e.g. redirect the action to another key.
 349 This however has a little performance drawback because of the copy.
 350
 351 =back
 352
 353 All the callbacks are expected to return an integer, which is passed straight to the perl magic API.
 354 However, only the return value of the C<len> callback currently holds a meaning.
 355
 356 =back
 357
 358     # A simple scalar tracer
 359     my $wiz = wizard get  => sub { print STDERR "got ${$_[0]}\n" },
 360                      set  => sub { print STDERR "set to ${$_[0]}\n" },
 361                      free => sub { print STDERR "${$_[0]} was deleted\n" }
 362
 363 =cut
 364
 365 sub wizard {
 366  croak 'Wrong number of arguments for wizard()' if @_ % 2;
 367  my %opts = @_;
 368  my @keys  = qw/sig data get set len clear free/;
 369  push @keys, 'copy'  if MGf_COPY;
 370  push @keys, 'dup'   if MGf_DUP;
 371  push @keys, 'local' if MGf_LOCAL;
 372  push @keys, qw/fetch store exists delete copy_key/ if VMG_UVAR;
 373  my $ret = eval { _wizard(map $opts{$_}, @keys) };
 374  if (my $err = $@) {
 375   $err =~ s/\sat\s+.*?\n//;
 376   croak $err;
 377  }
 378  return $ret;
 379 }
 380
 381 =head2 C<gensig>
 382
 383 With this tool, you can manually generate random magic signature between SIG_MIN and SIG_MAX inclusive.
 384 That's the way L</wizard> creates them when no signature is supplied.
 385
 386     # Generate a signature
 387     my $sig = gensig;
 388
 389 =head2 C<getsig>
 390
 391     getsig $wiz
 392
 393 This accessor returns the magic signature of this wizard.
 394
 395     # Get $wiz signature
 396     my $sig = getsig $wiz;
 397
 398 =head2 C<cast>
 399
 400     cast [$@%&*]var, [$wiz|$sig], ...
 401
 402 This function associates C<$wiz> magic to the variable supplied, without overwriting any other kind of magic.
 403 You can also supply the numeric signature C<$sig> instead of C<$wiz>.
 404 It returns true on success or when C<$wiz> magic is already present, C<0> on error, and C<undef> when no magic corresponds to the given signature (in case C<$sig> was supplied).
 405 All extra arguments specified after C<$wiz> are passed to the private data constructor.
 406 If the variable isn't a hash, any C<uvar> callback of the wizard is safely ignored.
 407
 408     # Casts $wiz onto $x. If $wiz isn't a signature, undef can't be returned.
 409     my $x;
 410     die 'error' unless cast $x, $wiz;
 411
 412 =head2 C<getdata>
 413
 414     getdata [$@%&*]var, [$wiz|$sig]
 415
 416 This accessor fetches the private data associated with the magic C<$wiz> (or the signature C<$sig>) in the variable.
 417 C<undef> is returned when no such magic or data is found, or when C<$sig> does not represent a current valid magic object.
 418
 419     # Get the attached data.
 420     my $data = getdata $x, $wiz or die 'no such magic or magic has no data';
 421
 422 =head2 C<dispell>
 423
 424     dispell [$@%&*]variable, [$wiz|$sig]
 425
 426 The exact opposite of L</cast> : it dissociates C<$wiz> magic from the variable.
 427 You can also pass the magic signature C<$sig> as the second argument.
 428 True is returned on success, C<0> on error or when no magic represented by C<$wiz> could be found in the variable, and C<undef> when no magic corresponds to the given signature (in case C<$sig> was supplied).
 429
 430     # Dispell now. If $wiz isn't a signature, undef can't be returned.
 431     die 'no such magic or error' unless dispell $x, $wiz;
 432
 433 =head1 EXPORT
 434
 435 The functions L</wizard>, L</gensig>, L</getsig>, L</cast>, L</getdata> and L</dispell> are only exported on request.
 436 All of them are exported by the tags C<':funcs'> and C<':all'>.
 437
 438 The constants L</SIG_MIN>, L</SIG_MAX>, L</SIG_NBR>, L</MGf_COPY>, L</MGf_DUP>, L</MGf_LOCAL> and L</VMG_UVAR> are also only exported on request.
 439 They are all exported by the tags C<':consts'> and C<':all'>.
 440
 441 =cut
 442
 443 use base qw/Exporter/;
 444
 445 our @EXPORT         = ();
 446 our %EXPORT_TAGS    = (
 447  'funcs' =>  [ qw/wizard gensig getsig cast getdata dispell/ ],
 448  'consts' => [ qw/SIG_MIN SIG_MAX SIG_NBR MGf_COPY MGf_DUP MGf_LOCAL VMG_UVAR/,
 449                qw/VMG_COMPAT_ARRAY_PUSH_NOLEN VMG_COMPAT_ARRAY_UNSHIFT_NOLEN_VOID VMG_COMPAT_ARRAY_UNDEF_CLEAR/,
 450                qw/VMG_COMPAT_SCALAR_LENGTH_NOLEN/,
 451                qw/VMG_PERL_PATCHLEVEL/,
 452                qw/VMG_THREADSAFE/ ]
 453 );
 454 our @EXPORT_OK      = map { @$_ } values %EXPORT_TAGS;
 455 $EXPORT_TAGS{'all'} = [ @EXPORT_OK ];
 456
 457 =head1 CAVEATS
 458
 459 If you store a magic object in the private data slot, the magic won't be accessible by L</getdata> since it's not copied by assignation.
 460 The only way to address this would be to return a reference.
 461
 462 If you define a wizard with a C<free> callback and cast it on itself, this destructor won't be called because the wizard will be destroyed first.
 463
 464 Using simultaneously C<get> and C<clear> magics on hashes may cause segfaults.
 465
 466 =head1 DEPENDENCIES
 467
 468 L<perl> 5.7.3.
 469
 470 L<Carp> (standard since perl 5), L<XSLoader> (standard since perl 5.006).
 471
 472 Copy tests need L<Tie::Array> (standard since perl 5.005) and L<Tie::Hash> (since 5.002).
 473
 474 Some uvar tests need L<Hash::Util::FieldHash> (standard since perl 5.009004).
 475
 476 Glob tests need L<Symbol> (standard since perl 5.002).
 477
 478 Threads tests need L<threads> and L<threads::shared>.
 479
 480 =head1 SEE ALSO
 481
 482 L<perlguts> and L<perlapi> for internal information about magic.
 483
 484 L<perltie> and L<overload> for other ways of enhancing objects.
 485
 486 =head1 AUTHOR
 487
 488 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 489
 490 You can contact me by mail or on C<irc.perl.org> (vincent).
 491
 492 =head1 BUGS
 493
 494 Please report any bugs or feature requests to C<bug-variable-magic at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Variable-Magic>. I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 495
 496 =head1 SUPPORT
 497
 498 You can find documentation for this module with the perldoc command.
 499
 500     perldoc Variable::Magic
 501
 502 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Variable-Magic>.
 503
 504 =head1 COPYRIGHT & LICENSE
 505
 506 Copyright 2007-2009 Vincent Pit, all rights reserved.
 507
 508 This program is free software; you can redistribute it and/or modify it
 509 under the same terms as Perl itself.
 510
 511 =cut
 512
 513 1; # End of Variable::Magic