lib/Variable/Magic.pm

   1 package Variable::Magic;
   2
   3 use 5.007003;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp qw/croak/;
   9
  10 =head1 NAME
  11
  12 Variable::Magic - Associate user-defined magic to variables from Perl.
  13
  14 =head1 VERSION
  15
  16 Version 0.25
  17
  18 =cut
  19
  20 our $VERSION;
  21 BEGIN {
  22  $VERSION = '0.25';
  23 }
  24
  25 =head1 SYNOPSIS
  26
  27     use Variable::Magic qw/wizard cast dispell/;
  28
  29     my $wiz = wizard set => sub { print STDERR "now set to ${$_[0]}!\n" };
  30     my $a = 1;
  31     cast $a, $wiz;
  32     $a = 2;          # "now set to 2!"
  33     dispell $a, $wiz;
  34     $a = 3           # (nothing)
  35
  36 =head1 DESCRIPTION
  37
  38 Magic is Perl way of enhancing objects. This mechanism let the user add extra data to any variable and hook syntaxical operations (such as access, assignation or destruction) that can be applied to it. With this module, you can add your own magic to any variable without the pain of the C API.
  39
  40 Magic differs from tieing and overloading in several ways :
  41
  42 =over 4
  43
  44 =item *
  45
  46 Magic isn't copied on assignation (as for blessed references) : you attach it to variables, not values.
  47
  48 =item *
  49
  50 It doesn't replace the original semantics : magic callbacks trigger before the original action take place, and can't prevent it to happen.
  51
  52 =item *
  53
  54 It's mostly invisible at the Perl level : magical and non-magical variables cannot be distinguished with C<ref>, C<reftype> or another trick.
  55
  56 =item *
  57
  58 It's notably faster, since perl's way of handling magic is lighter by nature, and there's no need for any method resolution.
  59
  60 =back
  61
  62 The operations that can be overloaded are :
  63
  64 =over 4
  65
  66 =item *
  67
  68 C<get>
  69
  70 This magic is invoked when the variable is evaluated (does not include array/hash subscripts and slices).
  71
  72 =item *
  73
  74 C<set>
  75
  76 This one is triggered each time the value of the variable changes (includes array/hash subscripts and slices).
  77
  78 =item *
  79
  80 C<len>
  81
  82 This magic is a little special : it is called when the 'size' or the 'length' of the variable has to be known by Perl. Typically, it's the magic involved when an array is evaluated in scalar context, but also on array assignation and loops (C<for>, C<map> or C<grep>). The callback has then to return the length as an integer.
  83
  84 =item *
  85
  86 C<clear>
  87
  88 This magic is invoked when the variable is reset, such as when an array is emptied. Please note that this is different from undefining the variable, even though the magic is called when the clearing is a result of the undefine (e.g. for an array, but actually a bug prevent it to work before perl 5.9.5 - see the L<history|/PERL MAGIC HISTORY>).
  89
  90 =item *
  91
  92 C<free>
  93
  94 This one can be considered as an object destructor. It happens when the variable goes out of scope (with the exception of global scope), but not when it is undefined.
  95
  96 =item *
  97
  98 C<copy>
  99
 100 This magic only applies to tied arrays and hashes. It fires when you try to access or change their elements. It is available on your perl iff C<MGf_COPY> is true.
 101
 102 =item *
 103
 104 C<dup>
 105
 106 Invoked when the variable is cloned across threads. Currently not available.
 107
 108 =item *
 109
 110 C<local>
 111
 112 When this magic is set on a variable, all subsequent localizations of the variable will trigger the callback. It is available on your perl iff C<MGf_LOCAL> is true.
 113
 114 =back
 115
 116 The following actions only apply to hashes and are available iff C<VMG_UVAR> is true. They are referred to as C<uvar> magics.
 117
 118 =over 4
 119
 120 =item *
 121
 122 C<fetch>
 123
 124 This magic happens each time an element is fetched from the hash.
 125
 126 =item *
 127
 128 C<store>
 129
 130 This one is called when an element is stored into the hash.
 131
 132 =item *
 133
 134 C<exists>
 135
 136 This magic fires when a key is tested for existence in the hash.
 137
 138 =item *
 139
 140 C<delete>
 141
 142 This last one triggers when a key is deleted in the hash, regardless of whether the key actually exists in it.
 143
 144 =back
 145
 146 You can refer to the tests to have more insight of where the different magics are invoked.
 147
 148 To prevent any clash between different magics defined with this module, an unique numerical signature is attached to each kind of magic (i.e. each set of callbacks for magic operations).
 149
 150 =head1 PERL MAGIC HISTORY
 151
 152 The places where magic is invoked have changed a bit through perl history. Here's a little list of the most recent ones.
 153
 154 =over 4
 155
 156 =item *
 157
 158 B<5.6.x>
 159
 160 I<p14416> : 'copy' and 'dup' magic.
 161
 162 =item *
 163
 164 B<5.8.9>
 165
 166 I<p28160> : Integration of I<p25854> (see below).
 167
 168 I<p32542> : Integration of I<p31473> (see below).
 169
 170 =item *
 171
 172 B<5.9.3>
 173
 174 I<p25854> : 'len' magic is no longer called when pushing an element into a magic array.
 175
 176 I<p26569> : 'local' magic.
 177
 178 =item *
 179
 180 B<5.9.5>
 181
 182 I<p31064> : Meaningful 'uvar' magic.
 183
 184 I<p31473> : 'clear' magic wasn't invoked when undefining an array. The bug is fixed as of this version.
 185
 186 =item *
 187
 188 B<5.10.0>
 189
 190 Since C<PERL_MAGIC_uvar> is uppercased, C<hv_magic_check()> triggers 'copy' magic on hash stores for (non-tied) hashes that also have 'uvar' magic.
 191
 192 =item *
 193
 194 B<5.11.x>
 195
 196 I<p32969> : 'len' magic is no longer invoked when calling C<length> with a magical scalar.
 197
 198 I<p34908> : 'len' magic is no longer called when pushing / unshifting an element into a magical array in void context. The C<push> part was already covered by I<p25854>.
 199
 200 =back
 201
 202 =head1 CONSTANTS
 203
 204 =head2 C<SIG_MIN>
 205
 206 The minimum integer used as a signature for user-defined magic.
 207
 208 =head2 C<SIG_MAX>
 209
 210 The maximum integer used as a signature for user-defined magic.
 211
 212 =head2 C<SIG_NBR>
 213
 214     SIG_NBR = SIG_MAX - SIG_MIN + 1
 215
 216 =head2 C<MGf_COPY>
 217
 218 Evaluates to true iff the 'copy' magic is available.
 219
 220 =head2 C<MGf_DUP>
 221
 222 Evaluates to true iff the 'dup' magic is available.
 223
 224 =head2 C<MGf_LOCAL>
 225
 226 Evaluates to true iff the 'local' magic is available.
 227
 228 =head2 C<VMG_UVAR>
 229
 230 When this constant is true, you can use the C<fetch,store,exists,delete> callbacks on hashes.
 231
 232 =head2 C<VMG_COMPAT_ARRAY_PUSH_NOLEN>
 233
 234 True for perls that don't call 'len' magic when you push an element in a magical array.
 235
 236 =head2 C<VMG_COMPAT_ARRAY_UNSHIFT_NOLEN_VOID>
 237
 238 True for perls that don't call 'len' magic when you unshift in void context an element in a magical array.
 239
 240 =head2 C<VMG_COMPAT_ARRAY_UNDEF_CLEAR>
 241
 242 True for perls that call 'clear' magic when undefining magical arrays.
 243
 244 =head2 C<VMG_COMPAT_SCALAR_LENGTH_NOLEN>
 245
 246 True for perls that don't call 'len' magic when taking the C<length> of a magical scalar.
 247
 248 =head2 C<VMG_PERL_PATCHLEVEL>
 249
 250 The perl patchlevel this module was built with, or C<0> for non-debugging perls.
 251
 252 =head2 C<VMG_THREADSAFE>
 253
 254 True iff this module could have been built with thread-safety features enabled.
 255
 256 =head1 FUNCTIONS
 257
 258 =cut
 259
 260 BEGIN {
 261  require XSLoader;
 262  XSLoader::load(__PACKAGE__, $VERSION);
 263 }
 264
 265 =head2 C<wizard>
 266
 267     wizard sig    => ...,
 268            data   => sub { ... },
 269            get    => sub { my ($ref, $data) = @_; ... },
 270            set    => sub { my ($ref, $data) = @_; ... },
 271            len    => sub { my ($ref, $data, $len) = @_; ... ; return $newlen; },
 272            clear  => sub { my ($ref, $data) = @_; ... },
 273            free   => sub { my ($ref, $data) = @_, ... },
 274            copy   => sub { my ($ref, $data, $key, $elt) = @_; ... },
 275            local  => sub { my ($ref, $data) = @_; ... },
 276            fetch  => sub { my ($ref, $data, $key) = @_; ... },
 277            store  => sub { my ($ref, $data, $key) = @_; ... },
 278            exists => sub { my ($ref, $data, $key) = @_; ... },
 279            delete => sub { my ($ref, $data, $key) = @_; ... }
 280
 281 This function creates a 'wizard', an opaque type that holds the magic information. It takes a list of keys / values as argument, whose keys can be :
 282
 283 =over 4
 284
 285 =item *
 286
 287 C<sig>
 288
 289 The numerical signature. If not specified or undefined, a random signature is generated. If the signature matches an already defined magic, then the existant magic object is returned.
 290
 291 =item *
 292
 293 C<data>
 294
 295 A code reference to a private data constructor. It is called each time this magic is cast on a variable, and the scalar returned is used as private data storage for it. C<$_[0]> is a reference to the magic object and C<@_[1 .. @_-1]> are all extra arguments that were passed to L</cast>.
 296
 297 =item *
 298
 299 C<get>, C<set>, C<len>, C<clear>, C<free>, C<copy>, C<local>, C<fetch>, C<store>, C<exists> and C<delete>
 300
 301 Code references to corresponding magic callbacks. You don't have to specify all of them : the magic associated with undefined entries simply won't be hooked. In those callbacks, C<$_[0]> is always a reference to the magic object and C<$_[1]> is always the private data (or C<undef> when no private data constructor was supplied). In the special case of C<len> magic and when the variable is an array, C<$_[2]> contains its normal length. C<$_[2]> is the current key in C<copy>, C<fetch>, C<store>, C<exists> and C<delete> callbacks, although for C<copy> it may just be a copy of the actual key so it's useless to (for example) cast magic on it. C<copy> magic also receives the current element (i.e. the value) in C<$_[3]>.
 302
 303 =back
 304
 305     # A simple scalar tracer
 306     my $wiz = wizard get  => sub { print STDERR "got ${$_[0]}\n" },
 307                      set  => sub { print STDERR "set to ${$_[0]}\n" },
 308                      free => sub { print STDERR "${$_[0]} was deleted\n" }
 309
 310 =cut
 311
 312 sub wizard {
 313  croak 'Wrong number of arguments for wizard()' if @_ % 2;
 314  my %opts = @_;
 315  my @cbs  = qw/sig data get set len clear free/;
 316  push @cbs, 'copy'  if MGf_COPY;
 317  push @cbs, 'dup'   if MGf_DUP;
 318  push @cbs, 'local' if MGf_LOCAL;
 319  push @cbs, qw/fetch store exists delete/ if VMG_UVAR;
 320  my $ret = eval { _wizard(map $opts{$_}, @cbs) };
 321  if (my $err = $@) {
 322   $err =~ s/\sat\s+.*?\n//;
 323   croak $err;
 324  }
 325  return $ret;
 326 }
 327
 328 =head2 C<gensig>
 329
 330 With this tool, you can manually generate random magic signature between SIG_MIN and SIG_MAX inclusive. That's the way L</wizard> creates them when no signature is supplied.
 331
 332     # Generate a signature
 333     my $sig = gensig;
 334
 335 =head2 C<getsig>
 336
 337     getsig $wiz
 338
 339 This accessor returns the magic signature of this wizard.
 340
 341     # Get $wiz signature
 342     my $sig = getsig $wiz;
 343
 344 =head2 C<cast>
 345
 346     cast [$@%&*]var, [$wiz|$sig], ...
 347
 348 This function associates C<$wiz> magic to the variable supplied, without overwriting any other kind of magic. You can also supply the numeric signature C<$sig> instead of C<$wiz>. It returns true on success or when C<$wiz> magic is already present, C<0> on error, and C<undef> when no magic corresponds to the given signature (in case C<$sig> was supplied). All extra arguments specified after C<$wiz> are passed to the private data constructor. If the variable isn't a hash, any C<uvar> callback of the wizard is safely ignored.
 349
 350     # Casts $wiz onto $x. If $wiz isn't a signature, undef can't be returned.
 351     my $x;
 352     die 'error' unless cast $x, $wiz;
 353
 354 =head2 C<getdata>
 355
 356     getdata [$@%&*]var, [$wiz|$sig]
 357
 358 This accessor fetches the private data associated with the magic C<$wiz> (or the signature C<$sig>) in the variable. C<undef> is returned when no such magic or data is found, or when C<$sig> does not represent a current valid magic object.
 359
 360     # Get the attached data.
 361     my $data = getdata $x, $wiz or die 'no such magic or magic has no data';
 362
 363 =head2 C<dispell>
 364
 365     dispell [$@%&*]variable, [$wiz|$sig]
 366
 367 The exact opposite of L</cast> : it dissociates C<$wiz> magic from the variable. You can also pass the magic signature C<$sig> as the second argument. True is returned on success, C<0> on error or when no magic represented by C<$wiz> could be found in the variable, and C<undef> when no magic corresponds to the given signature (in case C<$sig> was supplied).
 368
 369     # Dispell now. If $wiz isn't a signature, undef can't be returned.
 370     die 'no such magic or error' unless dispell $x, $wiz;
 371
 372 =head1 EXPORT
 373
 374 The functions L</wizard>, L</gensig>, L</getsig>, L</cast>, L</getdata> and L</dispell> are only exported on request. All of them are exported by the tags C<':funcs'> and C<':all'>.
 375
 376 The constants L</SIG_MIN>, L</SIG_MAX>, L</SIG_NBR>, L</MGf_COPY>, L</MGf_DUP>, L</MGf_LOCAL> and L</VMG_UVAR> are also only exported on request. They are all exported by the tags C<':consts'> and C<':all'>.
 377
 378 =cut
 379
 380 use base qw/Exporter/;
 381
 382 our @EXPORT         = ();
 383 our %EXPORT_TAGS    = (
 384  'funcs' =>  [ qw/wizard gensig getsig cast getdata dispell/ ],
 385  'consts' => [ qw/SIG_MIN SIG_MAX SIG_NBR MGf_COPY MGf_DUP MGf_LOCAL VMG_UVAR/,
 386                qw/VMG_COMPAT_ARRAY_PUSH_NOLEN VMG_COMPAT_ARRAY_UNSHIFT_NOLEN_VOID VMG_COMPAT_ARRAY_UNDEF_CLEAR/,
 387                qw/VMG_COMPAT_SCALAR_LENGTH_NOLEN/,
 388                qw/VMG_PERL_PATCHLEVEL/,
 389                qw/VMG_THREADSAFE/ ]
 390 );
 391 our @EXPORT_OK      = map { @$_ } values %EXPORT_TAGS;
 392 $EXPORT_TAGS{'all'} = [ @EXPORT_OK ];
 393
 394 =head1 CAVEATS
 395
 396 If you store a magic object in the private data slot, the magic won't be accessible by L</getdata> since it's not copied by assignation. The only way to address this would be to return a reference.
 397
 398 If you define a wizard with a C<free> callback and cast it on itself, this destructor won't be called because the wizard will be destroyed first.
 399
 400 =head1 DEPENDENCIES
 401
 402 L<perl> 5.7.3.
 403
 404 L<Carp> (standard since perl 5), L<XSLoader> (standard since perl 5.006).
 405
 406 Copy tests need L<Tie::Array> (standard since perl 5.005) and L<Tie::Hash> (since 5.002).
 407
 408 Some uvar tests need L<Hash::Util::FieldHash> (standard since perl 5.009004).
 409
 410 Glob tests need L<Symbol> (standard since perl 5.002).
 411
 412 Threads tests need L<threads> and L<threads::shared>.
 413
 414 =head1 SEE ALSO
 415
 416 L<perlguts> and L<perlapi> for internal information about magic.
 417
 418 L<perltie> and L<overload> for other ways of enhancing objects.
 419
 420 =head1 AUTHOR
 421
 422 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 423
 424 You can contact me by mail or on C<irc.perl.org> (vincent).
 425
 426 =head1 BUGS
 427
 428 Please report any bugs or feature requests to C<bug-variable-magic at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Variable-Magic>. I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 429
 430 =head1 SUPPORT
 431
 432 You can find documentation for this module with the perldoc command.
 433
 434     perldoc Variable::Magic
 435
 436 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Variable-Magic>.
 437
 438 =head1 COPYRIGHT & LICENSE
 439
 440 Copyright 2007-2008 Vincent Pit, all rights reserved.
 441
 442 This program is free software; you can redistribute it and/or modify it
 443 under the same terms as Perl itself.
 444
 445 =cut
 446
 447 1; # End of Variable::Magic