lib/Variable/Magic.pm

   1 package Variable::Magic;
   2
   3 use 5.008;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp qw/croak/;
   9
  10 =head1 NAME
  11
  12 Variable::Magic - Associate user-defined magic to variables from Perl.
  13
  14 =head1 VERSION
  15
  16 Version 0.31
  17
  18 =cut
  19
  20 our $VERSION;
  21 BEGIN {
  22  $VERSION = '0.31';
  23 }
  24
  25 =head1 SYNOPSIS
  26
  27     use Variable::Magic qw/wizard cast VMG_OP_INFO_NAME/;
  28
  29     { # A variable tracer
  30      my $wiz = wizard set  => sub { print "now set to ${$_[0]}!\n" },
  31                       free => sub { print "destroyed!\n" };
  32
  33      my $a = 1;
  34      cast $a, $wiz;
  35      $a = 2;        # "now set to 2!"
  36     }               # "destroyed!"
  37
  38     { # A hash with a default value
  39      my $wiz = wizard data     => sub { $_[1] },
  40                       fetch    => sub { $_[2] = $_[1] unless exists $_[0]->{$_[2]}; () },
  41                       store    => sub { print "key $_[2] stored in $_[-1]\n" },
  42                       copy_key => 1,
  43                       op_info  => VMG_OP_INFO_NAME;
  44
  45      my %h = (_default => 0, apple => 2);
  46      cast %h, $wiz, '_default';
  47      print $h{banana}, "\n"; # "0", because the 'banana' key doesn't exist in %h
  48      $h{pear} = 1;           # "key pear stored in helem"
  49     }
  50
  51 =head1 DESCRIPTION
  52
  53 Magic is Perl way of enhancing objects.
  54 This mechanism lets the user add extra data to any variable and hook syntaxical operations (such as access, assignment or destruction) that can be applied to it.
  55 With this module, you can add your own magic to any variable without having to write a single line of XS.
  56
  57 You'll realize that these magic variables look a lot like tied variables.
  58 It's not surprising, as tied variables are implemented as a special kind of magic, just like any 'irregular' Perl variable : scalars like C<$!>, C<$(> or C<$^W>, the C<%ENV> and C<%SIG> hashes, the C<@ISA> array,  C<vec()> and C<substr()> lvalues, L<thread::shared> variables...
  59 They all share the same underlying C API, and this module gives you direct access to it.
  60
  61 Still, the magic made available by this module differs from tieing and overloading in several ways :
  62
  63 =over 4
  64
  65 =item *
  66
  67 It isn't copied on assignment.
  68
  69 You attach it to variables, not values (as for blessed references).
  70
  71 =item *
  72
  73 It doesn't replace the original semantics.
  74
  75 Magic callbacks trigger before the original action take place, and can't prevent it to happen.
  76 This makes catching individual events easier than with C<tie>, where you have to provide fallbacks methods for all actions by usually inheriting from the correct C<Tie::Std*> class and overriding individual methods in your own class.
  77
  78 =item *
  79
  80 It's type-agnostic.
  81
  82 The same magic can be applied on scalars, arrays, hashes, subs or globs.
  83 But the same hook (see below for a list) may trigger differently depending on the the type of the variable.
  84
  85 =item *
  86
  87 It's mostly invisible at the Perl level.
  88
  89 Magical and non-magical variables cannot be distinguished with C<ref>, C<tied> or another trick.
  90
  91 =item *
  92
  93 It's notably faster.
  94
  95 Mainly because perl's way of handling magic is lighter by nature, and because there's no need for any method resolution.
  96 Also, since you don't have to reimplement all the variable semantics, you only pay for what you actually use.
  97
  98 =back
  99
 100 The operations that can be overloaded are :
 101
 102 =over 4
 103
 104 =item *
 105
 106 C<get>
 107
 108 This magic is invoked when the variable is evaluated (does not include array/hash subscripts and slices).
 109
 110 =item *
 111
 112 C<set>
 113
 114 This one is triggered each time the value of the variable changes (includes array/hash subscripts and slices).
 115
 116 =item *
 117
 118 C<len>
 119
 120 This magic is a little special : it is called when the 'size' or the 'length' of the variable has to be known by Perl.
 121 Typically, it's the magic involved when an array is evaluated in scalar context, but also on array assignment and loops (C<for>, C<map> or C<grep>).
 122 The callback has then to return the length as an integer.
 123
 124 =item *
 125
 126 C<clear>
 127
 128 This magic is invoked when the variable is reset, such as when an array is emptied.
 129 Please note that this is different from undefining the variable, even though the magic is called when the clearing is a result of the undefine (e.g. for an array, but actually a bug prevent it to work before perl 5.9.5 - see the L<history|/PERL MAGIC HISTORY>).
 130
 131 =item *
 132
 133 C<free>
 134
 135 This one can be considered as an object destructor.
 136 It happens when the variable goes out of scope (with the exception of global scope), but not when it is undefined.
 137
 138 =item *
 139
 140 C<copy>
 141
 142 This magic only applies to tied arrays and hashes.
 143 It fires when you try to access or change their elements.
 144 It is available on your perl iff C<MGf_COPY> is true.
 145
 146 =item *
 147
 148 C<dup>
 149
 150 Invoked when the variable is cloned across threads.
 151 Currently not available.
 152
 153 =item *
 154
 155 C<local>
 156
 157 When this magic is set on a variable, all subsequent localizations of the variable will trigger the callback.
 158 It is available on your perl iff C<MGf_LOCAL> is true.
 159
 160 =back
 161
 162 The following actions only apply to hashes and are available iff C<VMG_UVAR> is true.
 163 They are referred to as C<uvar> magics.
 164
 165 =over 4
 166
 167 =item *
 168
 169 C<fetch>
 170
 171 This magic happens each time an element is fetched from the hash.
 172
 173 =item *
 174
 175 C<store>
 176
 177 This one is called when an element is stored into the hash.
 178
 179 =item *
 180
 181 C<exists>
 182
 183 This magic fires when a key is tested for existence in the hash.
 184
 185 =item *
 186
 187 C<delete>
 188
 189 This last one triggers when a key is deleted in the hash, regardless of whether the key actually exists in it.
 190
 191 =back
 192
 193 You can refer to the tests to have more insight of where the different magics are invoked.
 194
 195 To prevent any clash between different magics defined with this module, an unique numerical signature is attached to each kind of magic (i.e. each set of callbacks for magic operations).
 196
 197 =head1 FUNCTIONS
 198
 199 =cut
 200
 201 BEGIN {
 202  require XSLoader;
 203  XSLoader::load(__PACKAGE__, $VERSION);
 204 }
 205
 206 =head2 C<wizard>
 207
 208     wizard sig      => ...,
 209            data     => sub { ... },
 210            get      => sub { my ($ref, $data [, $op]) = @_; ... },
 211            set      => sub { my ($ref, $data [, $op]) = @_; ... },
 212            len      => sub { my ($ref, $data, $len [, $op]) = @_; ... ; return $newlen; },
 213            clear    => sub { my ($ref, $data [, $op]) = @_; ... },
 214            free     => sub { my ($ref, $data [, $op]) = @_, ... },
 215            copy     => sub { my ($ref, $data, $key, $elt [, $op]) = @_; ... },
 216            local    => sub { my ($ref, $data [, $op]) = @_; ... },
 217            fetch    => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 218            store    => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 219            exists   => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 220            delete   => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 221            copy_key => $bool,
 222            op_info  => [ 0 | VMG_OP_INFO_NAME | VMG_OP_INFO_OBJECT ]
 223
 224 This function creates a 'wizard', an opaque type that holds the magic information.
 225 It takes a list of keys / values as argument, whose keys can be :
 226
 227 =over 4
 228
 229 =item *
 230
 231 C<sig>
 232
 233 The numerical signature.
 234 If not specified or undefined, a random signature is generated.
 235 If the signature matches an already defined magic, then the existant magic object is returned.
 236
 237 =item *
 238
 239 C<data>
 240
 241 A code reference to a private data constructor.
 242 It is called each time this magic is cast on a variable, and the scalar returned is used as private data storage for it.
 243 C<$_[0]> is a reference to the magic object and C<@_[1 .. @_-1]> are all extra arguments that were passed to L</cast>.
 244
 245 =item *
 246
 247 C<get>, C<set>, C<len>, C<clear>, C<free>, C<copy>, C<local>, C<fetch>, C<store>, C<exists> and C<delete>
 248
 249 Code references to the corresponding magic callbacks.
 250 You don't have to specify all of them : the magic associated with undefined entries simply won't be hooked.
 251 In those callbacks, C<$_[0]> is always a reference to the magic object and C<$_[1]> is always the private data (or C<undef> when no private data constructor was supplied).
 252
 253 Moreover, when you pass C<< op_info => $num >> to C<wizard>, the last element of C<@_> will be the current op name if C<$num == VMG_OP_INFO_NAME> and a C<B::OP> object representing the current op if C<$num == VMG_OP_INFO_OBJECT>.
 254 Both have a performance hit, but just getting the name is lighter than getting the op object.
 255
 256 Other arguments are specific to the magic hooked :
 257
 258 =over 8
 259
 260 =item *
 261
 262 C<len>
 263
 264 When the variable is an array or a scalar, C<$_[2]> contains the non-magical length.
 265 The callback can return the new scalar or array length to use, or C<undef> to default to the normal length.
 266
 267 =item *
 268
 269 C<copy>
 270
 271 C<$_[2]> is a either a copy or an alias of the current key, which means that it is useless to try to change or cast magic on it.
 272 C<$_[3]> is an alias to the current element (i.e. the value).
 273
 274 =item *
 275
 276 C<fetch>, C<store>, C<exists> and C<delete>
 277
 278 C<$_[2]> is an alias to the current key.
 279 Nothing prevents you from changing it, but be aware that there lurk dangerous side effects.
 280 For example, it may righteously be readonly if the key was a bareword.
 281 You can get a copy instead by passing C<< copy_key => 1 >> to L</wizard>, which allows you to safely assign to C<$_[2]> in order to e.g. redirect the action to another key.
 282 This however has a little performance drawback because of the copy.
 283
 284 =back
 285
 286 All the callbacks are expected to return an integer, which is passed straight to the perl magic API.
 287 However, only the return value of the C<len> callback currently holds a meaning.
 288
 289 =back
 290
 291     # A simple scalar tracer
 292     my $wiz = wizard get  => sub { print STDERR "got ${$_[0]}\n" },
 293                      set  => sub { print STDERR "set to ${$_[0]}\n" },
 294                      free => sub { print STDERR "${$_[0]} was deleted\n" }
 295
 296 Note that C<free> callbacks are I<never> called during global destruction, as there's no way to ensure that the wizard and the C<free> coderef weren't destroyed before the scalar.
 297
 298 =cut
 299
 300 sub wizard {
 301  croak 'Wrong number of arguments for wizard()' if @_ % 2;
 302  my %opts = @_;
 303  my @keys = qw/sig data op_info get set len clear free/;
 304  push @keys, 'copy'  if MGf_COPY;
 305  push @keys, 'dup'   if MGf_DUP;
 306  push @keys, 'local' if MGf_LOCAL;
 307  push @keys, qw/fetch store exists delete copy_key/ if VMG_UVAR;
 308  my $ret = eval { _wizard(map $opts{$_}, @keys) };
 309  if (my $err = $@) {
 310   $err =~ s/\sat\s+.*?\n//;
 311   croak $err;
 312  }
 313  return $ret;
 314 }
 315
 316 =head2 C<gensig>
 317
 318 With this tool, you can manually generate random magic signature between SIG_MIN and SIG_MAX inclusive.
 319 That's the way L</wizard> creates them when no signature is supplied.
 320
 321     # Generate a signature
 322     my $sig = gensig;
 323
 324 =head2 C<getsig>
 325
 326     getsig $wiz
 327
 328 This accessor returns the magic signature of this wizard.
 329
 330     # Get $wiz signature
 331     my $sig = getsig $wiz;
 332
 333 =head2 C<cast>
 334
 335     cast [$@%&*]var, [$wiz|$sig], ...
 336
 337 This function associates C<$wiz> magic to the variable supplied, without overwriting any other kind of magic.
 338 You can also supply the numeric signature C<$sig> instead of C<$wiz>.
 339 It returns true on success or when C<$wiz> magic is already present, C<0> on error, and C<undef> when no magic corresponds to the given signature (in case C<$sig> was supplied).
 340 All extra arguments specified after C<$wiz> are passed to the private data constructor.
 341 If the variable isn't a hash, any C<uvar> callback of the wizard is safely ignored.
 342
 343     # Casts $wiz onto $x. If $wiz isn't a signature, undef can't be returned.
 344     my $x;
 345     die 'error' unless cast $x, $wiz;
 346
 347 The C<var> argument can be an array or hash value.
 348 Magic for those behaves like for any other scalar, except that it is dispelled when the entry is deleted from the container.
 349 For example, if you want to call C<POSIX::tzset> each time the C<'TZ'> environment variable is changed in C<%ENV>, you can use :
 350
 351     use POSIX;
 352     cast $ENV{TZ}, wizard set => sub { POSIX::tzset(); () };
 353
 354 If you want to overcome the possible deletion of the C<'TZ'> entry, you have no choice but to rely on C<store> uvar magic.
 355
 356 C<cast> can be called from any magical callback, and in particular from C<data>.
 357 This allows you to recursively cast magic on datastructures :
 358
 359     my $wiz;
 360     $wiz = wizard
 361             data => sub {
 362              my ($var, $depth) = @_;
 363              $depth ||= 0;
 364              my $r = ref $var;
 365              if ($r eq 'ARRAY') {
 366               &cast((ref() ? $_ : \$_), $wiz, $depth + 1) for @$var;
 367              } elsif ($r eq 'HASH') {
 368               &cast((ref() ? $_ : \$_), $wiz, $depth + 1) for values %$var;
 369              }
 370              return $depth;
 371             },
 372             free => sub {
 373              my ($var, $depth) = @_;
 374              my $r = ref $var;
 375              print "free $r at depth $depth\n";
 376              ();
 377             };
 378
 379     {
 380      my %h = (
 381       a => [ 1, 2 ],
 382       b => { c => 3 }
 383      );
 384      cast %h, $wiz;
 385     }
 386
 387 When C<%h> goes out of scope, this will print something among the lines of :
 388
 389     free HASH at depth 0
 390     free HASH at depth 1
 391     free SCALAR at depth 2
 392     free ARRAY at depth 1
 393     free SCALAR at depth 3
 394     free SCALAR at depth 3
 395
 396 Of course, this example does nothing with the values that are added after the C<cast>.
 397
 398 =head2 C<getdata>
 399
 400     getdata [$@%&*]var, [$wiz|$sig]
 401
 402 This accessor fetches the private data associated with the magic C<$wiz> (or the signature C<$sig>) in the variable.
 403 C<undef> is returned when no such magic or data is found, or when C<$sig> does not represent a current valid magic object.
 404
 405     # Get the attached data.
 406     my $data = getdata $x, $wiz or die 'no such magic or magic has no data';
 407
 408 =head2 C<dispell>
 409
 410     dispell [$@%&*]variable, [$wiz|$sig]
 411
 412 The exact opposite of L</cast> : it dissociates C<$wiz> magic from the variable.
 413 You can also pass the magic signature C<$sig> as the second argument.
 414 True is returned on success, C<0> on error or when no magic represented by C<$wiz> could be found in the variable, and C<undef> when no magic corresponds to the given signature (in case C<$sig> was supplied).
 415
 416     # Dispell now. If $wiz isn't a signature, undef can't be returned.
 417     die 'no such magic or error' unless dispell $x, $wiz;
 418
 419 =head1 CONSTANTS
 420
 421 =head2 C<SIG_MIN>
 422
 423 The minimum integer used as a signature for user-defined magic.
 424
 425 =head2 C<SIG_MAX>
 426
 427 The maximum integer used as a signature for user-defined magic.
 428
 429 =head2 C<SIG_NBR>
 430
 431     SIG_NBR = SIG_MAX - SIG_MIN + 1
 432
 433 =head2 C<MGf_COPY>
 434
 435 Evaluates to true iff the 'copy' magic is available.
 436
 437 =head2 C<MGf_DUP>
 438
 439 Evaluates to true iff the 'dup' magic is available.
 440
 441 =head2 C<MGf_LOCAL>
 442
 443 Evaluates to true iff the 'local' magic is available.
 444
 445 =head2 C<VMG_UVAR>
 446
 447 When this constant is true, you can use the C<fetch,store,exists,delete> callbacks on hashes.
 448
 449 =head2 C<VMG_COMPAT_ARRAY_PUSH_NOLEN>
 450
 451 True for perls that don't call 'len' magic when you push an element in a magical array.
 452
 453 =head2 C<VMG_COMPAT_ARRAY_UNSHIFT_NOLEN_VOID>
 454
 455 True for perls that don't call 'len' magic when you unshift in void context an element in a magical array.
 456
 457 =head2 C<VMG_COMPAT_ARRAY_UNDEF_CLEAR>
 458
 459 True for perls that call 'clear' magic when undefining magical arrays.
 460
 461 =head2 C<VMG_COMPAT_SCALAR_LENGTH_NOLEN>
 462
 463 True for perls that don't call 'len' magic when taking the C<length> of a magical scalar.
 464
 465 =head2 C<VMG_PERL_PATCHLEVEL>
 466
 467 The perl patchlevel this module was built with, or C<0> for non-debugging perls.
 468
 469 =head2 C<VMG_THREADSAFE>
 470
 471 True iff this module could have been built with thread-safety features enabled.
 472
 473 =head2 C<VMG_OP_INFO_NAME>
 474
 475 Value to pass with C<op_info> to get the current op name in the magic callbacks.
 476
 477 =head2 C<VMG_OP_INFO_OBJECT>
 478
 479 Value to pass with C<op_info> to get a C<B::OP> object representing the current op in the magic callbacks.
 480
 481 =head1 PERL MAGIC HISTORY
 482
 483 The places where magic is invoked have changed a bit through perl history.
 484 Here's a little list of the most recent ones.
 485
 486 =over 4
 487
 488 =item *
 489
 490 B<5.6.x>
 491
 492 I<p14416> : 'copy' and 'dup' magic.
 493
 494 =item *
 495
 496 B<5.8.9>
 497
 498 I<p28160> : Integration of I<p25854> (see below).
 499
 500 I<p32542> : Integration of I<p31473> (see below).
 501
 502 =item *
 503
 504 B<5.9.3>
 505
 506 I<p25854> : 'len' magic is no longer called when pushing an element into a magic array.
 507
 508 I<p26569> : 'local' magic.
 509
 510 =item *
 511
 512 B<5.9.5>
 513
 514 I<p31064> : Meaningful 'uvar' magic.
 515
 516 I<p31473> : 'clear' magic wasn't invoked when undefining an array.
 517 The bug is fixed as of this version.
 518
 519 =item *
 520
 521 B<5.10.0>
 522
 523 Since C<PERL_MAGIC_uvar> is uppercased, C<hv_magic_check()> triggers 'copy' magic on hash stores for (non-tied) hashes that also have 'uvar' magic.
 524
 525 =item *
 526
 527 B<5.11.x>
 528
 529 I<p32969> : 'len' magic is no longer invoked when calling C<length> with a magical scalar.
 530
 531 I<p34908> : 'len' magic is no longer called when pushing / unshifting an element into a magical array in void context.
 532 The C<push> part was already covered by I<p25854>.
 533
 534 =back
 535
 536 =head1 EXPORT
 537
 538 The functions L</wizard>, L</gensig>, L</getsig>, L</cast>, L</getdata> and L</dispell> are only exported on request.
 539 All of them are exported by the tags C<':funcs'> and C<':all'>.
 540
 541 All the constants are also only exported on request, either individually or by the tags C<':consts'> and C<':all'>.
 542
 543 =cut
 544
 545 use base qw/Exporter/;
 546
 547 our @EXPORT         = ();
 548 our %EXPORT_TAGS    = (
 549  'funcs' =>  [ qw/wizard gensig getsig cast getdata dispell/ ],
 550  'consts' => [
 551                qw/SIG_MIN SIG_MAX SIG_NBR MGf_COPY MGf_DUP MGf_LOCAL VMG_UVAR/,
 552                qw/VMG_COMPAT_ARRAY_PUSH_NOLEN VMG_COMPAT_ARRAY_UNSHIFT_NOLEN_VOID VMG_COMPAT_ARRAY_UNDEF_CLEAR VMG_COMPAT_SCALAR_LENGTH_NOLEN/,
 553                qw/VMG_PERL_PATCHLEVEL/,
 554                qw/VMG_THREADSAFE/,
 555                qw/VMG_OP_INFO_NAME VMG_OP_INFO_OBJECT/
 556              ]
 557 );
 558 our @EXPORT_OK      = map { @$_ } values %EXPORT_TAGS;
 559 $EXPORT_TAGS{'all'} = [ @EXPORT_OK ];
 560
 561 =head1 CAVEATS
 562
 563 If you store a magic object in the private data slot, the magic won't be accessible by L</getdata> since it's not copied by assignment.
 564 The only way to address this would be to return a reference.
 565
 566 If you define a wizard with a C<free> callback and cast it on itself, this destructor won't be called because the wizard will be destroyed first.
 567
 568 =head1 DEPENDENCIES
 569
 570 L<perl> 5.8.
 571
 572 L<Carp> (standard since perl 5), L<XSLoader> (standard since perl 5.006).
 573
 574 Copy tests need L<Tie::Array> (standard since perl 5.005) and L<Tie::Hash> (since 5.002).
 575
 576 Some uvar tests need L<Hash::Util::FieldHash> (standard since perl 5.009004).
 577
 578 Glob tests need L<Symbol> (standard since perl 5.002).
 579
 580 Threads tests need L<threads> and L<threads::shared>.
 581
 582 =head1 SEE ALSO
 583
 584 L<perlguts> and L<perlapi> for internal information about magic.
 585
 586 L<perltie> and L<overload> for other ways of enhancing objects.
 587
 588 =head1 AUTHOR
 589
 590 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 591
 592 You can contact me by mail or on C<irc.perl.org> (vincent).
 593
 594 =head1 BUGS
 595
 596 Please report any bugs or feature requests to C<bug-variable-magic at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Variable-Magic>. I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 597
 598 =head1 SUPPORT
 599
 600 You can find documentation for this module with the perldoc command.
 601
 602     perldoc Variable::Magic
 603
 604 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Variable-Magic>.
 605
 606 =head1 COPYRIGHT & LICENSE
 607
 608 Copyright 2007-2009 Vincent Pit, all rights reserved.
 609
 610 This program is free software; you can redistribute it and/or modify it
 611 under the same terms as Perl itself.
 612
 613 =cut
 614
 615 1; # End of Variable::Magic