lib/Variable/Magic.pm

   1 package Variable::Magic;
   2
   3 use 5.007003;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp qw/croak/;
   9
  10 =head1 NAME
  11
  12 Variable::Magic - Associate user-defined magic to variables from Perl.
  13
  14 =head1 VERSION
  15
  16 Version 0.24
  17
  18 =cut
  19
  20 our $VERSION;
  21 BEGIN {
  22  $VERSION = '0.24';
  23 }
  24
  25 =head1 SYNOPSIS
  26
  27     use Variable::Magic qw/wizard cast dispell/;
  28
  29     my $wiz = wizard set => sub { print STDERR "now set to ${$_[0]}!\n" };
  30     my $a = 1;
  31     cast $a, $wiz;
  32     $a = 2;          # "now set to 2!"
  33     dispell $a, $wiz;
  34     $a = 3           # (nothing)
  35
  36 =head1 DESCRIPTION
  37
  38 Magic is Perl way of enhancing objects. This mechanism let the user add extra data to any variable and hook syntaxical operations (such as access, assignation or destruction) that can be applied to it. With this module, you can add your own magic to any variable without the pain of the C API.
  39
  40 Magic differs from tieing and overloading in several ways :
  41
  42 =over 4
  43
  44 =item *
  45
  46 Magic isn't copied on assignation (as for blessed references) : you attach it to variables, not values.
  47
  48 =item *
  49
  50 It doesn't replace the original semantics : magic callbacks trigger before the original action take place, and can't prevent it to happen.
  51
  52 =item *
  53
  54 It's mostly invisible at the Perl level : magical and non-magical variables cannot be distinguished with C<ref>, C<reftype> or another trick.
  55
  56 =item *
  57
  58 It's notably faster, since perl's way of handling magic is lighter by nature, and there's no need for any method resolution.
  59
  60 =back
  61
  62 The operations that can be overloaded are :
  63
  64 =over 4
  65
  66 =item *
  67
  68 C<get>
  69
  70 This magic is invoked when the variable is evaluated (does not include array/hash subscripts and slices).
  71
  72 =item *
  73
  74 C<set>
  75
  76 This one is triggered each time the value of the variable changes (includes array/hash subscripts and slices).
  77
  78 =item *
  79
  80 C<len>
  81
  82 This magic is a little special : it is called when the 'size' or the 'length' of the variable has to be known by Perl. Typically, it's the magic involved when an array is evaluated in scalar context, but also on array assignation and loops (C<for>, C<map> or C<grep>). The callback has then to return the length as an integer.
  83
  84 =item *
  85
  86 C<clear>
  87
  88 This magic is invoked when the variable is reset, such as when an array is emptied. Please note that this is different from undefining the variable, even though the magic is called when the clearing is a result of the undefine (e.g. for an array, but actually a bug prevent it to work before perl 5.9.5 - see the L<history|/PERL MAGIC HISTORY>).
  89
  90 =item *
  91
  92 C<free>
  93
  94 This one can be considered as an object destructor. It happens when the variable goes out of scope (with the exception of global scope), but not when it is undefined.
  95
  96 =item *
  97
  98 C<copy>
  99
 100 This magic only applies to tied arrays and hashes. It fires when you try to access or change their elements. It is available on your perl iff C<MGf_COPY> is true.
 101
 102 =item *
 103
 104 C<dup>
 105
 106 Invoked when the variable is cloned across threads. Currently not available.
 107
 108 =item *
 109
 110 C<local>
 111
 112 When this magic is set on a variable, all subsequent localizations of the variable will trigger the callback. It is available on your perl iff C<MGf_LOCAL> is true.
 113
 114 =back
 115
 116 The following actions only apply to hashes and are available iff C<VMG_UVAR> is true. They are referred to as C<uvar> magics.
 117
 118 =over 4
 119
 120 =item *
 121
 122 C<fetch>
 123
 124 This magic happens each time an element is fetched from the hash.
 125
 126 =item *
 127
 128 C<store>
 129
 130 This one is called when an element is stored into the hash.
 131
 132 =item *
 133
 134 C<exists>
 135
 136 This magic fires when a key is tested for existence in the hash.
 137
 138 =item *
 139
 140 C<delete>
 141
 142 This last one triggers when a key is deleted in the hash, regardless of whether the key actually exists in it.
 143
 144 =back
 145
 146 You can refer to the tests to have more insight of where the different magics are invoked.
 147
 148 To prevent any clash between different magics defined with this module, an unique numerical signature is attached to each kind of magic (i.e. each set of callbacks for magic operations).
 149
 150 =head1 PERL MAGIC HISTORY
 151
 152 The places where magic is invoked have changed a bit through perl history. Here's a little list of the most recent ones.
 153
 154 =over 4
 155
 156 =item *
 157
 158 B<5.6.x>
 159
 160 I<p14416> : 'copy' and 'dup' magic.
 161
 162 =item *
 163
 164 B<5.9.3>
 165
 166 I<p25854> : 'len' magic is no longer called when pushing an element into a magic array.
 167
 168 I<p26569> : 'local' magic.
 169
 170 =item *
 171
 172 B<5.9.5>
 173
 174 I<p31064> : Meaningful 'uvar' magic.
 175
 176 I<p31473> : 'clear' magic wasn't invoked when undefining an array. The bug is fixed as of this version.
 177
 178 =item *
 179
 180 B<5.10.0>
 181
 182 Since C<PERL_MAGIC_uvar> is uppercased, C<hv_magic_check()> triggers 'copy' magic on hash stores for (non-tied) hashes that also have 'uvar' magic.
 183
 184 =item *
 185
 186 B<5.11.x>
 187
 188 I<p32969> : 'len' magic is no longer invoked when calling C<length> with a magical scalar.
 189
 190 =back
 191
 192 =head1 CONSTANTS
 193
 194 =head2 C<SIG_MIN>
 195
 196 The minimum integer used as a signature for user-defined magic.
 197
 198 =head2 C<SIG_MAX>
 199
 200 The maximum integer used as a signature for user-defined magic.
 201
 202 =head2 C<SIG_NBR>
 203
 204     SIG_NBR = SIG_MAX - SIG_MIN + 1
 205
 206 =head2 C<MGf_COPY>
 207
 208 Evaluates to true iff the 'copy' magic is available.
 209
 210 =head2 C<MGf_DUP>
 211
 212 Evaluates to true iff the 'dup' magic is available.
 213
 214 =head2 C<MGf_LOCAL>
 215
 216 Evaluates to true iff the 'local' magic is available.
 217
 218 =head2 C<VMG_UVAR>
 219
 220 When this constant is true, you can use the C<fetch,store,exists,delete> callbacks on hashes.
 221
 222 =head2 C<VMG_COMPAT_ARRAY_PUSH_NOLEN>
 223
 224 True for perls that don't call 'len' magic when you push an element in a magical array.
 225
 226 =head2 C<VMG_COMPAT_ARRAY_UNDEF_CLEAR>
 227
 228 True for perls that call 'clear' magic when undefining magical arrays.
 229
 230 =head2 C<VMG_COMPAT_SCALAR_LENGTH_NOLEN>
 231
 232 True for perls that don't call 'len' magic when taking the C<length> of a magical scalar.
 233
 234 =head2 C<VMG_PERL_PATCHLEVEL>
 235
 236 The perl patchlevel this module was built with, or C<0> for non-debugging perls.
 237
 238 =head2 C<VMG_THREADSAFE>
 239
 240 True iff this module could have been built with thread-safety features enabled.
 241
 242 =head1 FUNCTIONS
 243
 244 =cut
 245
 246 BEGIN {
 247  require XSLoader;
 248  XSLoader::load(__PACKAGE__, $VERSION);
 249 }
 250
 251 =head2 C<wizard>
 252
 253     wizard sig    => ...,
 254            data   => sub { ... },
 255            get    => sub { my ($ref, $data) = @_; ... },
 256            set    => sub { my ($ref, $data) = @_; ... },
 257            len    => sub { my ($ref, $data, $len) = @_; ... ; return $newlen; },
 258            clear  => sub { my ($ref, $data) = @_; ... },
 259            free   => sub { my ($ref, $data) = @_, ... },
 260            copy   => sub { my ($ref, $data, $key, $elt) = @_; ... },
 261            local  => sub { my ($ref, $data) = @_; ... },
 262            fetch  => sub { my ($ref, $data, $key) = @_; ... },
 263            store  => sub { my ($ref, $data, $key) = @_; ... },
 264            exists => sub { my ($ref, $data, $key) = @_; ... },
 265            delete => sub { my ($ref, $data, $key) = @_; ... }
 266
 267 This function creates a 'wizard', an opaque type that holds the magic information. It takes a list of keys / values as argument, whose keys can be :
 268
 269 =over 4
 270
 271 =item *
 272
 273 C<sig>
 274
 275 The numerical signature. If not specified or undefined, a random signature is generated. If the signature matches an already defined magic, then the existant magic object is returned.
 276
 277 =item *
 278
 279 C<data>
 280
 281 A code reference to a private data constructor. It is called each time this magic is cast on a variable, and the scalar returned is used as private data storage for it. C<$_[0]> is a reference to the magic object and C<@_[1 .. @_-1]> are all extra arguments that were passed to L</cast>.
 282
 283 =item *
 284
 285 C<get>, C<set>, C<len>, C<clear>, C<free>, C<copy>, C<local>, C<fetch>, C<store>, C<exists> and C<delete>
 286
 287 Code references to corresponding magic callbacks. You don't have to specify all of them : the magic associated with undefined entries simply won't be hooked. In those callbacks, C<$_[0]> is always a reference to the magic object and C<$_[1]> is always the private data (or C<undef> when no private data constructor was supplied). In the special case of C<len> magic and when the variable is an array, C<$_[2]> contains its normal length. C<$_[2]> is the current key in C<copy>, C<fetch>, C<store>, C<exists> and C<delete> callbacks, although for C<copy> it may just be a copy of the actual key so it's useless to (for example) cast magic on it. C<copy> magic also receives the current element (i.e. the value) in C<$_[3]>.
 288
 289 =back
 290
 291     # A simple scalar tracer
 292     my $wiz = wizard get  => sub { print STDERR "got ${$_[0]}\n" },
 293                      set  => sub { print STDERR "set to ${$_[0]}\n" },
 294                      free => sub { print STDERR "${$_[0]} was deleted\n" }
 295
 296 =cut
 297
 298 sub wizard {
 299  croak 'Wrong number of arguments for wizard()' if @_ % 2;
 300  my %opts = @_;
 301  my @cbs  = qw/sig data get set len clear free/;
 302  push @cbs, 'copy'  if MGf_COPY;
 303  push @cbs, 'dup'   if MGf_DUP;
 304  push @cbs, 'local' if MGf_LOCAL;
 305  push @cbs, qw/fetch store exists delete/ if VMG_UVAR;
 306  my $ret = eval { _wizard(map $opts{$_}, @cbs) };
 307  if (my $err = $@) {
 308   $err =~ s/\sat\s+.*?\n//;
 309   croak $err;
 310  }
 311  return $ret;
 312 }
 313
 314 =head2 C<gensig>
 315
 316 With this tool, you can manually generate random magic signature between SIG_MIN and SIG_MAX inclusive. That's the way L</wizard> creates them when no signature is supplied.
 317
 318     # Generate a signature
 319     my $sig = gensig;
 320
 321 =head2 C<getsig>
 322
 323     getsig $wiz
 324
 325 This accessor returns the magic signature of this wizard.
 326
 327     # Get $wiz signature
 328     my $sig = getsig $wiz;
 329
 330 =head2 C<cast>
 331
 332     cast [$@%&*]var, [$wiz|$sig], ...
 333
 334 This function associates C<$wiz> magic to the variable supplied, without overwriting any other kind of magic. You can also supply the numeric signature C<$sig> instead of C<$wiz>. It returns true on success or when C<$wiz> magic is already present, C<0> on error, and C<undef> when no magic corresponds to the given signature (in case C<$sig> was supplied). All extra arguments specified after C<$wiz> are passed to the private data constructor. If the variable isn't a hash, any C<uvar> callback of the wizard is safely ignored.
 335
 336     # Casts $wiz onto $x. If $wiz isn't a signature, undef can't be returned.
 337     my $x;
 338     die 'error' unless cast $x, $wiz;
 339
 340 =head2 C<getdata>
 341
 342     getdata [$@%&*]var, [$wiz|$sig]
 343
 344 This accessor fetches the private data associated with the magic C<$wiz> (or the signature C<$sig>) in the variable. C<undef> is returned when no such magic or data is found, or when C<$sig> does not represent a current valid magic object.
 345
 346     # Get the attached data.
 347     my $data = getdata $x, $wiz or die 'no such magic or magic has no data';
 348
 349 =head2 C<dispell>
 350
 351     dispell [$@%&*]variable, [$wiz|$sig]
 352
 353 The exact opposite of L</cast> : it dissociates C<$wiz> magic from the variable. You can also pass the magic signature C<$sig> as the second argument. True is returned on success, C<0> on error or when no magic represented by C<$wiz> could be found in the variable, and C<undef> when no magic corresponds to the given signature (in case C<$sig> was supplied).
 354
 355     # Dispell now. If $wiz isn't a signature, undef can't be returned.
 356     die 'no such magic or error' unless dispell $x, $wiz;
 357
 358 =head1 EXPORT
 359
 360 The functions L</wizard>, L</gensig>, L</getsig>, L</cast>, L</getdata> and L</dispell> are only exported on request. All of them are exported by the tags C<':funcs'> and C<':all'>.
 361
 362 The constants L</SIG_MIN>, L</SIG_MAX>, L</SIG_NBR>, L</MGf_COPY>, L</MGf_DUP>, L</MGf_LOCAL> and L</VMG_UVAR> are also only exported on request. They are all exported by the tags C<':consts'> and C<':all'>.
 363
 364 =cut
 365
 366 use base qw/Exporter/;
 367
 368 our @EXPORT         = ();
 369 our %EXPORT_TAGS    = (
 370  'funcs' =>  [ qw/wizard gensig getsig cast getdata dispell/ ],
 371  'consts' => [ qw/SIG_MIN SIG_MAX SIG_NBR MGf_COPY MGf_DUP MGf_LOCAL VMG_UVAR/,
 372                qw/VMG_COMPAT_ARRAY_PUSH_NOLEN VMG_COMPAT_ARRAY_UNDEF_CLEAR/,
 373                qw/VMG_COMPAT_SCALAR_LENGTH_NOLEN/,
 374                qw/VMG_PERL_PATCHLEVEL/,
 375                qw/VMG_THREADSAFE/ ]
 376 );
 377 our @EXPORT_OK      = map { @$_ } values %EXPORT_TAGS;
 378 $EXPORT_TAGS{'all'} = [ @EXPORT_OK ];
 379
 380 =head1 CAVEATS
 381
 382 If you store a magic object in the private data slot, the magic won't be accessible by L</getdata> since it's not copied by assignation. The only way to address this would be to return a reference.
 383
 384 If you define a wizard with a C<free> callback and cast it on itself, this destructor won't be called because the wizard will be destroyed first.
 385
 386 =head1 DEPENDENCIES
 387
 388 L<perl> 5.7.3.
 389
 390 L<Carp> (standard since perl 5), L<XSLoader> (standard since perl 5.006).
 391
 392 Copy tests need L<Tie::Array> (standard since perl 5.005) and L<Tie::Hash> (since 5.002).
 393
 394 Some uvar tests need L<Hash::Util::FieldHash> (standard since perl 5.009004).
 395
 396 Glob tests need L<Symbol> (standard since perl 5.002).
 397
 398 Threads tests need L<threads> and L<threads::shared>.
 399
 400 =head1 SEE ALSO
 401
 402 L<perlguts> and L<perlapi> for internal information about magic.
 403
 404 L<perltie> and L<overload> for other ways of enhancing objects.
 405
 406 =head1 AUTHOR
 407
 408 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 409
 410 You can contact me by mail or on C<irc.perl.org> (vincent).
 411
 412 =head1 BUGS
 413
 414 Please report any bugs or feature requests to C<bug-variable-magic at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Variable-Magic>. I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 415
 416 =head1 SUPPORT
 417
 418 You can find documentation for this module with the perldoc command.
 419
 420     perldoc Variable::Magic
 421
 422 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Variable-Magic>.
 423
 424 =head1 COPYRIGHT & LICENSE
 425
 426 Copyright 2007-2008 Vincent Pit, all rights reserved.
 427
 428 This program is free software; you can redistribute it and/or modify it
 429 under the same terms as Perl itself.
 430
 431 =cut
 432
 433 1; # End of Variable::Magic