lib/Variable/Magic.pm

   1 package Variable::Magic;
   2
   3 use 5.007003;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp qw/croak/;
   9
  10 =head1 NAME
  11
  12 Variable::Magic - Associate user-defined magic to variables from Perl.
  13
  14 =head1 VERSION
  15
  16 Version 0.25
  17
  18 =cut
  19
  20 our $VERSION;
  21 BEGIN {
  22  $VERSION = '0.25';
  23 }
  24
  25 =head1 SYNOPSIS
  26
  27     use Variable::Magic qw/wizard cast dispell/;
  28
  29     my $wiz = wizard set => sub { print STDERR "now set to ${$_[0]}!\n" };
  30     my $a = 1;
  31     cast $a, $wiz;
  32     $a = 2;          # "now set to 2!"
  33     dispell $a, $wiz;
  34     $a = 3           # (nothing)
  35
  36 =head1 DESCRIPTION
  37
  38 Magic is Perl way of enhancing objects. This mechanism let the user add extra data to any variable and hook syntaxical operations (such as access, assignation or destruction) that can be applied to it. With this module, you can add your own magic to any variable without the pain of the C API.
  39
  40 Magic differs from tieing and overloading in several ways :
  41
  42 =over 4
  43
  44 =item *
  45
  46 Magic isn't copied on assignation (as for blessed references) : you attach it to variables, not values.
  47
  48 =item *
  49
  50 It doesn't replace the original semantics : magic callbacks trigger before the original action take place, and can't prevent it to happen.
  51
  52 =item *
  53
  54 It's mostly invisible at the Perl level : magical and non-magical variables cannot be distinguished with C<ref>, C<reftype> or another trick.
  55
  56 =item *
  57
  58 It's notably faster, since perl's way of handling magic is lighter by nature, and there's no need for any method resolution.
  59
  60 =back
  61
  62 The operations that can be overloaded are :
  63
  64 =over 4
  65
  66 =item *
  67
  68 C<get>
  69
  70 This magic is invoked when the variable is evaluated (does not include array/hash subscripts and slices).
  71
  72 =item *
  73
  74 C<set>
  75
  76 This one is triggered each time the value of the variable changes (includes array/hash subscripts and slices).
  77
  78 =item *
  79
  80 C<len>
  81
  82 This magic is a little special : it is called when the 'size' or the 'length' of the variable has to be known by Perl. Typically, it's the magic involved when an array is evaluated in scalar context, but also on array assignation and loops (C<for>, C<map> or C<grep>). The callback has then to return the length as an integer.
  83
  84 =item *
  85
  86 C<clear>
  87
  88 This magic is invoked when the variable is reset, such as when an array is emptied. Please note that this is different from undefining the variable, even though the magic is called when the clearing is a result of the undefine (e.g. for an array, but actually a bug prevent it to work before perl 5.9.5 - see the L<history|/PERL MAGIC HISTORY>).
  89
  90 =item *
  91
  92 C<free>
  93
  94 This one can be considered as an object destructor. It happens when the variable goes out of scope (with the exception of global scope), but not when it is undefined.
  95
  96 =item *
  97
  98 C<copy>
  99
 100 This magic only applies to tied arrays and hashes. It fires when you try to access or change their elements. It is available on your perl iff C<MGf_COPY> is true.
 101
 102 =item *
 103
 104 C<dup>
 105
 106 Invoked when the variable is cloned across threads. Currently not available.
 107
 108 =item *
 109
 110 C<local>
 111
 112 When this magic is set on a variable, all subsequent localizations of the variable will trigger the callback. It is available on your perl iff C<MGf_LOCAL> is true.
 113
 114 =back
 115
 116 The following actions only apply to hashes and are available iff C<VMG_UVAR> is true. They are referred to as C<uvar> magics.
 117
 118 =over 4
 119
 120 =item *
 121
 122 C<fetch>
 123
 124 This magic happens each time an element is fetched from the hash.
 125
 126 =item *
 127
 128 C<store>
 129
 130 This one is called when an element is stored into the hash.
 131
 132 =item *
 133
 134 C<exists>
 135
 136 This magic fires when a key is tested for existence in the hash.
 137
 138 =item *
 139
 140 C<delete>
 141
 142 This last one triggers when a key is deleted in the hash, regardless of whether the key actually exists in it.
 143
 144 =back
 145
 146 You can refer to the tests to have more insight of where the different magics are invoked.
 147
 148 To prevent any clash between different magics defined with this module, an unique numerical signature is attached to each kind of magic (i.e. each set of callbacks for magic operations).
 149
 150 =head1 PERL MAGIC HISTORY
 151
 152 The places where magic is invoked have changed a bit through perl history. Here's a little list of the most recent ones.
 153
 154 =over 4
 155
 156 =item *
 157
 158 B<5.6.x>
 159
 160 I<p14416> : 'copy' and 'dup' magic.
 161
 162 =item *
 163
 164 B<5.8.9>
 165
 166 I<p28160> : Integration of I<p25854> (see below).
 167
 168 I<p32542> : Integration of I<p31473> (see below).
 169
 170 =item *
 171
 172 B<5.9.3>
 173
 174 I<p25854> : 'len' magic is no longer called when pushing an element into a magic array.
 175
 176 I<p26569> : 'local' magic.
 177
 178 =item *
 179
 180 B<5.9.5>
 181
 182 I<p31064> : Meaningful 'uvar' magic.
 183
 184 I<p31473> : 'clear' magic wasn't invoked when undefining an array. The bug is fixed as of this version.
 185
 186 =item *
 187
 188 B<5.10.0>
 189
 190 Since C<PERL_MAGIC_uvar> is uppercased, C<hv_magic_check()> triggers 'copy' magic on hash stores for (non-tied) hashes that also have 'uvar' magic.
 191
 192 =item *
 193
 194 B<5.11.x>
 195
 196 I<p32969> : 'len' magic is no longer invoked when calling C<length> with a magical scalar.
 197
 198 =back
 199
 200 =head1 CONSTANTS
 201
 202 =head2 C<SIG_MIN>
 203
 204 The minimum integer used as a signature for user-defined magic.
 205
 206 =head2 C<SIG_MAX>
 207
 208 The maximum integer used as a signature for user-defined magic.
 209
 210 =head2 C<SIG_NBR>
 211
 212     SIG_NBR = SIG_MAX - SIG_MIN + 1
 213
 214 =head2 C<MGf_COPY>
 215
 216 Evaluates to true iff the 'copy' magic is available.
 217
 218 =head2 C<MGf_DUP>
 219
 220 Evaluates to true iff the 'dup' magic is available.
 221
 222 =head2 C<MGf_LOCAL>
 223
 224 Evaluates to true iff the 'local' magic is available.
 225
 226 =head2 C<VMG_UVAR>
 227
 228 When this constant is true, you can use the C<fetch,store,exists,delete> callbacks on hashes.
 229
 230 =head2 C<VMG_COMPAT_ARRAY_PUSH_NOLEN>
 231
 232 True for perls that don't call 'len' magic when you push an element in a magical array.
 233
 234 =head2 C<VMG_COMPAT_ARRAY_UNDEF_CLEAR>
 235
 236 True for perls that call 'clear' magic when undefining magical arrays.
 237
 238 =head2 C<VMG_COMPAT_SCALAR_LENGTH_NOLEN>
 239
 240 True for perls that don't call 'len' magic when taking the C<length> of a magical scalar.
 241
 242 =head2 C<VMG_PERL_PATCHLEVEL>
 243
 244 The perl patchlevel this module was built with, or C<0> for non-debugging perls.
 245
 246 =head2 C<VMG_THREADSAFE>
 247
 248 True iff this module could have been built with thread-safety features enabled.
 249
 250 =head1 FUNCTIONS
 251
 252 =cut
 253
 254 BEGIN {
 255  require XSLoader;
 256  XSLoader::load(__PACKAGE__, $VERSION);
 257 }
 258
 259 =head2 C<wizard>
 260
 261     wizard sig    => ...,
 262            data   => sub { ... },
 263            get    => sub { my ($ref, $data) = @_; ... },
 264            set    => sub { my ($ref, $data) = @_; ... },
 265            len    => sub { my ($ref, $data, $len) = @_; ... ; return $newlen; },
 266            clear  => sub { my ($ref, $data) = @_; ... },
 267            free   => sub { my ($ref, $data) = @_, ... },
 268            copy   => sub { my ($ref, $data, $key, $elt) = @_; ... },
 269            local  => sub { my ($ref, $data) = @_; ... },
 270            fetch  => sub { my ($ref, $data, $key) = @_; ... },
 271            store  => sub { my ($ref, $data, $key) = @_; ... },
 272            exists => sub { my ($ref, $data, $key) = @_; ... },
 273            delete => sub { my ($ref, $data, $key) = @_; ... }
 274
 275 This function creates a 'wizard', an opaque type that holds the magic information. It takes a list of keys / values as argument, whose keys can be :
 276
 277 =over 4
 278
 279 =item *
 280
 281 C<sig>
 282
 283 The numerical signature. If not specified or undefined, a random signature is generated. If the signature matches an already defined magic, then the existant magic object is returned.
 284
 285 =item *
 286
 287 C<data>
 288
 289 A code reference to a private data constructor. It is called each time this magic is cast on a variable, and the scalar returned is used as private data storage for it. C<$_[0]> is a reference to the magic object and C<@_[1 .. @_-1]> are all extra arguments that were passed to L</cast>.
 290
 291 =item *
 292
 293 C<get>, C<set>, C<len>, C<clear>, C<free>, C<copy>, C<local>, C<fetch>, C<store>, C<exists> and C<delete>
 294
 295 Code references to corresponding magic callbacks. You don't have to specify all of them : the magic associated with undefined entries simply won't be hooked. In those callbacks, C<$_[0]> is always a reference to the magic object and C<$_[1]> is always the private data (or C<undef> when no private data constructor was supplied). In the special case of C<len> magic and when the variable is an array, C<$_[2]> contains its normal length. C<$_[2]> is the current key in C<copy>, C<fetch>, C<store>, C<exists> and C<delete> callbacks, although for C<copy> it may just be a copy of the actual key so it's useless to (for example) cast magic on it. C<copy> magic also receives the current element (i.e. the value) in C<$_[3]>.
 296
 297 =back
 298
 299     # A simple scalar tracer
 300     my $wiz = wizard get  => sub { print STDERR "got ${$_[0]}\n" },
 301                      set  => sub { print STDERR "set to ${$_[0]}\n" },
 302                      free => sub { print STDERR "${$_[0]} was deleted\n" }
 303
 304 =cut
 305
 306 sub wizard {
 307  croak 'Wrong number of arguments for wizard()' if @_ % 2;
 308  my %opts = @_;
 309  my @cbs  = qw/sig data get set len clear free/;
 310  push @cbs, 'copy'  if MGf_COPY;
 311  push @cbs, 'dup'   if MGf_DUP;
 312  push @cbs, 'local' if MGf_LOCAL;
 313  push @cbs, qw/fetch store exists delete/ if VMG_UVAR;
 314  my $ret = eval { _wizard(map $opts{$_}, @cbs) };
 315  if (my $err = $@) {
 316   $err =~ s/\sat\s+.*?\n//;
 317   croak $err;
 318  }
 319  return $ret;
 320 }
 321
 322 =head2 C<gensig>
 323
 324 With this tool, you can manually generate random magic signature between SIG_MIN and SIG_MAX inclusive. That's the way L</wizard> creates them when no signature is supplied.
 325
 326     # Generate a signature
 327     my $sig = gensig;
 328
 329 =head2 C<getsig>
 330
 331     getsig $wiz
 332
 333 This accessor returns the magic signature of this wizard.
 334
 335     # Get $wiz signature
 336     my $sig = getsig $wiz;
 337
 338 =head2 C<cast>
 339
 340     cast [$@%&*]var, [$wiz|$sig], ...
 341
 342 This function associates C<$wiz> magic to the variable supplied, without overwriting any other kind of magic. You can also supply the numeric signature C<$sig> instead of C<$wiz>. It returns true on success or when C<$wiz> magic is already present, C<0> on error, and C<undef> when no magic corresponds to the given signature (in case C<$sig> was supplied). All extra arguments specified after C<$wiz> are passed to the private data constructor. If the variable isn't a hash, any C<uvar> callback of the wizard is safely ignored.
 343
 344     # Casts $wiz onto $x. If $wiz isn't a signature, undef can't be returned.
 345     my $x;
 346     die 'error' unless cast $x, $wiz;
 347
 348 =head2 C<getdata>
 349
 350     getdata [$@%&*]var, [$wiz|$sig]
 351
 352 This accessor fetches the private data associated with the magic C<$wiz> (or the signature C<$sig>) in the variable. C<undef> is returned when no such magic or data is found, or when C<$sig> does not represent a current valid magic object.
 353
 354     # Get the attached data.
 355     my $data = getdata $x, $wiz or die 'no such magic or magic has no data';
 356
 357 =head2 C<dispell>
 358
 359     dispell [$@%&*]variable, [$wiz|$sig]
 360
 361 The exact opposite of L</cast> : it dissociates C<$wiz> magic from the variable. You can also pass the magic signature C<$sig> as the second argument. True is returned on success, C<0> on error or when no magic represented by C<$wiz> could be found in the variable, and C<undef> when no magic corresponds to the given signature (in case C<$sig> was supplied).
 362
 363     # Dispell now. If $wiz isn't a signature, undef can't be returned.
 364     die 'no such magic or error' unless dispell $x, $wiz;
 365
 366 =head1 EXPORT
 367
 368 The functions L</wizard>, L</gensig>, L</getsig>, L</cast>, L</getdata> and L</dispell> are only exported on request. All of them are exported by the tags C<':funcs'> and C<':all'>.
 369
 370 The constants L</SIG_MIN>, L</SIG_MAX>, L</SIG_NBR>, L</MGf_COPY>, L</MGf_DUP>, L</MGf_LOCAL> and L</VMG_UVAR> are also only exported on request. They are all exported by the tags C<':consts'> and C<':all'>.
 371
 372 =cut
 373
 374 use base qw/Exporter/;
 375
 376 our @EXPORT         = ();
 377 our %EXPORT_TAGS    = (
 378  'funcs' =>  [ qw/wizard gensig getsig cast getdata dispell/ ],
 379  'consts' => [ qw/SIG_MIN SIG_MAX SIG_NBR MGf_COPY MGf_DUP MGf_LOCAL VMG_UVAR/,
 380                qw/VMG_COMPAT_ARRAY_PUSH_NOLEN VMG_COMPAT_ARRAY_UNDEF_CLEAR/,
 381                qw/VMG_COMPAT_SCALAR_LENGTH_NOLEN/,
 382                qw/VMG_PERL_PATCHLEVEL/,
 383                qw/VMG_THREADSAFE/ ]
 384 );
 385 our @EXPORT_OK      = map { @$_ } values %EXPORT_TAGS;
 386 $EXPORT_TAGS{'all'} = [ @EXPORT_OK ];
 387
 388 =head1 CAVEATS
 389
 390 If you store a magic object in the private data slot, the magic won't be accessible by L</getdata> since it's not copied by assignation. The only way to address this would be to return a reference.
 391
 392 If you define a wizard with a C<free> callback and cast it on itself, this destructor won't be called because the wizard will be destroyed first.
 393
 394 =head1 DEPENDENCIES
 395
 396 L<perl> 5.7.3.
 397
 398 L<Carp> (standard since perl 5), L<XSLoader> (standard since perl 5.006).
 399
 400 Copy tests need L<Tie::Array> (standard since perl 5.005) and L<Tie::Hash> (since 5.002).
 401
 402 Some uvar tests need L<Hash::Util::FieldHash> (standard since perl 5.009004).
 403
 404 Glob tests need L<Symbol> (standard since perl 5.002).
 405
 406 Threads tests need L<threads> and L<threads::shared>.
 407
 408 =head1 SEE ALSO
 409
 410 L<perlguts> and L<perlapi> for internal information about magic.
 411
 412 L<perltie> and L<overload> for other ways of enhancing objects.
 413
 414 =head1 AUTHOR
 415
 416 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 417
 418 You can contact me by mail or on C<irc.perl.org> (vincent).
 419
 420 =head1 BUGS
 421
 422 Please report any bugs or feature requests to C<bug-variable-magic at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Variable-Magic>. I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 423
 424 =head1 SUPPORT
 425
 426 You can find documentation for this module with the perldoc command.
 427
 428     perldoc Variable::Magic
 429
 430 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Variable-Magic>.
 431
 432 =head1 COPYRIGHT & LICENSE
 433
 434 Copyright 2007-2008 Vincent Pit, all rights reserved.
 435
 436 This program is free software; you can redistribute it and/or modify it
 437 under the same terms as Perl itself.
 438
 439 =cut
 440
 441 1; # End of Variable::Magic