lib/Variable/Magic.pm

   1 package Variable::Magic;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Carp qw/croak/;
   7
   8 =head1 NAME
   9
  10 Variable::Magic - Associate user-defined magic to variables from Perl.
  11
  12 =head1 VERSION
  13
  14 Version 0.01
  15
  16 =cut
  17
  18 our $VERSION = '0.01';
  19
  20 =head1 SYNOPSIS
  21
  22     use Variable::Magic qw/wizard cast dispell/;
  23
  24     my $wiz = wizard set => sub { print STDERR "now set to $_[0]!\n" };
  25     my $a = 1;
  26     cast $a, $wiz;
  27     $a = 2;          # "now set to 2!"
  28     dispell $a, $wiz;
  29     $a = 3           # (nothing)
  30
  31 =head1 DESCRIPTION
  32
  33 Magic is Perl way of enhancing objects. This mechanism let the user add extra data to any variable and overload syntaxical operations (such as access, assignation or destruction) that can be applied to it. With this module, you can add your own magic to any variable without the pain of the C API.
  34
  35 The operations that can be overloaded are :
  36
  37 =over 4
  38
  39 =item C<get>
  40
  41 This magic is invoked when the variable is evaluated (does not include array/hash subscripts and slices).
  42
  43 =item C<set>
  44
  45 This one is triggered each time the value of the variable changes (includes array/hash subscripts and slices).
  46
  47 =item C<len>
  48
  49 This magic is a little special : it is called when the 'size' or the 'length' of the variable has to be known by Perl. Typically, it's the magic involved when an array is evaluated in scalar context, but also on array assignation and loops (C<for>, C<map> or C<grep>). The callback has then to return the length as an integer.
  50
  51 =item C<clear>
  52
  53 This magic is invoked when the variable is reset, such as when an array is emptied. Please note that this is different from undefining the variable, even though the magic is called when the reset is a result of the undefine (e.g. for an array).
  54
  55 =item C<free>
  56
  57 This last one can be considered as an object destructor. It happens when the variable goes out of scope (with the exception of global scope), but not when it is undefined.
  58
  59 =back
  60
  61 To prevent any clash between different magics defined with this module, an unique numerical signature is attached to each kind of magic (i.e. each set of callbacks for magic operations).
  62
  63 =head1 CONSTANTS
  64
  65 =head2 C<SIG_MIN>
  66
  67 The minimum integer used as a signature for user-defined magic.
  68
  69 =cut
  70
  71 use constant SIG_MIN => 2 ** 8;
  72
  73 =head2 C<SIG_MAX>
  74
  75 The maximum integer used as a signature for user-defined magic.
  76
  77 =cut
  78
  79 use constant SIG_MAX => 2 ** 16 - 1;
  80
  81 =head2 C<SIG_NBR>
  82
  83     SIG_NBR = SIG_MAX - SIG_MIN + 1
  84
  85 =cut
  86
  87 use constant SIG_NBR => SIG_MAX - SIG_MIN + 1;
  88
  89 =head1 FUNCTIONS
  90
  91 =cut
  92
  93 require XSLoader;
  94
  95 XSLoader::load(__PACKAGE__, $VERSION);
  96
  97 my %wizz;
  98
  99 =head2 C<wizard>
 100
 101     wizard sig => .., data => ..., get => .., set => .., len => .., clear => .., free => ..
 102
 103 This function creates a 'wizard', an opaque type that holds the magic information. It takes a list of keys / values as argument, whose keys can be :
 104
 105 =over 4
 106
 107 =item C<'sig'>
 108
 109 The numerical signature. If not specified or undefined, a random signature is generated.
 110
 111 =item C<'data'>
 112
 113 A code reference to a private data constructor. It will be called each time this magic is cast on a variable, and the scalar returned will be used as private data storage for it.
 114
 115 =item C<'get'>, C<'set'>, C<'len'>, C<'clear'> and C<'free'>
 116
 117 Code references to corresponding magic callbacks. You don't have to specify all of them : the magic associated with undefined entries simply won't be hooked. When the magic variable is an array or a hash, C<$_[0]> is a reference to it, but directly references it otherwise. C<$_[1]> is the private data (or C<undef> when no private data constructor was supplied). In the special case of C<len> magic and when the variable is an array, C<$_[2]> contains its normal length.
 118
 119 =back
 120
 121     # A simple scalar tracer
 122     my $wiz = wizard get  => sub { print STDERR "got $_[0]\n" },
 123                      set  => sub { print STDERR "set to $_[0]\n" },
 124                      free => sub { print STDERR "$_[0] was deleted\n" }
 125
 126 =cut
 127
 128 sub wizard {
 129  croak 'Wrong number of arguments for wizard()' if @_ % 2;
 130  my %opts = @_;
 131  my $sig;
 132  if (defined $opts{sig}) {
 133   $sig = int $opts{sig};
 134   $sig += SIG_MIN if $sig < SIG_MIN;
 135   $sig %= SIG_MAX + 1 if $sig > SIG_MAX;
 136  } else {
 137   $sig = gensig();
 138  }
 139  return _wizard($sig, map { $opts{$_} } qw/get set len clear free data/);
 140 }
 141
 142 =head2 C<gensig>
 143
 144 With this tool, you can manually generate random magic signature between SIG_MIN and SIG_MAX inclusive. That's the way L</wizard> creates them when no signature is supplied.
 145
 146     # Generate a signature
 147     my $sig = gensig;
 148
 149 =cut
 150
 151 sub gensig {
 152  my $sig;
 153  my $used = ~~keys %wizz;
 154  croak 'Too many magic signatures used' if $used == SIG_NBR;
 155  do { $sig = SIG_MIN + int(rand(SIG_NBR)) } while $wizz{$sig};
 156  return $sig;
 157 }
 158
 159 =head2 C<getsig>
 160
 161     getsig $wiz
 162
 163 This accessor returns the magic signature of this wizard.
 164
 165     # Get $wiz signature
 166     my $sig = getsig $wiz;
 167
 168 =head2 C<cast>
 169
 170     cast [$@%&*]var, $wiz
 171
 172 This function associates C<$wiz> magic to the variable supplied, without overwriting any other kind of magic. It returns true on success or when C<$wiz> magic is already present, and false on error.
 173
 174     # Casts $wiz to $x
 175     my $x;
 176     die 'error' unless cast $x, $wiz;
 177
 178 =head2 C<getdata>
 179
 180     getdata [$@%&*]var, $wiz
 181
 182 This accessor fetches the private data associated with the magic C<$wiz> in the variable. C<undef> is returned when no such magic or data is found.
 183
 184 =head2 C<dispell>
 185
 186     dispell [$@%&*]variable, $wiz
 187     dispell [$@%&*]variable, $sig
 188
 189 The exact opposite of L</cast> : it dissociates C<$wiz> magic from the variable. You can also pass the magic signature as the second argument. True is returned on success, and false on error or when no magic represented by C<$wiz> could be found in the variable.
 190
 191     # Dispell now
 192     die 'no such magic or error' unless dispell $x, $wiz;
 193
 194 =head1 EXPORT
 195
 196 The functions L</wizard>, L</gensig>, L</getsig>, L</cast>, L</getdata> and L</dispell> are only exported on request. All of them are exported by the tags C<':funcs'> and C<':all'>.
 197
 198 The constants L</SIG_MIN>, L</SIG_MAX> and L</SIG_NBR> are also only exported on request. They are all exported by the tags C<':consts'> and C<':all'>.
 199
 200 =cut
 201
 202 use base qw/Exporter/;
 203
 204 our @EXPORT         = ();
 205 our %EXPORT_TAGS    = (
 206  'funcs' =>  [ qw/wizard gensig getsig cast getdata dispell/ ],
 207  'consts' => [ qw/SIG_MIN SIG_MAX SIG_NBR/ ]
 208 );
 209 our @EXPORT_OK      = map { @$_ } values %EXPORT_TAGS;
 210 $EXPORT_TAGS{'all'} = \@EXPORT_OK;
 211
 212 =head1 DEPENDENCIES
 213
 214 L<Carp> (standard since perl 5), L<XSLoader> (standard since perl 5.006).
 215
 216 Tests use L<Symbol> (standard since perl 5.002).
 217
 218 =head1 SEE ALSO
 219
 220 L<perlguts> and L<perlapi> for internal information about magic.
 221
 222 =head1 AUTHOR
 223
 224 Vincent Pit, C<< <perl at profvince.com> >>
 225
 226 =head1 BUGS
 227
 228 Please report any bugs or feature requests to
 229 C<bug-variable-magic at rt.cpan.org>, or through the web interface at
 230 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Variable-Magic>.
 231 I will be notified, and then you'll automatically be notified of progress on
 232 your bug as I make changes.
 233
 234 =head1 SUPPORT
 235
 236 You can find documentation for this module with the perldoc command.
 237
 238     perldoc Variable::Magic
 239
 240 =head1 COPYRIGHT & LICENSE
 241
 242 Copyright 2007 Vincent Pit, all rights reserved.
 243
 244 This program is free software; you can redistribute it and/or modify it
 245 under the same terms as Perl itself.
 246
 247 =cut
 248
 249 1; # End of Variable::Magic