README

   1 NAME
   2     Variable::Magic - Associate user-defined magic to variables from Perl.
   3
   4 VERSION
   5     Version 0.51
   6
   7 SYNOPSIS
   8         use Variable::Magic qw<wizard cast VMG_OP_INFO_NAME>;
   9
  10         { # A variable tracer
  11          my $wiz = wizard(
  12           set  => sub { print "now set to ${$_[0]}!\n" },
  13           free => sub { print "destroyed!\n" },
  14          );
  15
  16          my $a = 1;
  17          cast $a, $wiz;
  18          $a = 2;        # "now set to 2!"
  19         }               # "destroyed!"
  20
  21         { # A hash with a default value
  22          my $wiz = wizard(
  23           data     => sub { $_[1] },
  24           fetch    => sub { $_[2] = $_[1] unless exists $_[0]->{$_[2]}; () },
  25           store    => sub { print "key $_[2] stored in $_[-1]\n" },
  26           copy_key => 1,
  27           op_info  => VMG_OP_INFO_NAME,
  28          );
  29
  30          my %h = (_default => 0, apple => 2);
  31          cast %h, $wiz, '_default';
  32          print $h{banana}, "\n"; # "0" (there is no 'banana' key in %h)
  33          $h{pear} = 1;           # "key pear stored in helem"
  34         }
  35
  36 DESCRIPTION
  37     Magic is Perl's way of enhancing variables. This mechanism lets the user
  38     add extra data to any variable and hook syntactical operations (such as
  39     access, assignment or destruction) that can be applied to it. With this
  40     module, you can add your own magic to any variable without having to
  41     write a single line of XS.
  42
  43     You'll realize that these magic variables look a lot like tied
  44     variables. It is not surprising, as tied variables are implemented as a
  45     special kind of magic, just like any 'irregular' Perl variable : scalars
  46     like $!, $( or $^W, the %ENV and %SIG hashes, the @ISA array, "vec()"
  47     and "substr()" lvalues, threads::shared variables... They all share the
  48     same underlying C API, and this module gives you direct access to it.
  49
  50     Still, the magic made available by this module differs from tieing and
  51     overloading in several ways :
  52
  53     *   Magic is not copied on assignment.
  54
  55         You attach it to variables, not values (as for blessed references).
  56
  57     *   Magic does not replace the original semantics.
  58
  59         Magic callbacks usually get triggered before the original action
  60         takes place, and cannot prevent it from happening. This also makes
  61         catching individual events easier than with "tie", where you have to
  62         provide fallbacks methods for all actions by usually inheriting from
  63         the correct "Tie::Std*" class and overriding individual methods in
  64         your own class.
  65
  66     *   Magic is multivalued.
  67
  68         You can safely apply different kinds of magics to the same variable,
  69         and each of them will be invoked successively.
  70
  71     *   Magic is type-agnostic.
  72
  73         The same magic can be applied on scalars, arrays, hashes, subs or
  74         globs. But the same hook (see below for a list) may trigger
  75         differently depending on the the type of the variable.
  76
  77     *   Magic is invisible at Perl level.
  78
  79         Magical and non-magical variables cannot be distinguished with
  80         "ref", "tied" or another trick.
  81
  82     *   Magic is notably faster.
  83
  84         Mainly because perl's way of handling magic is lighter by nature,
  85         and because there is no need for any method resolution. Also, since
  86         you don't have to reimplement all the variable semantics, you only
  87         pay for what you actually use.
  88
  89     The operations that can be overloaded are :
  90
  91     *   *get*
  92
  93         This magic is invoked when the variable is evaluated. It is never
  94         called for arrays and hashes.
  95
  96     *   *set*
  97
  98         This magic is called each time the value of the variable changes. It
  99         is called for array subscripts and slices, but never for hashes.
 100
 101     *   *len*
 102
 103         This magic only applies to scalars and arrays, and is triggered when
 104         the 'size' or the 'length' of the variable has to be known by Perl.
 105         This is typically the magic involved when an array is evaluated in
 106         scalar context, but also on array assignment and loops ("for", "map"
 107         or "grep"). The length is returned from the callback as an integer.
 108
 109     *   *clear*
 110
 111         This magic is invoked when the variable is reset, such as when an
 112         array is emptied. Please note that this is different from undefining
 113         the variable, even though the magic is called when the clearing is a
 114         result of the undefine (e.g. for an array, but actually a bug
 115         prevent it to work before perl 5.9.5 - see the history).
 116
 117     *   *free*
 118
 119         This magic is called when a variable is destroyed as the result of
 120         going out of scope (but not when it is undefined). It behaves
 121         roughly like Perl object destructors (i.e. "DESTROY" methods),
 122         except that exceptions thrown from inside a *free* callback will
 123         always be propagated to the surrounding code.
 124
 125     *   *copy*
 126
 127         This magic only applies to tied arrays and hashes, and fires when
 128         you try to access or change their elements.
 129
 130     *   *dup*
 131
 132         This magic is invoked when the variable is cloned across threads. It
 133         is currently not available.
 134
 135     *   *local*
 136
 137         When this magic is set on a variable, all subsequent localizations
 138         of the variable will trigger the callback. It is available on your
 139         perl if and only if "MGf_LOCAL" is true.
 140
 141     The following actions only apply to hashes and are available if and only
 142     if "VMG_UVAR" is true. They are referred to as *uvar* magics.
 143
 144     *   *fetch*
 145
 146         This magic is invoked each time an element is fetched from the hash.
 147
 148     *   *store*
 149
 150         This one is called when an element is stored into the hash.
 151
 152     *   *exists*
 153
 154         This magic fires when a key is tested for existence in the hash.
 155
 156     *   *delete*
 157
 158         This magic is triggered when a key is deleted in the hash,
 159         regardless of whether the key actually exists in it.
 160
 161     You can refer to the tests to have more insight of where the different
 162     magics are invoked.
 163
 164 FUNCTIONS
 165   "wizard"
 166         wizard(
 167          data     => sub { ... },
 168          get      => sub { my ($ref, $data [, $op]) = @_; ... },
 169          set      => sub { my ($ref, $data [, $op]) = @_; ... },
 170          len      => sub {
 171           my ($ref, $data, $len [, $op]) = @_; ... ; return $newlen
 172          },
 173          clear    => sub { my ($ref, $data [, $op]) = @_; ... },
 174          free     => sub { my ($ref, $data [, $op]) = @_, ... },
 175          copy     => sub { my ($ref, $data, $key, $elt [, $op]) = @_; ... },
 176          local    => sub { my ($ref, $data [, $op]) = @_; ... },
 177          fetch    => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 178          store    => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 179          exists   => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 180          delete   => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 181          copy_key => $bool,
 182          op_info  => [ 0 | VMG_OP_INFO_NAME | VMG_OP_INFO_OBJECT ],
 183         )
 184
 185     This function creates a 'wizard', an opaque object that holds the magic
 186     information. It takes a list of keys / values as argument, whose keys
 187     can be :
 188
 189     *   "data"
 190
 191         A code (or string) reference to a private data constructor. It is
 192         called in scalar context each time the magic is cast onto a
 193         variable, with $_[0] being a reference to this variable and @_[1 ..
 194         @_-1] being all extra arguments that were passed to "cast". The
 195         scalar returned from this call is then attached to the variable and
 196         can be retrieved later with "getdata".
 197
 198     *   "get", "set", "len", "clear", "free", "copy", "local", "fetch",
 199         "store", "exists" and "delete"
 200
 201         Code (or string) references to the respective magic callbacks. You
 202         don't have to specify all of them : the magic corresponding to
 203         undefined entries will simply not be hooked.
 204
 205         When those callbacks are executed, $_[0] is a reference to the magic
 206         variable and $_[1] is the associated private data (or "undef" when
 207         no private data constructor is supplied with the wizard). Other
 208         arguments depend on which kind of magic is involved :
 209
 210         *       *len*
 211
 212                 $_[2] contains the natural, non-magical length of the
 213                 variable (which can only be a scalar or an array as *len*
 214                 magic is only relevant for these types). The callback is
 215                 expected to return the new scalar or array length to use, or
 216                 "undef" to default to the normal length.
 217
 218         *       *copy*
 219
 220                 $_[2] is a either an alias or a copy of the current key, and
 221                 $_[3] is an alias to the current element (i.e. the value).
 222                 Because $_[2] might be a copy, it is useless to try to
 223                 change it or cast magic on it.
 224
 225         *       *fetch*, *store*, *exists* and *delete*
 226
 227                 $_[2] is an alias to the current key. Note that $_[2] may
 228                 rightfully be readonly if the key comes from a bareword, and
 229                 as such it is unsafe to assign to it. You can ask for a copy
 230                 instead by passing "copy_key => 1" to "wizard" which, at the
 231                 price of a small performance hit, allows you to safely
 232                 assign to $_[2] in order to e.g. redirect the action to
 233                 another key.
 234
 235         Finally, if "op_info => $num" is also passed to "wizard", then one
 236         extra element is appended to @_. Its nature depends on the value of
 237         $num :
 238
 239         *       "VMG_OP_INFO_NAME"
 240
 241                 $_[-1] is the current op name.
 242
 243         *       "VMG_OP_INFO_OBJECT"
 244
 245                 $_[-1] is the "B::OP" object for the current op.
 246
 247         Both result in a small performance hit, but just getting the name is
 248         lighter than getting the op object.
 249
 250         These callbacks are executed in scalar context and are expected to
 251         return an integer, which is then passed straight to the perl magic
 252         API. However, only the return value of the *len* magic callback
 253         currently holds a meaning.
 254
 255     Each callback can be specified as :
 256
 257     *   a code reference, which will be called as a subroutine.
 258
 259     *   a string reference, where the string denotes which subroutine is to
 260         be called when magic is triggered. If the subroutine name is not
 261         fully qualified, then the current package at the time the magic is
 262         invoked will be used instead.
 263
 264     *   a reference to "undef", in which case a no-op magic callback is
 265         installed instead of the default one. This may especially be helpful
 266         for *local* magic, where an empty callback prevents magic from being
 267         copied during localization.
 268
 269     Note that *free* magic is never called during global destruction, as
 270     there is no way to ensure that the wizard object and the callback were
 271     not destroyed before the variable.
 272
 273     Here is a simple usage example :
 274
 275         # A simple scalar tracer
 276         my $wiz = wizard(
 277          get  => sub { print STDERR "got ${$_[0]}\n" },
 278          set  => sub { print STDERR "set to ${$_[0]}\n" },
 279          free => sub { print STDERR "${$_[0]} was deleted\n" },
 280         );
 281
 282   "cast"
 283         cast [$@%&*]var, $wiz, @args
 284
 285     This function associates $wiz magic to the supplied variable, without
 286     overwriting any other kind of magic. It returns true on success or when
 287     $wiz magic is already attached, and croaks on error. When $wiz provides
 288     a data constructor, it is called just before magic is cast onto the
 289     variable, and it receives a reference to the target variable in $_[0]
 290     and the content of @args in @_[1 .. @args]. Otherwise, @args is ignored.
 291
 292         # Casts $wiz onto $x, passing (\$x, '1') to the data constructor.
 293         my $x;
 294         cast $x, $wiz, 1;
 295
 296     The "var" argument can be an array or hash value. Magic for these
 297     scalars behaves like for any other, except that it is dispelled when the
 298     entry is deleted from the container. For example, if you want to call
 299     "POSIX::tzset" each time the 'TZ' environment variable is changed in
 300     %ENV, you can use :
 301
 302         use POSIX;
 303         cast $ENV{TZ}, wizard set => sub { POSIX::tzset(); () };
 304
 305     If you want to handle the possible deletion of the 'TZ' entry, you must
 306     also specify *store* magic.
 307
 308   "getdata"
 309         getdata [$@%&*]var, $wiz
 310
 311     This accessor fetches the private data associated with the magic $wiz in
 312     the variable. It croaks when $wiz does not represent a valid magic
 313     object, and returns an empty list if no such magic is attached to the
 314     variable or when the wizard has no data constructor.
 315
 316         # Get the data attached to $wiz in $x, or undef if $wiz
 317         # did not attach any.
 318         my $data = getdata $x, $wiz;
 319
 320   "dispell"
 321         dispell [$@%&*]variable, $wiz
 322
 323     The exact opposite of "cast" : it dissociates $wiz magic from the
 324     variable. This function returns true on success, 0 when no magic
 325     represented by $wiz could be found in the variable, and croaks if the
 326     supplied wizard is invalid.
 327
 328         # Dispell now.
 329         die 'no such magic in $x' unless dispell $x, $wiz;
 330
 331 CONSTANTS
 332   "MGf_COPY"
 333     Evaluates to true if and only if the *copy* magic is available. This is
 334     the case for perl 5.7.3 and greater, which is ensured by the
 335     requirements of this module.
 336
 337   "MGf_DUP"
 338     Evaluates to true if and only if the *dup* magic is available. This is
 339     the case for perl 5.7.3 and greater, which is ensured by the
 340     requirements of this module.
 341
 342   "MGf_LOCAL"
 343     Evaluates to true if and only if the *local* magic is available. This is
 344     the case for perl 5.9.3 and greater.
 345
 346   "VMG_UVAR"
 347     When this constant is true, you can use the *fetch*, *store*, *exists*
 348     and *delete* magics on hashes. Initial "VMG_UVAR" capability was
 349     introduced in perl 5.9.5, with a fully functional implementation shipped
 350     with perl 5.10.0.
 351
 352   "VMG_COMPAT_SCALAR_LENGTH_NOLEN"
 353     True for perls that don't call *len* magic when taking the "length" of a
 354     magical scalar.
 355
 356   "VMG_COMPAT_ARRAY_PUSH_NOLEN"
 357     True for perls that don't call *len* magic when you push an element in a
 358     magical array. Starting from perl 5.11.0, this only refers to pushes in
 359     non-void context and hence is false.
 360
 361   "VMG_COMPAT_ARRAY_PUSH_NOLEN_VOID"
 362     True for perls that don't call *len* magic when you push in void context
 363     an element in a magical array.
 364
 365   "VMG_COMPAT_ARRAY_UNSHIFT_NOLEN_VOID"
 366     True for perls that don't call *len* magic when you unshift in void
 367     context an element in a magical array.
 368
 369   "VMG_COMPAT_ARRAY_UNDEF_CLEAR"
 370     True for perls that call *clear* magic when undefining magical arrays.
 371
 372   "VMG_COMPAT_HASH_DELETE_NOUVAR_VOID"
 373     True for perls that don't call *delete* magic when you delete an element
 374     from a hash in void context.
 375
 376   "VMG_COMPAT_GLOB_GET"
 377     True for perls that call *get* magic for operations on globs.
 378
 379   "VMG_PERL_PATCHLEVEL"
 380     The perl patchlevel this module was built with, or 0 for non-debugging
 381     perls.
 382
 383   "VMG_THREADSAFE"
 384     True if and only if this module could have been built with thread-safety
 385     features enabled.
 386
 387   "VMG_FORKSAFE"
 388     True if and only if this module could have been built with fork-safety
 389     features enabled. This is always true except on Windows where it is
 390     false for perl 5.10.0 and below.
 391
 392   "VMG_OP_INFO_NAME"
 393     Value to pass with "op_info" to get the current op name in the magic
 394     callbacks.
 395
 396   "VMG_OP_INFO_OBJECT"
 397     Value to pass with "op_info" to get a "B::OP" object representing the
 398     current op in the magic callbacks.
 399
 400 COOKBOOK
 401   Associate an object to any perl variable
 402     This technique can be useful for passing user data through limited APIs.
 403     It is similar to using inside-out objects, but without the drawback of
 404     having to implement a complex destructor.
 405
 406         {
 407          package Magical::UserData;
 408
 409          use Variable::Magic qw<wizard cast getdata>;
 410
 411          my $wiz = wizard data => sub { \$_[1] };
 412
 413          sub ud (\[$@%*&]) : lvalue {
 414           my ($var) = @_;
 415           my $data = &getdata($var, $wiz);
 416           unless (defined $data) {
 417            $data = \(my $slot);
 418            &cast($var, $wiz, $slot)
 419                      or die "Couldn't cast UserData magic onto the variable";
 420           }
 421           $$data;
 422          }
 423         }
 424
 425         {
 426          BEGIN { *ud = \&Magical::UserData::ud }
 427
 428          my $cb;
 429          $cb = sub { print 'Hello, ', ud(&$cb), "!\n" };
 430
 431          ud(&$cb) = 'world';
 432          $cb->(); # Hello, world!
 433         }
 434
 435   Recursively cast magic on datastructures
 436     "cast" can be called from any magical callback, and in particular from
 437     "data". This allows you to recursively cast magic on datastructures :
 438
 439         my $wiz;
 440         $wiz = wizard data => sub {
 441          my ($var, $depth) = @_;
 442          $depth ||= 0;
 443          my $r = ref $var;
 444          if ($r eq 'ARRAY') {
 445           &cast((ref() ? $_ : \$_), $wiz, $depth + 1) for @$var;
 446          } elsif ($r eq 'HASH') {
 447           &cast((ref() ? $_ : \$_), $wiz, $depth + 1) for values %$var;
 448          }
 449          return $depth;
 450         },
 451         free => sub {
 452          my ($var, $depth) = @_;
 453          my $r = ref $var;
 454          print "free $r at depth $depth\n";
 455          ();
 456         };
 457
 458         {
 459          my %h = (
 460           a => [ 1, 2 ],
 461           b => { c => 3 }
 462          );
 463          cast %h, $wiz;
 464         }
 465
 466     When %h goes out of scope, this prints something among the lines of :
 467
 468         free HASH at depth 0
 469         free HASH at depth 1
 470         free SCALAR at depth 2
 471         free ARRAY at depth 1
 472         free SCALAR at depth 3
 473         free SCALAR at depth 3
 474
 475     Of course, this example does nothing with the values that are added
 476     after the "cast".
 477
 478 PERL MAGIC HISTORY
 479     The places where magic is invoked have changed a bit through perl
 480     history. Here is a little list of the most recent ones.
 481
 482     *   5.6.x
 483
 484         *p14416* : *copy* and *dup* magic.
 485
 486     *   5.8.9
 487
 488         *p28160* : Integration of *p25854* (see below).
 489
 490         *p32542* : Integration of *p31473* (see below).
 491
 492     *   5.9.3
 493
 494         *p25854* : *len* magic is no longer called when pushing an element
 495         into a magic array.
 496
 497         *p26569* : *local* magic.
 498
 499     *   5.9.5
 500
 501         *p31064* : Meaningful *uvar* magic.
 502
 503         *p31473* : *clear* magic was not invoked when undefining an array.
 504         The bug is fixed as of this version.
 505
 506     *   5.10.0
 507
 508         Since "PERL_MAGIC_uvar" is uppercased, "hv_magic_check()" triggers
 509         *copy* magic on hash stores for (non-tied) hashes that also have
 510         *uvar* magic.
 511
 512     *   5.11.x
 513
 514         *p32969* : *len* magic is no longer invoked when calling "length"
 515         with a magical scalar.
 516
 517         *p34908* : *len* magic is no longer called when pushing / unshifting
 518         an element into a magical array in void context. The "push" part was
 519         already covered by *p25854*.
 520
 521         *g9cdcb38b* : *len* magic is called again when pushing into a
 522         magical array in non-void context.
 523
 524 EXPORT
 525     The functions "wizard", "cast", "getdata" and "dispell" are only
 526     exported on request. All of them are exported by the tags ':funcs' and
 527     ':all'.
 528
 529     All the constants are also only exported on request, either individually
 530     or by the tags ':consts' and ':all'.
 531
 532 CAVEATS
 533     In order to hook hash operations with magic, you need at least perl
 534     5.10.0 (see "VMG_UVAR").
 535
 536     If you want to store a magic object in the private data slot, you will
 537     not be able to recover the magic with "getdata", since magic is not
 538     copied by assignment. You can work around this gotcha by storing a
 539     reference to the magic object instead.
 540
 541     If you define a wizard with *free* magic and cast it on itself, it
 542     results in a memory cycle, so this destructor will not be called when
 543     the wizard is freed.
 544
 545 DEPENDENCIES
 546     perl 5.8.
 547
 548     A C compiler. This module may happen to build with a C++ compiler as
 549     well, but don't rely on it, as no guarantee is made in this regard.
 550
 551     Carp (core since perl 5), XSLoader (since 5.006).
 552
 553     Copy tests need Tie::Array (core since perl 5.005) and Tie::Hash (since
 554     5.002). Some uvar tests need Hash::Util::FieldHash (since 5.009004).
 555     Glob tests need Symbol (since 5.002). Threads tests need threads and
 556     threads::shared (both since 5.007003).
 557
 558 SEE ALSO
 559     perlguts and perlapi for internal information about magic.
 560
 561     perltie and overload for other ways of enhancing objects.
 562
 563 AUTHOR
 564     Vincent Pit, "<perl at profvince.com>", <http://www.profvince.com>.
 565
 566     You can contact me by mail or on "irc.perl.org" (vincent).
 567
 568 BUGS
 569     Please report any bugs or feature requests to "bug-variable-magic at
 570     rt.cpan.org", or through the web interface at
 571     <http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Variable-Magic>. I will
 572     be notified, and then you'll automatically be notified of progress on
 573     your bug as I make changes.
 574
 575 SUPPORT
 576     You can find documentation for this module with the perldoc command.
 577
 578         perldoc Variable::Magic
 579
 580     Tests code coverage report is available at
 581     <http://www.profvince.com/perl/cover/Variable-Magic>.
 582
 583 COPYRIGHT & LICENSE
 584     Copyright 2007,2008,2009,2010,2011,2012 Vincent Pit, all rights
 585     reserved.
 586
 587     This program is free software; you can redistribute it and/or modify it
 588     under the same terms as Perl itself.
 589