lib/Variable/Magic.pm

   1 package Variable::Magic;
   2
   3 use 5.007003;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp qw/croak/;
   9
  10 =head1 NAME
  11
  12 Variable::Magic - Associate user-defined magic to variables from Perl.
  13
  14 =head1 VERSION
  15
  16 Version 0.19
  17
  18 =cut
  19
  20 our $VERSION;
  21 BEGIN {
  22  $VERSION = '0.19';
  23 }
  24
  25 =head1 SYNOPSIS
  26
  27     use Variable::Magic qw/wizard cast dispell/;
  28
  29     my $wiz = wizard set => sub { print STDERR "now set to ${$_[0]}!\n" };
  30     my $a = 1;
  31     cast $a, $wiz;
  32     $a = 2;          # "now set to 2!"
  33     dispell $a, $wiz;
  34     $a = 3           # (nothing)
  35
  36 =head1 DESCRIPTION
  37
  38 Magic is Perl way of enhancing objects. This mechanism let the user add extra data to any variable and overload syntaxical operations (such as access, assignation or destruction) that can be applied to it. With this module, you can add your own magic to any variable without the pain of the C API.
  39
  40 The operations that can be overloaded are :
  41
  42 =over 4
  43
  44 =item *
  45
  46 C<get>
  47
  48 This magic is invoked when the variable is evaluated (does not include array/hash subscripts and slices).
  49
  50 =item *
  51
  52 C<set>
  53
  54 This one is triggered each time the value of the variable changes (includes array/hash subscripts and slices).
  55
  56 =item *
  57
  58 C<len>
  59
  60 This magic is a little special : it is called when the 'size' or the 'length' of the variable has to be known by Perl. Typically, it's the magic involved when an array is evaluated in scalar context, but also on array assignation and loops (C<for>, C<map> or C<grep>). The callback has then to return the length as an integer.
  61
  62 =item *
  63
  64 C<clear>
  65
  66 This magic is invoked when the variable is reset, such as when an array is emptied. Please note that this is different from undefining the variable, even though the magic is called when the clearing is a result of the undefine (e.g. for an array, but actually a bug prevent it to work before perl 5.9.5 - see the L<history|/PERL MAGIC HISTORY>).
  67
  68 =item *
  69
  70 C<free>
  71
  72 This one can be considered as an object destructor. It happens when the variable goes out of scope (with the exception of global scope), but not when it is undefined.
  73
  74 =item *
  75
  76 C<copy>
  77
  78 This magic only applies to tied arrays and hashes. It fires when you try to access or change their elements. It is available on your perl iff C<MGf_COPY> is true.
  79
  80 =item *
  81
  82 C<dup>
  83
  84 Invoked when the variable is cloned across threads. Currently not available.
  85
  86 =item *
  87
  88 C<local>
  89
  90 When this magic is set on a variable, all subsequent localizations of the variable will trigger the callback. It is available on your perl iff C<MGf_LOCAL> is true.
  91
  92 =back
  93
  94 The following actions only apply to hashes and are available iff C<VMG_UVAR> is true. They are referred to as C<uvar> magics.
  95
  96 =over 4
  97
  98 =item *
  99
 100 C<fetch>
 101
 102 This magic happens each time an element is fetched from the hash.
 103
 104 =item *
 105
 106 C<store>
 107
 108 This one is called when an element is stored into the hash.
 109
 110 =item *
 111
 112 C<exists>
 113
 114 This magic fires when a key is tested for existence in the hash.
 115
 116 =item *
 117
 118 C<delete>
 119
 120 This last one triggers when a key is deleted in the hash, regardless of whether the key actually exists in it.
 121
 122 =back
 123
 124 You can refer to the tests to have more insight of where the different magics are invoked.
 125
 126 To prevent any clash between different magics defined with this module, an unique numerical signature is attached to each kind of magic (i.e. each set of callbacks for magic operations).
 127
 128 =head1 PERL MAGIC HISTORY
 129
 130 The places where magic is invoked have changed a bit through perl history. Here's a little list of the most recent ones.
 131
 132 =over 4
 133
 134 =item *
 135
 136 B<5.6.x>
 137
 138 I<p14416> : 'copy' and 'dup' magic.
 139
 140 =item *
 141
 142 B<5.9.3>
 143
 144 I<p25854> : 'len' magic is no longer called when pushing an element into a magic array.
 145
 146 I<p26569> : 'local' magic.
 147
 148 =item *
 149
 150 B<5.9.5>
 151
 152 I<p31064> : Meaningful 'uvar' magic.
 153
 154 I<p31473> : 'clear' magic wasn't invoked when undefining an array. The bug is fixed as of this version.
 155
 156 =item *
 157
 158 B<5.10.0>
 159
 160 Since C<PERL_MAGIC_uvar> is uppercased, C<hv_magic_check()> triggers 'copy' magic on hash stores for (non-tied) hashes that also have 'uvar' magic.
 161
 162 =item *
 163
 164 B<5.11.x>
 165
 166 I<p32969> : 'len' magic is no longer invoked when calling C<length> with a magical scalar.
 167
 168 =back
 169
 170 =head1 CONSTANTS
 171
 172 =head2 C<SIG_MIN>
 173
 174 The minimum integer used as a signature for user-defined magic.
 175
 176 =head2 C<SIG_MAX>
 177
 178 The maximum integer used as a signature for user-defined magic.
 179
 180 =head2 C<SIG_NBR>
 181
 182     SIG_NBR = SIG_MAX - SIG_MIN + 1
 183
 184 =head2 C<MGf_COPY>
 185
 186 Evaluates to true iff the 'copy' magic is available.
 187
 188 =head2 C<MGf_DUP>
 189
 190 Evaluates to true iff the 'dup' magic is available.
 191
 192 =head2 C<MGf_LOCAL>
 193
 194 Evaluates to true iff the 'local' magic is available.
 195
 196 =head2 C<VMG_UVAR>
 197
 198 When this constant is true, you can use the C<fetch,store,exists,delete> callbacks on hashes.
 199
 200 =head2 C<VMG_COMPAT_ARRAY_PUSH_NOLEN>
 201
 202 True for perls that don't call 'len' magic when you push an element in a magical array.
 203
 204 =head2 C<VMG_COMPAT_ARRAY_UNDEF_CLEAR>
 205
 206 True for perls that call 'clear' magic when undefining magical arrays.
 207
 208 =head2 C<VMG_COMPAT_SCALAR_LENGTH_NOLEN>
 209
 210 True for perls that don't call 'len' magic when taking the C<length> of a magical scalar.
 211
 212 =head2 C<VMG_PERL_PATCHLEVEL>
 213
 214 The perl patchlevel this module was built with, or C<0> for non-debugging perls.
 215
 216 =head1 FUNCTIONS
 217
 218 =cut
 219
 220 BEGIN {
 221  require XSLoader;
 222  XSLoader::load(__PACKAGE__, $VERSION);
 223 }
 224
 225 =head2 C<wizard>
 226
 227     wizard sig    => ...,
 228            data   => sub { ... },
 229            get    => sub { my ($ref, $data) = @_; ... },
 230            set    => sub { my ($ref, $data) = @_; ... },
 231            len    => sub { my ($ref, $data, $len) = @_; ... ; return $newlen; },
 232            clear  => sub { my ($ref, $data) = @_; ... },
 233            free   => sub { my ($ref, $data) = @_, ... },
 234            copy   => sub { my ($ref, $data, $key, $elt) = @_; ... },
 235            local  => sub { my ($ref, $data) = @_; ... },
 236            fetch  => sub { my ($ref, $data, $key) = @_; ... },
 237            store  => sub { my ($ref, $data, $key) = @_; ... },
 238            exists => sub { my ($ref, $data, $key) = @_; ... },
 239            delete => sub { my ($ref, $data, $key) = @_; ... }
 240
 241 This function creates a 'wizard', an opaque type that holds the magic information. It takes a list of keys / values as argument, whose keys can be :
 242
 243 =over 4
 244
 245 =item *
 246
 247 C<sig>
 248
 249 The numerical signature. If not specified or undefined, a random signature is generated. If the signature matches an already defined magic, then the existant magic object is returned.
 250
 251 =item *
 252
 253 C<data>
 254
 255 A code reference to a private data constructor. It is called each time this magic is cast on a variable, and the scalar returned is used as private data storage for it. C<$_[0]> is a reference to the magic object and C<@_[1 .. @_-1]> are all extra arguments that were passed to L</cast>.
 256
 257 =item *
 258
 259 C<get>, C<set>, C<len>, C<clear>, C<free>, C<copy>, C<local>, C<fetch>, C<store>, C<exists> and C<delete>
 260
 261 Code references to corresponding magic callbacks. You don't have to specify all of them : the magic associated with undefined entries simply won't be hooked. In those callbacks, C<$_[0]> is always a reference to the magic object and C<$_[1]> is always the private data (or C<undef> when no private data constructor was supplied). In the special case of C<len> magic and when the variable is an array, C<$_[2]> contains its normal length. C<$_[2]> is the current key in C<copy>, C<fetch>, C<store>, C<exists> and C<delete> callbacks, although for C<copy> it may just be a copy of the actual key so it's useless to (for example) cast magic on it. C<copy> magic also receives the current element (i.e. the value) in C<$_[3]>.
 262
 263 =back
 264
 265     # A simple scalar tracer
 266     my $wiz = wizard get  => sub { print STDERR "got ${$_[0]}\n" },
 267                      set  => sub { print STDERR "set to ${$_[0]}\n" },
 268                      free => sub { print STDERR "${$_[0]} was deleted\n" }
 269
 270 =cut
 271
 272 sub wizard {
 273  croak 'Wrong number of arguments for wizard()' if @_ % 2;
 274  my %opts = @_;
 275  my @cbs  = qw/sig data get set len clear free/;
 276  push @cbs, 'copy'  if MGf_COPY;
 277  push @cbs, 'dup'   if MGf_DUP;
 278  push @cbs, 'local' if MGf_LOCAL;
 279  push @cbs, qw/fetch store exists delete/ if VMG_UVAR;
 280  return _wizard(map $opts{$_}, @cbs);
 281 }
 282
 283 =head2 C<gensig>
 284
 285 With this tool, you can manually generate random magic signature between SIG_MIN and SIG_MAX inclusive. That's the way L</wizard> creates them when no signature is supplied.
 286
 287     # Generate a signature
 288     my $sig = gensig;
 289
 290 =head2 C<getsig>
 291
 292     getsig $wiz
 293
 294 This accessor returns the magic signature of this wizard.
 295
 296     # Get $wiz signature
 297     my $sig = getsig $wiz;
 298
 299 =head2 C<cast>
 300
 301     cast [$@%&*]var, [$wiz|$sig], ...
 302
 303 This function associates C<$wiz> magic to the variable supplied, without overwriting any other kind of magic. You can also supply the numeric signature C<$sig> instead of C<$wiz>. It returns true on success or when C<$wiz> magic is already present, C<0> on error, and C<undef> when no magic corresponds to the given signature (in case C<$sig> was supplied). All extra arguments specified after C<$wiz> are passed to the private data constructor. If the variable isn't a hash, any C<uvar> callback of the wizard is safely ignored.
 304
 305     # Casts $wiz onto $x. If $wiz isn't a signature, undef can't be returned.
 306     my $x;
 307     die 'error' unless cast $x, $wiz;
 308
 309 =head2 C<getdata>
 310
 311     getdata [$@%&*]var, [$wiz|$sig]
 312
 313 This accessor fetches the private data associated with the magic C<$wiz> (or the signature C<$sig>) in the variable. C<undef> is returned when no such magic or data is found, or when C<$sig> does not represent a current valid magic object.
 314
 315     # Get the attached data.
 316     my $data = getdata $x, $wiz or die 'no such magic or magic has no data';
 317
 318 =head2 C<dispell>
 319
 320     dispell [$@%&*]variable, [$wiz|$sig]
 321
 322 The exact opposite of L</cast> : it dissociates C<$wiz> magic from the variable. You can also pass the magic signature C<$sig> as the second argument. True is returned on success, C<0> on error or when no magic represented by C<$wiz> could be found in the variable, and C<undef> when no magic corresponds to the given signature (in case C<$sig> was supplied).
 323
 324     # Dispell now. If $wiz isn't a signature, undef can't be returned.
 325     die 'no such magic or error' unless dispell $x, $wiz;
 326
 327 =head1 EXPORT
 328
 329 The functions L</wizard>, L</gensig>, L</getsig>, L</cast>, L</getdata> and L</dispell> are only exported on request. All of them are exported by the tags C<':funcs'> and C<':all'>.
 330
 331 The constants L</SIG_MIN>, L</SIG_MAX>, L</SIG_NBR>, L</MGf_COPY>, L</MGf_DUP>, L</MGf_LOCAL> and L</VMG_UVAR> are also only exported on request. They are all exported by the tags C<':consts'> and C<':all'>.
 332
 333 =cut
 334
 335 use base qw/Exporter/;
 336
 337 our @EXPORT         = ();
 338 our %EXPORT_TAGS    = (
 339  'funcs' =>  [ qw/wizard gensig getsig cast getdata dispell/ ],
 340  'consts' => [ qw/SIG_MIN SIG_MAX SIG_NBR MGf_COPY MGf_DUP MGf_LOCAL VMG_UVAR/,
 341                qw/VMG_COMPAT_ARRAY_PUSH_NOLEN VMG_COMPAT_ARRAY_UNDEF_CLEAR/,
 342                qw/VMG_COMPAT_SCALAR_LENGTH_NOLEN/,
 343                qw/VMG_PERL_PATCHLEVEL/ ]
 344 );
 345 our @EXPORT_OK      = map { @$_ } values %EXPORT_TAGS;
 346 $EXPORT_TAGS{'all'} = [ @EXPORT_OK ];
 347
 348 =head1 CAVEATS
 349
 350 If you store a magic object in the private data slot, the magic won't be accessible by L</getdata> since it's not copied by assignation. The only way to address this would be to return a reference.
 351
 352 If you define a wizard with a C<free> callback and cast it on itself, this destructor won't be called because the wizard will be destroyed first.
 353
 354 =head1 DEPENDENCIES
 355
 356 L<perl> 5.7.3.
 357
 358 L<Carp> (standard since perl 5), L<XSLoader> (standard since perl 5.006).
 359
 360 Copy tests need L<Tie::Array> (standard since perl 5.005) and L<Tie::Hash> (since 5.002).
 361
 362 Some uvar tests need L<Hash::Util::FieldHash> (standard since perl 5.009004).
 363
 364 Glob tests need L<Symbol> (standard since perl 5.002).
 365
 366 =head1 SEE ALSO
 367
 368 L<perlguts> and L<perlapi> for internal information about magic.
 369
 370 L<perltie> and L<overload> for other ways of enhancing objects.
 371
 372 =head1 AUTHOR
 373
 374 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 375
 376 You can contact me by mail or on #perl @ FreeNode (vincent or Prof_Vince).
 377
 378 =head1 BUGS
 379
 380 Please report any bugs or feature requests to C<bug-variable-magic at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Variable-Magic>. I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 381
 382 =head1 SUPPORT
 383
 384 You can find documentation for this module with the perldoc command.
 385
 386     perldoc Variable::Magic
 387
 388 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Variable-Magic>.
 389
 390 =head1 COPYRIGHT & LICENSE
 391
 392 Copyright 2007-2008 Vincent Pit, all rights reserved.
 393
 394 This program is free software; you can redistribute it and/or modify it
 395 under the same terms as Perl itself.
 396
 397 =cut
 398
 399 1; # End of Variable::Magic