lib/Variable/Magic.pm

   1 package Variable::Magic;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Carp qw/croak/;
   7
   8 =head1 NAME
   9
  10 Variable::Magic - Associate user-defined magic to variables from Perl.
  11
  12 =head1 VERSION
  13
  14 Version 0.02
  15
  16 =cut
  17
  18 our $VERSION = '0.02';
  19
  20 =head1 SYNOPSIS
  21
  22     use Variable::Magic qw/wizard cast dispell/;
  23
  24     my $wiz = wizard set => sub { print STDERR "now set to $_[0]!\n" };
  25     my $a = 1;
  26     cast $a, $wiz;
  27     $a = 2;          # "now set to 2!"
  28     dispell $a, $wiz;
  29     $a = 3           # (nothing)
  30
  31 =head1 DESCRIPTION
  32
  33 Magic is Perl way of enhancing objects. This mechanism let the user add extra data to any variable and overload syntaxical operations (such as access, assignation or destruction) that can be applied to it. With this module, you can add your own magic to any variable without the pain of the C API.
  34
  35 The operations that can be overloaded are :
  36
  37 =over 4
  38
  39 =item C<get>
  40
  41 This magic is invoked when the variable is evaluated (does not include array/hash subscripts and slices).
  42
  43 =item C<set>
  44
  45 This one is triggered each time the value of the variable changes (includes array/hash subscripts and slices).
  46
  47 =item C<len>
  48
  49 This magic is a little special : it is called when the 'size' or the 'length' of the variable has to be known by Perl. Typically, it's the magic involved when an array is evaluated in scalar context, but also on array assignation and loops (C<for>, C<map> or C<grep>). The callback has then to return the length as an integer.
  50
  51 =item C<clear>
  52
  53 This magic is invoked when the variable is reset, such as when an array is emptied. Please note that this is different from undefining the variable, even though the magic is called when the clearing is a result of the undefine (e.g. for an array, but actually a bug prevent it to work before perl 5.9.5 - see the L<history|/PERL MAGIC HISTORY>).
  54
  55 =item C<free>
  56
  57 This last one can be considered as an object destructor. It happens when the variable goes out of scope (with the exception of global scope), but not when it is undefined.
  58
  59 =back
  60
  61 To prevent any clash between different magics defined with this module, an unique numerical signature is attached to each kind of magic (i.e. each set of callbacks for magic operations).
  62
  63 =head1 PERL MAGIC HISTORY
  64
  65 =head2 B<5.9.3>
  66
  67 =over 4
  68
  69 =item 'len' magic is no longer called when pushing an element into a magic array.
  70
  71 =back
  72
  73 =head2 B<5.9.5>
  74
  75 =over 4
  76
  77 =item 'clear' magic wasn't invoked when undefining an array. The bug is fixed as of this version.
  78
  79 =back
  80
  81 =head1 CONSTANTS
  82
  83 =head2 C<SIG_MIN>
  84
  85 The minimum integer used as a signature for user-defined magic.
  86
  87 =cut
  88
  89 use constant SIG_MIN => 2 ** 8;
  90
  91 =head2 C<SIG_MAX>
  92
  93 The maximum integer used as a signature for user-defined magic.
  94
  95 =cut
  96
  97 use constant SIG_MAX => 2 ** 16 - 1;
  98
  99 =head2 C<SIG_NBR>
 100
 101     SIG_NBR = SIG_MAX - SIG_MIN + 1
 102
 103 =cut
 104
 105 use constant SIG_NBR => SIG_MAX - SIG_MIN + 1;
 106
 107 =head1 FUNCTIONS
 108
 109 =cut
 110
 111 require XSLoader;
 112
 113 XSLoader::load(__PACKAGE__, $VERSION);
 114
 115 my %wizz;
 116
 117 =head2 C<wizard>
 118
 119     wizard sig => .., data => ..., get => .., set => .., len => .., clear => .., free => ..
 120
 121 This function creates a 'wizard', an opaque type that holds the magic information. It takes a list of keys / values as argument, whose keys can be :
 122
 123 =over 4
 124
 125 =item C<'sig'>
 126
 127 The numerical signature. If not specified or undefined, a random signature is generated.
 128
 129 =item C<'data'>
 130
 131 A code reference to a private data constructor. It will be called each time this magic is cast on a variable, and the scalar returned will be used as private data storage for it.
 132
 133 =item C<'get'>, C<'set'>, C<'len'>, C<'clear'> and C<'free'>
 134
 135 Code references to corresponding magic callbacks. You don't have to specify all of them : the magic associated with undefined entries simply won't be hooked. When the magic variable is an array or a hash, C<$_[0]> is a reference to it, but directly references it otherwise. C<$_[1]> is the private data (or C<undef> when no private data constructor was supplied). In the special case of C<len> magic and when the variable is an array, C<$_[2]> contains its normal length.
 136
 137 =back
 138
 139     # A simple scalar tracer
 140     my $wiz = wizard get  => sub { print STDERR "got $_[0]\n" },
 141                      set  => sub { print STDERR "set to $_[0]\n" },
 142                      free => sub { print STDERR "$_[0] was deleted\n" }
 143
 144 =cut
 145
 146 sub wizard {
 147  croak 'Wrong number of arguments for wizard()' if @_ % 2;
 148  my %opts = @_;
 149  my $sig;
 150  if (defined $opts{sig}) {
 151   $sig = int $opts{sig};
 152   $sig += SIG_MIN if $sig < SIG_MIN;
 153   $sig %= SIG_MAX + 1 if $sig > SIG_MAX;
 154  } else {
 155   $sig = gensig();
 156  }
 157  return _wizard($sig, map { $opts{$_} } qw/get set len clear free data/);
 158 }
 159
 160 =head2 C<gensig>
 161
 162 With this tool, you can manually generate random magic signature between SIG_MIN and SIG_MAX inclusive. That's the way L</wizard> creates them when no signature is supplied.
 163
 164     # Generate a signature
 165     my $sig = gensig;
 166
 167 =cut
 168
 169 sub gensig {
 170  my $sig;
 171  my $used = ~~keys %wizz;
 172  croak 'Too many magic signatures used' if $used == SIG_NBR;
 173  do { $sig = SIG_MIN + int(rand(SIG_NBR)) } while $wizz{$sig};
 174  return $sig;
 175 }
 176
 177 =head2 C<getsig>
 178
 179     getsig $wiz
 180
 181 This accessor returns the magic signature of this wizard.
 182
 183     # Get $wiz signature
 184     my $sig = getsig $wiz;
 185
 186 =head2 C<cast>
 187
 188     cast [$@%&*]var, $wiz
 189
 190 This function associates C<$wiz> magic to the variable supplied, without overwriting any other kind of magic. It returns true on success or when C<$wiz> magic is already present, and false on error.
 191
 192     # Casts $wiz to $x
 193     my $x;
 194     die 'error' unless cast $x, $wiz;
 195
 196 =head2 C<getdata>
 197
 198     getdata [$@%&*]var, $wiz
 199
 200 This accessor fetches the private data associated with the magic C<$wiz> in the variable. C<undef> is returned when no such magic or data is found.
 201
 202 =head2 C<dispell>
 203
 204     dispell [$@%&*]variable, $wiz
 205     dispell [$@%&*]variable, $sig
 206
 207 The exact opposite of L</cast> : it dissociates C<$wiz> magic from the variable. You can also pass the magic signature as the second argument. True is returned on success, and false on error or when no magic represented by C<$wiz> could be found in the variable.
 208
 209     # Dispell now
 210     die 'no such magic or error' unless dispell $x, $wiz;
 211
 212 =head1 EXPORT
 213
 214 The functions L</wizard>, L</gensig>, L</getsig>, L</cast>, L</getdata> and L</dispell> are only exported on request. All of them are exported by the tags C<':funcs'> and C<':all'>.
 215
 216 The constants L</SIG_MIN>, L</SIG_MAX> and L</SIG_NBR> are also only exported on request. They are all exported by the tags C<':consts'> and C<':all'>.
 217
 218 =cut
 219
 220 use base qw/Exporter/;
 221
 222 our @EXPORT         = ();
 223 our %EXPORT_TAGS    = (
 224  'funcs' =>  [ qw/wizard gensig getsig cast getdata dispell/ ],
 225  'consts' => [ qw/SIG_MIN SIG_MAX SIG_NBR/ ]
 226 );
 227 our @EXPORT_OK      = map { @$_ } values %EXPORT_TAGS;
 228 $EXPORT_TAGS{'all'} = \@EXPORT_OK;
 229
 230 =head1 DEPENDENCIES
 231
 232 L<Carp> (standard since perl 5), L<XSLoader> (standard since perl 5.006).
 233
 234 Tests use L<Symbol> (standard since perl 5.002).
 235
 236 =head1 SEE ALSO
 237
 238 L<perlguts> and L<perlapi> for internal information about magic.
 239
 240 =head1 AUTHOR
 241
 242 Vincent Pit, C<< <perl at profvince.com> >>
 243
 244 =head1 BUGS
 245
 246 Please report any bugs or feature requests to
 247 C<bug-variable-magic at rt.cpan.org>, or through the web interface at
 248 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Variable-Magic>.
 249 I will be notified, and then you'll automatically be notified of progress on
 250 your bug as I make changes.
 251
 252 =head1 SUPPORT
 253
 254 You can find documentation for this module with the perldoc command.
 255
 256     perldoc Variable::Magic
 257
 258 =head1 COPYRIGHT & LICENSE
 259
 260 Copyright 2007 Vincent Pit, all rights reserved.
 261
 262 This program is free software; you can redistribute it and/or modify it
 263 under the same terms as Perl itself.
 264
 265 =cut
 266
 267 1; # End of Variable::Magic