lib/Variable/Magic.pm

   1 package Variable::Magic;
   2
   3 use 5.007003;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp qw/croak/;
   9
  10 =head1 NAME
  11
  12 Variable::Magic - Associate user-defined magic to variables from Perl.
  13
  14 =head1 VERSION
  15
  16 Version 0.19
  17
  18 =cut
  19
  20 our $VERSION;
  21 BEGIN {
  22  $VERSION = '0.19';
  23 }
  24
  25 =head1 SYNOPSIS
  26
  27     use Variable::Magic qw/wizard cast dispell/;
  28
  29     my $wiz = wizard set => sub { print STDERR "now set to ${$_[0]}!\n" };
  30     my $a = 1;
  31     cast $a, $wiz;
  32     $a = 2;          # "now set to 2!"
  33     dispell $a, $wiz;
  34     $a = 3           # (nothing)
  35
  36 =head1 DESCRIPTION
  37
  38 Magic is Perl way of enhancing objects. This mechanism let the user add extra data to any variable and overload syntaxical operations (such as access, assignation or destruction) that can be applied to it. With this module, you can add your own magic to any variable without the pain of the C API.
  39
  40 The operations that can be overloaded are :
  41
  42 =over 4
  43
  44 =item C<get>
  45
  46 This magic is invoked when the variable is evaluated (does not include array/hash subscripts and slices).
  47
  48 =item C<set>
  49
  50 This one is triggered each time the value of the variable changes (includes array/hash subscripts and slices).
  51
  52 =item C<len>
  53
  54 This magic is a little special : it is called when the 'size' or the 'length' of the variable has to be known by Perl. Typically, it's the magic involved when an array is evaluated in scalar context, but also on array assignation and loops (C<for>, C<map> or C<grep>). The callback has then to return the length as an integer.
  55
  56 =item C<clear>
  57
  58 This magic is invoked when the variable is reset, such as when an array is emptied. Please note that this is different from undefining the variable, even though the magic is called when the clearing is a result of the undefine (e.g. for an array, but actually a bug prevent it to work before perl 5.9.5 - see the L<history|/PERL MAGIC HISTORY>).
  59
  60 =item C<free>
  61
  62 This one can be considered as an object destructor. It happens when the variable goes out of scope (with the exception of global scope), but not when it is undefined.
  63
  64 =item C<copy>
  65
  66 This magic only applies to tied arrays and hashes. It fires when you try to access or change their elements. It is available on your perl iff C<MGf_COPY> is true.
  67
  68 =item C<dup>
  69
  70 Invoked when the variable is cloned across threads. Currently not available.
  71
  72 =item C<local>
  73
  74 When this magic is set on a variable, all subsequent localizations of the variable will trigger the callback. It is available on your perl iff C<MGf_LOCAL> is true.
  75
  76 =back
  77
  78 The following actions only apply to hashes and are available iff C<VMG_UVAR> is true. They are referred to as C<uvar> magics.
  79
  80 =over 4
  81
  82 =item C<fetch>
  83
  84 This magic happens each time an element is fetched from the hash.
  85
  86 =item C<store>
  87
  88 This one is called when an element is stored into the hash.
  89
  90 =item C<exists>
  91
  92 This magic fires when a key is tested for existence in the hash.
  93
  94 =item C<delete>
  95
  96 This last one triggers when a key is deleted in the hash, regardless of whether the key actually exists in it.
  97
  98 =back
  99
 100 You can refer to the tests to have more insight of where the different magics are invoked.
 101
 102 To prevent any clash between different magics defined with this module, an unique numerical signature is attached to each kind of magic (i.e. each set of callbacks for magic operations).
 103
 104 =head1 PERL MAGIC HISTORY
 105
 106 The places where magic is invoked have changed a bit through perl history. Here's a little list of the most recent ones.
 107
 108 =head2 B<5.6.x>
 109
 110 =over 4
 111
 112 =item I<p14416> : 'copy' and 'dup' magic.
 113
 114 =back
 115
 116 =head2 B<5.9.3>
 117
 118 =over 4
 119
 120 =item I<p25854> : 'len' magic is no longer called when pushing an element into a magic array.
 121
 122 =item I<p26569> : 'local' magic.
 123
 124 =back
 125
 126 =head2 B<5.9.5>
 127
 128 =over 4
 129
 130 =item I<p31064> : Meaningful 'uvar' magic.
 131
 132 =item I<p31473> : 'clear' magic wasn't invoked when undefining an array. The bug is fixed as of this version.
 133
 134 =back
 135
 136 =head2 B<5.10.0>
 137
 138 =over 4
 139
 140 =item Since C<PERL_MAGIC_uvar> is uppercased, C<hv_magic_check()> triggers 'copy' magic on hash stores for (non-tied) hashes that also have 'uvar' magic.
 141
 142 =back
 143
 144 =head2 B<5.11.x>
 145
 146 =over 4
 147
 148 =item I<p32969> : 'len' magic is no longer invoked when calling C<length> with a magical scalar.
 149
 150 =back
 151
 152 =head1 CONSTANTS
 153
 154 =head2 C<SIG_MIN>
 155
 156 The minimum integer used as a signature for user-defined magic.
 157
 158 =head2 C<SIG_MAX>
 159
 160 The maximum integer used as a signature for user-defined magic.
 161
 162 =head2 C<SIG_NBR>
 163
 164     SIG_NBR = SIG_MAX - SIG_MIN + 1
 165
 166 =head2 C<MGf_COPY>
 167
 168 Evaluates to true iff the 'copy' magic is available.
 169
 170 =head2 C<MGf_DUP>
 171
 172 Evaluates to true iff the 'dup' magic is available.
 173
 174 =head2 C<MGf_LOCAL>
 175
 176 Evaluates to true iff the 'local' magic is available.
 177
 178 =head2 C<VMG_UVAR>
 179
 180 When this constant is true, you can use the C<fetch,store,exists,delete> callbacks on hashes.
 181
 182 =head2 C<VMG_COMPAT_ARRAY_PUSH_NOLEN>
 183
 184 True for perls that don't call 'len' magic when you push an element in a magical array.
 185
 186 =head2 C<VMG_COMPAT_ARRAY_UNDEF_CLEAR>
 187
 188 True for perls that call 'clear' magic when undefining magical arrays.
 189
 190 =head2 C<VMG_COMPAT_SCALAR_LENGTH_NOLEN>
 191
 192 True for perls that don't call 'len' magic when taking the C<length> of a magical scalar.
 193
 194 =head2 C<VMG_PERL_PATCHLEVEL>
 195
 196 The perl patchlevel this module was built with, or C<0> for non-debugging perls.
 197
 198 =head1 FUNCTIONS
 199
 200 =cut
 201
 202 BEGIN {
 203  require XSLoader;
 204  XSLoader::load(__PACKAGE__, $VERSION);
 205 }
 206
 207 =head2 C<wizard>
 208
 209     wizard sig    => ...,
 210            data   => sub { ... },
 211            get    => sub { my ($ref, $data) = @_; ... },
 212            set    => sub { my ($ref, $data) = @_; ... },
 213            len    => sub { my ($ref, $data, $len) = @_; ... ; return $newlen; },
 214            clear  => sub { my ($ref, $data) = @_; ... },
 215            free   => sub { my ($ref, $data) = @_, ... },
 216            copy   => sub { my ($ref, $data, $key, $elt) = @_; ... },
 217            local  => sub { my ($ref, $data) = @_; ... },
 218            fetch  => sub { my ($ref, $data, $key) = @_; ... },
 219            store  => sub { my ($ref, $data, $key) = @_; ... },
 220            exists => sub { my ($ref, $data, $key) = @_; ... },
 221            delete => sub { my ($ref, $data, $key) = @_; ... }
 222
 223 This function creates a 'wizard', an opaque type that holds the magic information. It takes a list of keys / values as argument, whose keys can be :
 224
 225 =over 4
 226
 227 =item C<sig>
 228
 229 The numerical signature. If not specified or undefined, a random signature is generated. If the signature matches an already defined magic, then the existant magic object is returned.
 230
 231 =item C<data>
 232
 233 A code reference to a private data constructor. It is called each time this magic is cast on a variable, and the scalar returned is used as private data storage for it. C<$_[0]> is a reference to the magic object and C<@_[1 .. @_-1]> are all extra arguments that were passed to L</cast>.
 234
 235 =item C<get>, C<set>, C<len>, C<clear>, C<free>, C<copy>, C<local>, C<fetch>, C<store>, C<exists> and C<delete>
 236
 237 Code references to corresponding magic callbacks. You don't have to specify all of them : the magic associated with undefined entries simply won't be hooked. In those callbacks, C<$_[0]> is always a reference to the magic object and C<$_[1]> is always the private data (or C<undef> when no private data constructor was supplied). In the special case of C<len> magic and when the variable is an array, C<$_[2]> contains its normal length. C<$_[2]> is the current key in C<copy>, C<fetch>, C<store>, C<exists> and C<delete> callbacks, although for C<copy> it may just be a copy of the actual key so it's useless to (for example) cast magic on it. C<copy> magic also receives the current element (i.e. the value) in C<$_[3]>.
 238
 239 =back
 240
 241     # A simple scalar tracer
 242     my $wiz = wizard get  => sub { print STDERR "got ${$_[0]}\n" },
 243                      set  => sub { print STDERR "set to ${$_[0]}\n" },
 244                      free => sub { print STDERR "${$_[0]} was deleted\n" }
 245
 246 =cut
 247
 248 sub wizard {
 249  croak 'Wrong number of arguments for wizard()' if @_ % 2;
 250  my %opts = @_;
 251  my @cbs  = qw/sig data get set len clear free/;
 252  push @cbs, 'copy'  if MGf_COPY;
 253  push @cbs, 'dup'   if MGf_DUP;
 254  push @cbs, 'local' if MGf_LOCAL;
 255  push @cbs, qw/fetch store exists delete/ if VMG_UVAR;
 256  return _wizard(map $opts{$_}, @cbs);
 257 }
 258
 259 =head2 C<gensig>
 260
 261 With this tool, you can manually generate random magic signature between SIG_MIN and SIG_MAX inclusive. That's the way L</wizard> creates them when no signature is supplied.
 262
 263     # Generate a signature
 264     my $sig = gensig;
 265
 266 =head2 C<getsig>
 267
 268     getsig $wiz
 269
 270 This accessor returns the magic signature of this wizard.
 271
 272     # Get $wiz signature
 273     my $sig = getsig $wiz;
 274
 275 =head2 C<cast>
 276
 277     cast [$@%&*]var, [$wiz|$sig], ...
 278
 279 This function associates C<$wiz> magic to the variable supplied, without overwriting any other kind of magic. You can also supply the numeric signature C<$sig> instead of C<$wiz>. It returns true on success or when C<$wiz> magic is already present, C<0> on error, and C<undef> when no magic corresponds to the given signature (in case C<$sig> was supplied). All extra arguments specified after C<$wiz> are passed to the private data constructor. If the variable isn't a hash, any C<uvar> callback of the wizard is safely ignored.
 280
 281     # Casts $wiz onto $x. If $wiz isn't a signature, undef can't be returned.
 282     my $x;
 283     die 'error' unless cast $x, $wiz;
 284
 285 =head2 C<getdata>
 286
 287     getdata [$@%&*]var, [$wiz|$sig]
 288
 289 This accessor fetches the private data associated with the magic C<$wiz> (or the signature C<$sig>) in the variable. C<undef> is returned when no such magic or data is found, or when C<$sig> does not represent a current valid magic object.
 290
 291     # Get the attached data.
 292     my $data = getdata $x, $wiz or die 'no such magic or magic has no data';
 293
 294 =head2 C<dispell>
 295
 296     dispell [$@%&*]variable, [$wiz|$sig]
 297
 298 The exact opposite of L</cast> : it dissociates C<$wiz> magic from the variable. You can also pass the magic signature C<$sig> as the second argument. True is returned on success, C<0> on error or when no magic represented by C<$wiz> could be found in the variable, and C<undef> when no magic corresponds to the given signature (in case C<$sig> was supplied).
 299
 300     # Dispell now. If $wiz isn't a signature, undef can't be returned.
 301     die 'no such magic or error' unless dispell $x, $wiz;
 302
 303 =head1 EXPORT
 304
 305 The functions L</wizard>, L</gensig>, L</getsig>, L</cast>, L</getdata> and L</dispell> are only exported on request. All of them are exported by the tags C<':funcs'> and C<':all'>.
 306
 307 The constants L</SIG_MIN>, L</SIG_MAX>, L</SIG_NBR>, L</MGf_COPY>, L</MGf_DUP>, L</MGf_LOCAL> and L</VMG_UVAR> are also only exported on request. They are all exported by the tags C<':consts'> and C<':all'>.
 308
 309 =cut
 310
 311 use base qw/Exporter/;
 312
 313 our @EXPORT         = ();
 314 our %EXPORT_TAGS    = (
 315  'funcs' =>  [ qw/wizard gensig getsig cast getdata dispell/ ],
 316  'consts' => [ qw/SIG_MIN SIG_MAX SIG_NBR MGf_COPY MGf_DUP MGf_LOCAL VMG_UVAR/,
 317                qw/VMG_COMPAT_ARRAY_PUSH_NOLEN VMG_COMPAT_ARRAY_UNDEF_CLEAR/,
 318                qw/VMG_COMPAT_SCALAR_LENGTH_NOLEN/,
 319                qw/VMG_PERL_PATCHLEVEL/ ]
 320 );
 321 our @EXPORT_OK      = map { @$_ } values %EXPORT_TAGS;
 322 $EXPORT_TAGS{'all'} = [ @EXPORT_OK ];
 323
 324 =head1 CAVEATS
 325
 326 If you store a magic object in the private data slot, the magic won't be accessible by L</getdata> since it's not copied by assignation. The only way to address this would be to return a reference.
 327
 328 If you define a wizard with a C<free> callback and cast it on itself, this destructor won't be called because the wizard will be destroyed first.
 329
 330 =head1 DEPENDENCIES
 331
 332 L<perl> 5.7.3.
 333
 334 L<Carp> (standard since perl 5), L<XSLoader> (standard since perl 5.006).
 335
 336 Copy tests need L<Tie::Array> (standard since perl 5.005) and L<Tie::Hash> (since 5.002).
 337
 338 Some uvar tests need L<Hash::Util::FieldHash> (standard since perl 5.009004).
 339
 340 Glob tests need L<Symbol> (standard since perl 5.002).
 341
 342 =head1 SEE ALSO
 343
 344 L<perlguts> and L<perlapi> for internal information about magic.
 345
 346 L<perltie> and L<overload> for other ways of enhancing objects.
 347
 348 =head1 AUTHOR
 349
 350 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 351
 352 You can contact me by mail or on #perl @ FreeNode (vincent or Prof_Vince).
 353
 354 =head1 BUGS
 355
 356 Please report any bugs or feature requests to C<bug-variable-magic at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Variable-Magic>. I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 357
 358 =head1 SUPPORT
 359
 360 You can find documentation for this module with the perldoc command.
 361
 362     perldoc Variable::Magic
 363
 364 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Variable-Magic>.
 365
 366 =head1 COPYRIGHT & LICENSE
 367
 368 Copyright 2007-2008 Vincent Pit, all rights reserved.
 369
 370 This program is free software; you can redistribute it and/or modify it
 371 under the same terms as Perl itself.
 372
 373 =cut
 374
 375 1; # End of Variable::Magic