lib/Variable/Magic.pm

   1 package Variable::Magic;
   2
   3 use 5.008;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp qw/croak/;
   9
  10 =head1 NAME
  11
  12 Variable::Magic - Associate user-defined magic to variables from Perl.
  13
  14 =head1 VERSION
  15
  16 Version 0.38
  17
  18 =cut
  19
  20 our $VERSION;
  21 BEGIN {
  22  $VERSION = '0.38';
  23 }
  24
  25 =head1 SYNOPSIS
  26
  27     use Variable::Magic qw/wizard cast VMG_OP_INFO_NAME/;
  28
  29     { # A variable tracer
  30      my $wiz = wizard set  => sub { print "now set to ${$_[0]}!\n" },
  31                       free => sub { print "destroyed!\n" };
  32
  33      my $a = 1;
  34      cast $a, $wiz;
  35      $a = 2;        # "now set to 2!"
  36     }               # "destroyed!"
  37
  38     { # A hash with a default value
  39      my $wiz = wizard data     => sub { $_[1] },
  40                       fetch    => sub { $_[2] = $_[1] unless exists $_[0]->{$_[2]}; () },
  41                       store    => sub { print "key $_[2] stored in $_[-1]\n" },
  42                       copy_key => 1,
  43                       op_info  => VMG_OP_INFO_NAME;
  44
  45      my %h = (_default => 0, apple => 2);
  46      cast %h, $wiz, '_default';
  47      print $h{banana}, "\n"; # "0", because the 'banana' key doesn't exist in %h
  48      $h{pear} = 1;           # "key pear stored in helem"
  49     }
  50
  51 =head1 DESCRIPTION
  52
  53 Magic is Perl way of enhancing objects.
  54 This mechanism lets the user add extra data to any variable and hook syntaxical operations (such as access, assignment or destruction) that can be applied to it.
  55 With this module, you can add your own magic to any variable without having to write a single line of XS.
  56
  57 You'll realize that these magic variables look a lot like tied variables.
  58 It's not surprising, as tied variables are implemented as a special kind of magic, just like any 'irregular' Perl variable : scalars like C<$!>, C<$(> or C<$^W>, the C<%ENV> and C<%SIG> hashes, the C<@ISA> array,  C<vec()> and C<substr()> lvalues, L<threads::shared> variables...
  59 They all share the same underlying C API, and this module gives you direct access to it.
  60
  61 Still, the magic made available by this module differs from tieing and overloading in several ways :
  62
  63 =over 4
  64
  65 =item *
  66
  67 It isn't copied on assignment.
  68
  69 You attach it to variables, not values (as for blessed references).
  70
  71 =item *
  72
  73 It doesn't replace the original semantics.
  74
  75 Magic callbacks usually trigger before the original action take place, and can't prevent it to happen.
  76 This also makes catching individual events easier than with C<tie>, where you have to provide fallbacks methods for all actions by usually inheriting from the correct C<Tie::Std*> class and overriding individual methods in your own class.
  77
  78 =item *
  79
  80 It's type-agnostic.
  81
  82 The same magic can be applied on scalars, arrays, hashes, subs or globs.
  83 But the same hook (see below for a list) may trigger differently depending on the the type of the variable.
  84
  85 =item *
  86
  87 It's mostly invisible at the Perl level.
  88
  89 Magical and non-magical variables cannot be distinguished with C<ref>, C<tied> or another trick.
  90
  91 =item *
  92
  93 It's notably faster.
  94
  95 Mainly because perl's way of handling magic is lighter by nature, and because there's no need for any method resolution.
  96 Also, since you don't have to reimplement all the variable semantics, you only pay for what you actually use.
  97
  98 =back
  99
 100 The operations that can be overloaded are :
 101
 102 =over 4
 103
 104 =item *
 105
 106 C<get>
 107
 108 This magic is invoked when the variable is evaluated.
 109 It is never called for arrays and hashes.
 110
 111 =item *
 112
 113 C<set>
 114
 115 This one is triggered each time the value of the variable changes.
 116 It is called for array subscripts and slices, but never for hashes.
 117
 118 =item *
 119
 120 C<len>
 121
 122 This magic is a little special : it is called when the 'size' or the 'length' of the variable has to be known by Perl.
 123 Typically, it's the magic involved when an array is evaluated in scalar context, but also on array assignment and loops (C<for>, C<map> or C<grep>).
 124 The callback has then to return the length as an integer.
 125
 126 =item *
 127
 128 C<clear>
 129
 130 This magic is invoked when the variable is reset, such as when an array is emptied.
 131 Please note that this is different from undefining the variable, even though the magic is called when the clearing is a result of the undefine (e.g. for an array, but actually a bug prevent it to work before perl 5.9.5 - see the L<history|/PERL MAGIC HISTORY>).
 132
 133 =item *
 134
 135 C<free>
 136
 137 This one can be considered as an object destructor.
 138 It happens when the variable goes out of scope, but not when it is undefined.
 139
 140 =item *
 141
 142 C<copy>
 143
 144 This magic only applies to tied arrays and hashes.
 145 It fires when you try to access or change their elements.
 146 It is available on your perl iff C<MGf_COPY> is true.
 147
 148 =item *
 149
 150 C<dup>
 151
 152 Invoked when the variable is cloned across threads.
 153 Currently not available.
 154
 155 =item *
 156
 157 C<local>
 158
 159 When this magic is set on a variable, all subsequent localizations of the variable will trigger the callback.
 160 It is available on your perl iff C<MGf_LOCAL> is true.
 161
 162 =back
 163
 164 The following actions only apply to hashes and are available iff C<VMG_UVAR> is true.
 165 They are referred to as C<uvar> magics.
 166
 167 =over 4
 168
 169 =item *
 170
 171 C<fetch>
 172
 173 This magic happens each time an element is fetched from the hash.
 174
 175 =item *
 176
 177 C<store>
 178
 179 This one is called when an element is stored into the hash.
 180
 181 =item *
 182
 183 C<exists>
 184
 185 This magic fires when a key is tested for existence in the hash.
 186
 187 =item *
 188
 189 C<delete>
 190
 191 This last one triggers when a key is deleted in the hash, regardless of whether the key actually exists in it.
 192
 193 =back
 194
 195 You can refer to the tests to have more insight of where the different magics are invoked.
 196
 197 To prevent any clash between different magics defined with this module, an unique numerical signature is attached to each kind of magic (i.e. each set of callbacks for magic operations).
 198 At the C level, magic tokens owned by magic created by this module have their C<< mg->mg_private >> field set to C<0x3891> or C<0x3892>, so please don't use these magic (sic) numbers in other extensions.
 199
 200 =head1 FUNCTIONS
 201
 202 =cut
 203
 204 BEGIN {
 205  require XSLoader;
 206  XSLoader::load(__PACKAGE__, $VERSION);
 207 }
 208
 209 =head2 C<wizard>
 210
 211     wizard data     => sub { ... },
 212            get      => sub { my ($ref, $data [, $op]) = @_; ... },
 213            set      => sub { my ($ref, $data [, $op]) = @_; ... },
 214            len      => sub { my ($ref, $data, $len [, $op]) = @_; ... ; return $newlen; },
 215            clear    => sub { my ($ref, $data [, $op]) = @_; ... },
 216            free     => sub { my ($ref, $data [, $op]) = @_, ... },
 217            copy     => sub { my ($ref, $data, $key, $elt [, $op]) = @_; ... },
 218            local    => sub { my ($ref, $data [, $op]) = @_; ... },
 219            fetch    => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 220            store    => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 221            exists   => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 222            delete   => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 223            copy_key => $bool,
 224            op_info  => [ 0 | VMG_OP_INFO_NAME | VMG_OP_INFO_OBJECT ]
 225
 226 This function creates a 'wizard', an opaque type that holds the magic information.
 227 It takes a list of keys / values as argument, whose keys can be :
 228
 229 =over 4
 230
 231 =item *
 232
 233 C<sig>
 234
 235 The numerical signature.
 236 If not specified or undefined, a random signature is generated.
 237 If the signature matches an already defined magic, then the existant magic object is returned.
 238
 239 This option is B<deprecated> and will be removed in december 2009.
 240
 241 =item *
 242
 243 C<data>
 244
 245 A code reference to a private data constructor.
 246 It is called each time this magic is cast on a variable, and the scalar returned is used as private data storage for it.
 247 C<$_[0]> is a reference to the magic object and C<@_[1 .. @_-1]> are all extra arguments that were passed to L</cast>.
 248
 249 =item *
 250
 251 C<get>, C<set>, C<len>, C<clear>, C<free>, C<copy>, C<local>, C<fetch>, C<store>, C<exists> and C<delete>
 252
 253 Code references to the corresponding magic callbacks.
 254 You don't have to specify all of them : the magic associated with undefined entries simply won't be hooked.
 255 In those callbacks, C<$_[0]> is always a reference to the magic object and C<$_[1]> is always the private data (or C<undef> when no private data constructor was supplied).
 256
 257 Moreover, when you pass C<< op_info => $num >> to C<wizard>, the last element of C<@_> will be the current op name if C<$num == VMG_OP_INFO_NAME> and a C<B::OP> object representing the current op if C<$num == VMG_OP_INFO_OBJECT>.
 258 Both have a performance hit, but just getting the name is lighter than getting the op object.
 259
 260 Other arguments are specific to the magic hooked :
 261
 262 =over 8
 263
 264 =item *
 265
 266 C<len>
 267
 268 When the variable is an array or a scalar, C<$_[2]> contains the non-magical length.
 269 The callback can return the new scalar or array length to use, or C<undef> to default to the normal length.
 270
 271 =item *
 272
 273 C<copy>
 274
 275 C<$_[2]> is a either a copy or an alias of the current key, which means that it is useless to try to change or cast magic on it.
 276 C<$_[3]> is an alias to the current element (i.e. the value).
 277
 278 =item *
 279
 280 C<fetch>, C<store>, C<exists> and C<delete>
 281
 282 C<$_[2]> is an alias to the current key.
 283 Nothing prevents you from changing it, but be aware that there lurk dangerous side effects.
 284 For example, it may rightfully be readonly if the key was a bareword.
 285 You can get a copy instead by passing C<< copy_key => 1 >> to L</wizard>, which allows you to safely assign to C<$_[2]> in order to e.g. redirect the action to another key.
 286 This however has a little performance drawback because of the copy.
 287
 288 =back
 289
 290 All the callbacks are expected to return an integer, which is passed straight to the perl magic API.
 291 However, only the return value of the C<len> callback currently holds a meaning.
 292
 293 =back
 294
 295     # A simple scalar tracer
 296     my $wiz = wizard get  => sub { print STDERR "got ${$_[0]}\n" },
 297                      set  => sub { print STDERR "set to ${$_[0]}\n" },
 298                      free => sub { print STDERR "${$_[0]} was deleted\n" }
 299
 300 Note that C<free> callbacks are I<never> called during global destruction, as there's no way to ensure that the wizard and the C<free> callback weren't destroyed before the variable.
 301
 302 =cut
 303
 304 sub wizard {
 305  croak 'Wrong number of arguments for wizard()' if @_ % 2;
 306  my %opts = @_;
 307  my @keys = qw/sig data op_info get set len clear free/;
 308  push @keys, 'copy'  if MGf_COPY;
 309  push @keys, 'dup'   if MGf_DUP;
 310  push @keys, 'local' if MGf_LOCAL;
 311  push @keys, qw/fetch store exists delete copy_key/ if VMG_UVAR;
 312  my $ret = eval { _wizard(map $opts{$_}, @keys) };
 313  if (my $err = $@) {
 314   $err =~ s/\sat\s+.*?\n//;
 315   croak $err;
 316  }
 317  return $ret;
 318 }
 319
 320 =head2 C<gensig>
 321
 322 With this tool, you can manually generate random magic signature between SIG_MIN and SIG_MAX inclusive.
 323 That's the way L</wizard> creates them when no signature is supplied.
 324
 325     # Generate a signature
 326     my $sig = gensig;
 327
 328 This function is B<deprecated> and will be removed in december 2009.
 329
 330 =head2 C<getsig>
 331
 332     getsig $wiz
 333
 334 This accessor returns the magic signature of this wizard.
 335
 336     # Get $wiz signature
 337     my $sig = getsig $wiz;
 338
 339 This function is B<deprecated> and will be removed in december 2009.
 340
 341 =head2 C<cast>
 342
 343     cast [$@%&*]var, $wiz, ...
 344
 345 This function associates C<$wiz> magic to the variable supplied, without overwriting any other kind of magic.
 346 It returns true on success or when C<$wiz> magic is already present, and croaks on error.
 347 All extra arguments specified after C<$wiz> are passed to the private data constructor in C<@_[1 .. @_-1]>.
 348 If the variable isn't a hash, any C<uvar> callback of the wizard is safely ignored.
 349
 350     # Casts $wiz onto $x, and pass '1' to the data constructor.
 351     my $x;
 352     cast $x, $wiz, 1;
 353
 354 The C<var> argument can be an array or hash value.
 355 Magic for those behaves like for any other scalar, except that it is dispelled when the entry is deleted from the container.
 356 For example, if you want to call C<POSIX::tzset> each time the C<'TZ'> environment variable is changed in C<%ENV>, you can use :
 357
 358     use POSIX;
 359     cast $ENV{TZ}, wizard set => sub { POSIX::tzset(); () };
 360
 361 If you want to overcome the possible deletion of the C<'TZ'> entry, you have no choice but to rely on C<store> uvar magic.
 362
 363 =head2 C<getdata>
 364
 365     getdata [$@%&*]var, $wiz
 366
 367 This accessor fetches the private data associated with the magic C<$wiz> in the variable.
 368 It croaks when C<$wiz> do not represent a valid magic object, and returns an empty list if no such magic is attached to the variable or when the wizard has no data constructor.
 369
 370     # Get the attached data, or undef if the wizard does not attach any.
 371     my $data = getdata $x, $wiz;
 372
 373 =head2 C<dispell>
 374
 375     dispell [$@%&*]variable, $wiz
 376
 377 The exact opposite of L</cast> : it dissociates C<$wiz> magic from the variable.
 378 This function returns true on success, C<0> when no magic represented by C<$wiz> could be found in the variable, and croaks if the supplied wizard is invalid.
 379
 380     # Dispell now.
 381     die 'no such magic in $x' unless dispell $x, $wiz;
 382
 383 =head1 CONSTANTS
 384
 385 =head2 C<SIG_MIN>
 386
 387 The minimum integer used as a signature for user-defined magic.
 388
 389 This constant is B<deprecated> and will be removed in december 2009.
 390
 391 =head2 C<SIG_MAX>
 392
 393 The maximum integer used as a signature for user-defined magic.
 394
 395 This constant is B<deprecated> and will be removed in december 2009.
 396
 397 =head2 C<SIG_NBR>
 398
 399     SIG_NBR = SIG_MAX - SIG_MIN + 1
 400
 401 This constant is B<deprecated> and will be removed in december 2009.
 402
 403 =head2 C<MGf_COPY>
 404
 405 Evaluates to true iff the 'copy' magic is available.
 406
 407 =head2 C<MGf_DUP>
 408
 409 Evaluates to true iff the 'dup' magic is available.
 410
 411 =head2 C<MGf_LOCAL>
 412
 413 Evaluates to true iff the 'local' magic is available.
 414
 415 =head2 C<VMG_UVAR>
 416
 417 When this constant is true, you can use the C<fetch,store,exists,delete> callbacks on hashes.
 418
 419 =head2 C<VMG_COMPAT_ARRAY_PUSH_NOLEN>
 420
 421 True for perls that don't call 'len' magic when you push an element in a magical array.
 422 Starting from perl 5.11.0, this only refers to pushes in non-void context and hence is false.
 423
 424 =head2 C<VMG_COMPAT_ARRAY_PUSH_NOLEN_VOID>
 425
 426 True for perls that don't call 'len' magic when you push in void context an element in a magical array.
 427
 428 =head2 C<VMG_COMPAT_ARRAY_UNSHIFT_NOLEN_VOID>
 429
 430 True for perls that don't call 'len' magic when you unshift in void context an element in a magical array.
 431
 432 =head2 C<VMG_COMPAT_ARRAY_UNDEF_CLEAR>
 433
 434 True for perls that call 'clear' magic when undefining magical arrays.
 435
 436 =head2 C<VMG_COMPAT_SCALAR_LENGTH_NOLEN>
 437
 438 True for perls that don't call 'len' magic when taking the C<length> of a magical scalar.
 439
 440 =head2 C<VMG_PERL_PATCHLEVEL>
 441
 442 The perl patchlevel this module was built with, or C<0> for non-debugging perls.
 443
 444 =head2 C<VMG_THREADSAFE>
 445
 446 True iff this module could have been built with thread-safety features enabled.
 447
 448 =head2 C<VMG_FORKSAFE>
 449
 450 True iff this module could have been built with fork-safety features enabled.
 451 This will always be true except on Windows where it's false for perl 5.10.0 and below .
 452
 453 =head2 C<VMG_OP_INFO_NAME>
 454
 455 Value to pass with C<op_info> to get the current op name in the magic callbacks.
 456
 457 =head2 C<VMG_OP_INFO_OBJECT>
 458
 459 Value to pass with C<op_info> to get a C<B::OP> object representing the current op in the magic callbacks.
 460
 461 =head1 COOKBOOK
 462
 463 =head2 Associate an object to any perl variable
 464
 465 This can be useful for passing user data through limited APIs.
 466
 467     {
 468      package Magical::UserData;
 469
 470      use Variable::Magic qw/wizard cast getdata/;
 471
 472      my $wiz = wizard data => sub { \$_[1] };
 473
 474      sub ud (\[$@%*&]) : lvalue {
 475       my ($var) = @_;
 476       my $data = &getdata($var, $wiz);
 477       unless (defined $data) {
 478        &cast($var, $wiz);
 479        $data = &getdata($var, $wiz);
 480        die "Couldn't cast UserData magic onto the variable" unless defined $data;
 481       }
 482       $$data;
 483      }
 484     }
 485
 486     {
 487      BEGIN { *ud = \&Magical::UserData::ud }
 488
 489      my $cb;
 490      $cb = sub { print 'Hello, ', ud(&$cb), "!\n" };
 491
 492      ud(&$cb) = 'world';
 493      $cb->(); # Hello, world!
 494     }
 495
 496 =head2 Recursively cast magic on datastructures
 497
 498 C<cast> can be called from any magical callback, and in particular from C<data>.
 499 This allows you to recursively cast magic on datastructures :
 500
 501     my $wiz;
 502     $wiz = wizard data => sub {
 503      my ($var, $depth) = @_;
 504      $depth ||= 0;
 505      my $r = ref $var;
 506      if ($r eq 'ARRAY') {
 507       &cast((ref() ? $_ : \$_), $wiz, $depth + 1) for @$var;
 508      } elsif ($r eq 'HASH') {
 509       &cast((ref() ? $_ : \$_), $wiz, $depth + 1) for values %$var;
 510      }
 511      return $depth;
 512     },
 513     free => sub {
 514      my ($var, $depth) = @_;
 515      my $r = ref $var;
 516      print "free $r at depth $depth\n";
 517      ();
 518     };
 519
 520     {
 521      my %h = (
 522       a => [ 1, 2 ],
 523       b => { c => 3 }
 524      );
 525      cast %h, $wiz;
 526     }
 527
 528 When C<%h> goes out of scope, this will print something among the lines of :
 529
 530     free HASH at depth 0
 531     free HASH at depth 1
 532     free SCALAR at depth 2
 533     free ARRAY at depth 1
 534     free SCALAR at depth 3
 535     free SCALAR at depth 3
 536
 537 Of course, this example does nothing with the values that are added after the C<cast>.
 538
 539 =head1 PERL MAGIC HISTORY
 540
 541 The places where magic is invoked have changed a bit through perl history.
 542 Here's a little list of the most recent ones.
 543
 544 =over 4
 545
 546 =item *
 547
 548 B<5.6.x>
 549
 550 I<p14416> : 'copy' and 'dup' magic.
 551
 552 =item *
 553
 554 B<5.8.9>
 555
 556 I<p28160> : Integration of I<p25854> (see below).
 557
 558 I<p32542> : Integration of I<p31473> (see below).
 559
 560 =item *
 561
 562 B<5.9.3>
 563
 564 I<p25854> : 'len' magic is no longer called when pushing an element into a magic array.
 565
 566 I<p26569> : 'local' magic.
 567
 568 =item *
 569
 570 B<5.9.5>
 571
 572 I<p31064> : Meaningful 'uvar' magic.
 573
 574 I<p31473> : 'clear' magic wasn't invoked when undefining an array.
 575 The bug is fixed as of this version.
 576
 577 =item *
 578
 579 B<5.10.0>
 580
 581 Since C<PERL_MAGIC_uvar> is uppercased, C<hv_magic_check()> triggers 'copy' magic on hash stores for (non-tied) hashes that also have 'uvar' magic.
 582
 583 =item *
 584
 585 B<5.11.x>
 586
 587 I<p32969> : 'len' magic is no longer invoked when calling C<length> with a magical scalar.
 588
 589 I<p34908> : 'len' magic is no longer called when pushing / unshifting an element into a magical array in void context.
 590 The C<push> part was already covered by I<p25854>.
 591
 592 I<g9cdcb38b> : 'len' magic is called again when pushing into a magical array in non-void context.
 593
 594 =back
 595
 596 =head1 EXPORT
 597
 598 The functions L</wizard>, L</gensig>, L</getsig>, L</cast>, L</getdata> and L</dispell> are only exported on request.
 599 All of them are exported by the tags C<':funcs'> and C<':all'>.
 600
 601 All the constants are also only exported on request, either individually or by the tags C<':consts'> and C<':all'>.
 602
 603 =cut
 604
 605 use base qw/Exporter/;
 606
 607 our @EXPORT         = ();
 608 our %EXPORT_TAGS    = (
 609  'funcs' =>  [ qw/wizard gensig getsig cast getdata dispell/ ],
 610  'consts' => [
 611                qw/SIG_MIN SIG_MAX SIG_NBR MGf_COPY MGf_DUP MGf_LOCAL VMG_UVAR/,
 612                qw/VMG_COMPAT_ARRAY_PUSH_NOLEN VMG_COMPAT_ARRAY_PUSH_NOLEN_VOID/,
 613                qw/VMG_COMPAT_ARRAY_UNSHIFT_NOLEN_VOID/,
 614                qw/VMG_COMPAT_ARRAY_UNDEF_CLEAR/,
 615                qw/VMG_COMPAT_SCALAR_LENGTH_NOLEN/,
 616                qw/VMG_PERL_PATCHLEVEL/,
 617                qw/VMG_THREADSAFE VMG_FORKSAFE/,
 618                qw/VMG_OP_INFO_NAME VMG_OP_INFO_OBJECT/
 619              ]
 620 );
 621 our @EXPORT_OK      = map { @$_ } values %EXPORT_TAGS;
 622 $EXPORT_TAGS{'all'} = [ @EXPORT_OK ];
 623
 624 =head1 CAVEATS
 625
 626 If you store a magic object in the private data slot, the magic won't be accessible by L</getdata> since it's not copied by assignment.
 627 The only way to address this would be to return a reference.
 628
 629 If you define a wizard with a C<free> callback and cast it on itself, this destructor won't be called because the wizard will be destroyed first.
 630
 631 =head1 DEPENDENCIES
 632
 633 L<perl> 5.8.
 634
 635 L<Carp> (standard since perl 5), L<XSLoader> (standard since perl 5.006).
 636
 637 Copy tests need L<Tie::Array> (standard since perl 5.005) and L<Tie::Hash> (since 5.002).
 638
 639 Some uvar tests need L<Hash::Util::FieldHash> (standard since perl 5.009004).
 640
 641 Glob tests need L<Symbol> (standard since perl 5.002).
 642
 643 Threads tests need L<threads> and L<threads::shared>.
 644
 645 =head1 SEE ALSO
 646
 647 L<perlguts> and L<perlapi> for internal information about magic.
 648
 649 L<perltie> and L<overload> for other ways of enhancing objects.
 650
 651 =head1 AUTHOR
 652
 653 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 654
 655 You can contact me by mail or on C<irc.perl.org> (vincent).
 656
 657 =head1 BUGS
 658
 659 Please report any bugs or feature requests to C<bug-variable-magic at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Variable-Magic>. I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 660
 661 =head1 SUPPORT
 662
 663 You can find documentation for this module with the perldoc command.
 664
 665     perldoc Variable::Magic
 666
 667 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Variable-Magic>.
 668
 669 =head1 COPYRIGHT & LICENSE
 670
 671 Copyright 2007-2009 Vincent Pit, all rights reserved.
 672
 673 This program is free software; you can redistribute it and/or modify it
 674 under the same terms as Perl itself.
 675
 676 =cut
 677
 678 1; # End of Variable::Magic