README

   1 NAME
   2     Variable::Magic - Associate user-defined magic to variables from Perl.
   3
   4 VERSION
   5     Version 0.42
   6
   7 SYNOPSIS
   8         use Variable::Magic qw/wizard cast VMG_OP_INFO_NAME/;
   9
  10         { # A variable tracer
  11          my $wiz = wizard set  => sub { print "now set to ${$_[0]}!\n" },
  12                           free => sub { print "destroyed!\n" };
  13
  14          my $a = 1;
  15          cast $a, $wiz;
  16          $a = 2;        # "now set to 2!"
  17         }               # "destroyed!"
  18
  19         { # A hash with a default value
  20          my $wiz = wizard data     => sub { $_[1] },
  21                           fetch    => sub { $_[2] = $_[1] unless exists $_[0]->{$_[2]}; () },
  22                           store    => sub { print "key $_[2] stored in $_[-1]\n" },
  23                           copy_key => 1,
  24                           op_info  => VMG_OP_INFO_NAME;
  25
  26          my %h = (_default => 0, apple => 2);
  27          cast %h, $wiz, '_default';
  28          print $h{banana}, "\n"; # "0", because the 'banana' key doesn't exist in %h
  29          $h{pear} = 1;           # "key pear stored in helem"
  30         }
  31
  32 DESCRIPTION
  33     Magic is Perl's way of enhancing variables. This mechanism lets the user
  34     add extra data to any variable and hook syntactical operations (such as
  35     access, assignment or destruction) that can be applied to it. With this
  36     module, you can add your own magic to any variable without having to
  37     write a single line of XS.
  38
  39     You'll realize that these magic variables look a lot like tied
  40     variables. It's not surprising, as tied variables are implemented as a
  41     special kind of magic, just like any 'irregular' Perl variable : scalars
  42     like $!, $( or $^W, the %ENV and %SIG hashes, the @ISA array, "vec()"
  43     and "substr()" lvalues, threads::shared variables... They all share the
  44     same underlying C API, and this module gives you direct access to it.
  45
  46     Still, the magic made available by this module differs from tieing and
  47     overloading in several ways :
  48
  49     *   It isn't copied on assignment.
  50
  51         You attach it to variables, not values (as for blessed references).
  52
  53     *   It doesn't replace the original semantics.
  54
  55         Magic callbacks usually get triggered before the original action
  56         takes place, and can't prevent it from happening. This also makes
  57         catching individual events easier than with "tie", where you have to
  58         provide fallbacks methods for all actions by usually inheriting from
  59         the correct "Tie::Std*" class and overriding individual methods in
  60         your own class.
  61
  62     *   It's type-agnostic.
  63
  64         The same magic can be applied on scalars, arrays, hashes, subs or
  65         globs. But the same hook (see below for a list) may trigger
  66         differently depending on the the type of the variable.
  67
  68     *   It's mostly invisible at the Perl level.
  69
  70         Magical and non-magical variables cannot be distinguished with
  71         "ref", "tied" or another trick.
  72
  73     *   It's notably faster.
  74
  75         Mainly because perl's way of handling magic is lighter by nature,
  76         and because there's no need for any method resolution. Also, since
  77         you don't have to reimplement all the variable semantics, you only
  78         pay for what you actually use.
  79
  80     The operations that can be overloaded are :
  81
  82     *   "get"
  83
  84         This magic is invoked when the variable is evaluated. It is never
  85         called for arrays and hashes.
  86
  87     *   "set"
  88
  89         This one is triggered each time the value of the variable changes.
  90         It is called for array subscripts and slices, but never for hashes.
  91
  92     *   "len"
  93
  94         This magic is a little special : it is called when the 'size' or the
  95         'length' of the variable has to be known by Perl. Typically, it's
  96         the magic involved when an array is evaluated in scalar context, but
  97         also on array assignment and loops ("for", "map" or "grep"). The
  98         callback has then to return the length as an integer.
  99
 100     *   "clear"
 101
 102         This magic is invoked when the variable is reset, such as when an
 103         array is emptied. Please note that this is different from undefining
 104         the variable, even though the magic is called when the clearing is a
 105         result of the undefine (e.g. for an array, but actually a bug
 106         prevent it to work before perl 5.9.5 - see the history).
 107
 108     *   "free"
 109
 110         This one can be considered as an object destructor. It happens when
 111         the variable goes out of scope, but not when it is undefined.
 112
 113     *   "copy"
 114
 115         This magic only applies to tied arrays and hashes. It fires when you
 116         try to access or change their elements. It is available on your perl
 117         iff "MGf_COPY" is true.
 118
 119     *   "dup"
 120
 121         Invoked when the variable is cloned across threads. Currently not
 122         available.
 123
 124     *   "local"
 125
 126         When this magic is set on a variable, all subsequent localizations
 127         of the variable will trigger the callback. It is available on your
 128         perl iff "MGf_LOCAL" is true.
 129
 130     The following actions only apply to hashes and are available iff
 131     "VMG_UVAR" is true. They are referred to as "uvar" magics.
 132
 133     *   "fetch"
 134
 135         This magic happens each time an element is fetched from the hash.
 136
 137     *   "store"
 138
 139         This one is called when an element is stored into the hash.
 140
 141     *   "exists"
 142
 143         This magic fires when a key is tested for existence in the hash.
 144
 145     *   "delete"
 146
 147         This last one triggers when a key is deleted in the hash, regardless
 148         of whether the key actually exists in it.
 149
 150     You can refer to the tests to have more insight of where the different
 151     magics are invoked.
 152
 153     To prevent any clash between different magics defined with this module,
 154     an unique numerical signature is attached to each kind of magic (i.e.
 155     each set of callbacks for magic operations). At the C level, magic
 156     tokens owned by magic created by this module have their "mg->mg_private"
 157     field set to 0x3891 or 0x3892, so please don't use these magic (sic)
 158     numbers in other extensions.
 159
 160 FUNCTIONS
 161   "wizard"
 162         wizard data     => sub { ... },
 163                get      => sub { my ($ref, $data [, $op]) = @_; ... },
 164                set      => sub { my ($ref, $data [, $op]) = @_; ... },
 165                len      => sub { my ($ref, $data, $len [, $op]) = @_; ... ; return $newlen; },
 166                clear    => sub { my ($ref, $data [, $op]) = @_; ... },
 167                free     => sub { my ($ref, $data [, $op]) = @_, ... },
 168                copy     => sub { my ($ref, $data, $key, $elt [, $op]) = @_; ... },
 169                local    => sub { my ($ref, $data [, $op]) = @_; ... },
 170                fetch    => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 171                store    => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 172                exists   => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 173                delete   => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 174                copy_key => $bool,
 175                op_info  => [ 0 | VMG_OP_INFO_NAME | VMG_OP_INFO_OBJECT ]
 176
 177     This function creates a 'wizard', an opaque type that holds the magic
 178     information. It takes a list of keys / values as argument, whose keys
 179     can be :
 180
 181     *   "data"
 182
 183         A code (or string) reference to a private data constructor. It is
 184         called each time this magic is cast on a variable, and the scalar
 185         returned is used as private data storage for it. $_[0] is a
 186         reference to the magic object and @_[1 .. @_-1] are all extra
 187         arguments that were passed to "cast".
 188
 189     *   "get", "set", "len", "clear", "free", "copy", "local", "fetch",
 190         "store", "exists" and "delete"
 191
 192         Code (or string) references to the corresponding magic callbacks.
 193         You don't have to specify all of them : the magic associated with
 194         undefined entries simply won't be hooked. In those callbacks, $_[0]
 195         is always a reference to the magic object and $_[1] is always the
 196         private data (or "undef" when no private data constructor was
 197         supplied).
 198
 199         Moreover, when you pass "op_info => $num" to "wizard", the last
 200         element of @_ will be the current op name if "$num ==
 201         VMG_OP_INFO_NAME" and a "B::OP" object representing the current op
 202         if "$num == VMG_OP_INFO_OBJECT". Both have a performance hit, but
 203         just getting the name is lighter than getting the op object.
 204
 205         Other arguments are specific to the magic hooked :
 206
 207         *       "len"
 208
 209                 When the variable is an array or a scalar, $_[2] contains
 210                 the non-magical length. The callback can return the new
 211                 scalar or array length to use, or "undef" to default to the
 212                 normal length.
 213
 214         *       "copy"
 215
 216                 $_[2] is a either a copy or an alias of the current key,
 217                 which means that it is useless to try to change or cast
 218                 magic on it. $_[3] is an alias to the current element (i.e.
 219                 the value).
 220
 221         *       "fetch", "store", "exists" and "delete"
 222
 223                 $_[2] is an alias to the current key. Nothing prevents you
 224                 from changing it, but be aware that there lurk dangerous
 225                 side effects. For example, it may rightfully be readonly if
 226                 the key was a bareword. You can get a copy instead by
 227                 passing "copy_key => 1" to "wizard", which allows you to
 228                 safely assign to $_[2] in order to e.g. redirect the action
 229                 to another key. This however has a little performance
 230                 drawback because of the copy.
 231
 232         All the callbacks are expected to return an integer, which is passed
 233         straight to the perl magic API. However, only the return value of
 234         the "len" callback currently holds a meaning.
 235
 236     Each callback can be specified as a code or a string reference, in which
 237     case the function denoted by the string will be used as the callback.
 238
 239     Note that "free" callbacks are *never* called during global destruction,
 240     as there's no way to ensure that the wizard and the "free" callback
 241     weren't destroyed before the variable.
 242
 243     Here's a simple usage example :
 244
 245         # A simple scalar tracer
 246         my $wiz = wizard get  => sub { print STDERR "got ${$_[0]}\n" },
 247                          set  => sub { print STDERR "set to ${$_[0]}\n" },
 248                          free => sub { print STDERR "${$_[0]} was deleted\n" }
 249
 250   "cast"
 251         cast [$@%&*]var, $wiz, ...
 252
 253     This function associates $wiz magic to the variable supplied, without
 254     overwriting any other kind of magic. It returns true on success or when
 255     $wiz magic is already present, and croaks on error. All extra arguments
 256     specified after $wiz are passed to the private data constructor in @_[1
 257     .. @_-1]. If the variable isn't a hash, any "uvar" callback of the
 258     wizard is safely ignored.
 259
 260         # Casts $wiz onto $x, and pass '1' to the data constructor.
 261         my $x;
 262         cast $x, $wiz, 1;
 263
 264     The "var" argument can be an array or hash value. Magic for those
 265     behaves like for any other scalar, except that it is dispelled when the
 266     entry is deleted from the container. For example, if you want to call
 267     "POSIX::tzset" each time the 'TZ' environment variable is changed in
 268     %ENV, you can use :
 269
 270         use POSIX;
 271         cast $ENV{TZ}, wizard set => sub { POSIX::tzset(); () };
 272
 273     If you want to overcome the possible deletion of the 'TZ' entry, you
 274     have no choice but to rely on "store" uvar magic.
 275
 276   "getdata"
 277         getdata [$@%&*]var, $wiz
 278
 279     This accessor fetches the private data associated with the magic $wiz in
 280     the variable. It croaks when $wiz do not represent a valid magic object,
 281     and returns an empty list if no such magic is attached to the variable
 282     or when the wizard has no data constructor.
 283
 284         # Get the attached data, or undef if the wizard does not attach any.
 285         my $data = getdata $x, $wiz;
 286
 287   "dispell"
 288         dispell [$@%&*]variable, $wiz
 289
 290     The exact opposite of "cast" : it dissociates $wiz magic from the
 291     variable. This function returns true on success, 0 when no magic
 292     represented by $wiz could be found in the variable, and croaks if the
 293     supplied wizard is invalid.
 294
 295         # Dispell now.
 296         die 'no such magic in $x' unless dispell $x, $wiz;
 297
 298 CONSTANTS
 299   "MGf_COPY"
 300     Evaluates to true iff the 'copy' magic is available.
 301
 302   "MGf_DUP"
 303     Evaluates to true iff the 'dup' magic is available.
 304
 305   "MGf_LOCAL"
 306     Evaluates to true iff the 'local' magic is available.
 307
 308   "VMG_UVAR"
 309     When this constant is true, you can use the "fetch,store,exists,delete"
 310     callbacks on hashes.
 311
 312   "VMG_COMPAT_ARRAY_PUSH_NOLEN"
 313     True for perls that don't call 'len' magic when you push an element in a
 314     magical array. Starting from perl 5.11.0, this only refers to pushes in
 315     non-void context and hence is false.
 316
 317   "VMG_COMPAT_ARRAY_PUSH_NOLEN_VOID"
 318     True for perls that don't call 'len' magic when you push in void context
 319     an element in a magical array.
 320
 321   "VMG_COMPAT_ARRAY_UNSHIFT_NOLEN_VOID"
 322     True for perls that don't call 'len' magic when you unshift in void
 323     context an element in a magical array.
 324
 325   "VMG_COMPAT_ARRAY_UNDEF_CLEAR"
 326     True for perls that call 'clear' magic when undefining magical arrays.
 327
 328   "VMG_COMPAT_SCALAR_LENGTH_NOLEN"
 329     True for perls that don't call 'len' magic when taking the "length" of a
 330     magical scalar.
 331
 332   "VMG_PERL_PATCHLEVEL"
 333     The perl patchlevel this module was built with, or 0 for non-debugging
 334     perls.
 335
 336   "VMG_THREADSAFE"
 337     True iff this module could have been built with thread-safety features
 338     enabled.
 339
 340   "VMG_FORKSAFE"
 341     True iff this module could have been built with fork-safety features
 342     enabled. This will always be true except on Windows where it's false for
 343     perl 5.10.0 and below .
 344
 345   "VMG_OP_INFO_NAME"
 346     Value to pass with "op_info" to get the current op name in the magic
 347     callbacks.
 348
 349   "VMG_OP_INFO_OBJECT"
 350     Value to pass with "op_info" to get a "B::OP" object representing the
 351     current op in the magic callbacks.
 352
 353 COOKBOOK
 354   Associate an object to any perl variable
 355     This technique can be useful for passing user data through limited APIs.
 356     It is similar to using inside-out objects, but without the drawback of
 357     having to implement a complex destructor.
 358
 359         {
 360          package Magical::UserData;
 361
 362          use Variable::Magic qw/wizard cast getdata/;
 363
 364          my $wiz = wizard data => sub { \$_[1] };
 365
 366          sub ud (\[$@%*&]) : lvalue {
 367           my ($var) = @_;
 368           my $data = &getdata($var, $wiz);
 369           unless (defined $data) {
 370            $data = \(my $slot);
 371            &cast($var, $wiz, $slot)
 372                             or die "Couldn't cast UserData magic onto the variable";
 373           }
 374           $$data;
 375          }
 376         }
 377
 378         {
 379          BEGIN { *ud = \&Magical::UserData::ud }
 380
 381          my $cb;
 382          $cb = sub { print 'Hello, ', ud(&$cb), "!\n" };
 383
 384          ud(&$cb) = 'world';
 385          $cb->(); # Hello, world!
 386         }
 387
 388   Recursively cast magic on datastructures
 389     "cast" can be called from any magical callback, and in particular from
 390     "data". This allows you to recursively cast magic on datastructures :
 391
 392         my $wiz;
 393         $wiz = wizard data => sub {
 394          my ($var, $depth) = @_;
 395          $depth ||= 0;
 396          my $r = ref $var;
 397          if ($r eq 'ARRAY') {
 398           &cast((ref() ? $_ : \$_), $wiz, $depth + 1) for @$var;
 399          } elsif ($r eq 'HASH') {
 400           &cast((ref() ? $_ : \$_), $wiz, $depth + 1) for values %$var;
 401          }
 402          return $depth;
 403         },
 404         free => sub {
 405          my ($var, $depth) = @_;
 406          my $r = ref $var;
 407          print "free $r at depth $depth\n";
 408          ();
 409         };
 410
 411         {
 412          my %h = (
 413           a => [ 1, 2 ],
 414           b => { c => 3 }
 415          );
 416          cast %h, $wiz;
 417         }
 418
 419     When %h goes out of scope, this will print something among the lines of
 420     :
 421
 422         free HASH at depth 0
 423         free HASH at depth 1
 424         free SCALAR at depth 2
 425         free ARRAY at depth 1
 426         free SCALAR at depth 3
 427         free SCALAR at depth 3
 428
 429     Of course, this example does nothing with the values that are added
 430     after the "cast".
 431
 432 PERL MAGIC HISTORY
 433     The places where magic is invoked have changed a bit through perl
 434     history. Here's a little list of the most recent ones.
 435
 436     *   5.6.x
 437
 438         *p14416* : 'copy' and 'dup' magic.
 439
 440     *   5.8.9
 441
 442         *p28160* : Integration of *p25854* (see below).
 443
 444         *p32542* : Integration of *p31473* (see below).
 445
 446     *   5.9.3
 447
 448         *p25854* : 'len' magic is no longer called when pushing an element
 449         into a magic array.
 450
 451         *p26569* : 'local' magic.
 452
 453     *   5.9.5
 454
 455         *p31064* : Meaningful 'uvar' magic.
 456
 457         *p31473* : 'clear' magic wasn't invoked when undefining an array.
 458         The bug is fixed as of this version.
 459
 460     *   5.10.0
 461
 462         Since "PERL_MAGIC_uvar" is uppercased, "hv_magic_check()" triggers
 463         'copy' magic on hash stores for (non-tied) hashes that also have
 464         'uvar' magic.
 465
 466     *   5.11.x
 467
 468         *p32969* : 'len' magic is no longer invoked when calling "length"
 469         with a magical scalar.
 470
 471         *p34908* : 'len' magic is no longer called when pushing / unshifting
 472         an element into a magical array in void context. The "push" part was
 473         already covered by *p25854*.
 474
 475         *g9cdcb38b* : 'len' magic is called again when pushing into a
 476         magical array in non-void context.
 477
 478 EXPORT
 479     The functions "wizard", "cast", "getdata" and "dispell" are only
 480     exported on request. All of them are exported by the tags ':funcs' and
 481     ':all'.
 482
 483     All the constants are also only exported on request, either individually
 484     or by the tags ':consts' and ':all'.
 485
 486 CAVEATS
 487     If you store a magic object in the private data slot, the magic won't be
 488     accessible by "getdata" since it's not copied by assignment. The only
 489     way to address this would be to return a reference.
 490
 491     If you define a wizard with a "free" callback and cast it on itself,
 492     this destructor won't be called because the wizard will be destroyed
 493     first.
 494
 495 DEPENDENCIES
 496     perl 5.8.
 497
 498     Carp (standard since perl 5), XSLoader (standard since perl 5.006).
 499
 500     Copy tests need Tie::Array (standard since perl 5.005) and Tie::Hash
 501     (since 5.002).
 502
 503     Some uvar tests need Hash::Util::FieldHash (standard since perl
 504     5.009004).
 505
 506     Glob tests need Symbol (standard since perl 5.002).
 507
 508     Threads tests need threads and threads::shared.
 509
 510 SEE ALSO
 511     perlguts and perlapi for internal information about magic.
 512
 513     perltie and overload for other ways of enhancing objects.
 514
 515 AUTHOR
 516     Vincent Pit, "<perl at profvince.com>", <http://www.profvince.com>.
 517
 518     You can contact me by mail or on "irc.perl.org" (vincent).
 519
 520 BUGS
 521     Please report any bugs or feature requests to "bug-variable-magic at
 522     rt.cpan.org", or through the web interface at
 523     <http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Variable-Magic>. I will
 524     be notified, and then you'll automatically be notified of progress on
 525     your bug as I make changes.
 526
 527 SUPPORT
 528     You can find documentation for this module with the perldoc command.
 529
 530         perldoc Variable::Magic
 531
 532     Tests code coverage report is available at
 533     <http://www.profvince.com/perl/cover/Variable-Magic>.
 534
 535 COPYRIGHT & LICENSE
 536     Copyright 2007,2008,2009,2010 Vincent Pit, all rights reserved.
 537
 538     This program is free software; you can redistribute it and/or modify it
 539     under the same terms as Perl itself.
 540