lib/VPIT/TestHelpers.pm

   1 package VPIT::TestHelpers;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Config ();
   7
   8 sub export_to_pkg {
   9  my ($subs, $pkg) = @_;
  10
  11  while (my ($name, $code) = each %$subs) {
  12   no strict 'refs';
  13   *{$pkg.'::'.$name} = $code;
  14  }
  15
  16  return 1;
  17 }
  18
  19 my %exports = (
  20  load_or_skip     => \&load_or_skip,
  21  load_or_skip_all => \&load_or_skip_all,
  22  run_perl         => \&run_perl,
  23  skip_all         => \&skip_all,
  24 );
  25
  26 sub import {
  27  my $pkg = caller;
  28
  29  export_to_pkg \%exports => $pkg;
  30 }
  31
  32 my $test_sub = sub {
  33  my $sub = shift;
  34
  35  my $stash;
  36  if ($INC{'Test/Leaner.pm'}) {
  37   $stash = \%Test::Leaner::;
  38  } else {
  39   require Test::More;
  40   $stash = \%Test::More::;
  41  }
  42
  43  my $glob = $stash->{$sub};
  44  return $glob ? *$glob{CODE} : undef;
  45 };
  46
  47 sub skip { $test_sub->('skip')->(@_) }
  48
  49 sub skip_all { $test_sub->('plan')->(skip_all => $_[0]) }
  50
  51 sub diag {
  52  my $diag = $test_sub->('diag');
  53  $diag->($_) for @_;
  54 }
  55
  56 our $TODO;
  57 local $TODO;
  58
  59 sub load {
  60  my ($pkg, $ver, $imports) = @_;
  61
  62  my $spec = $ver && $ver !~ /^[0._]*$/ ? "$pkg $ver" : $pkg;
  63  my $err;
  64
  65  local $@;
  66  if (eval "use $spec (); 1") {
  67   $ver = do { no strict 'refs'; ${"${pkg}::VERSION"} };
  68   $ver = 'undef' unless defined $ver;
  69
  70   if ($imports) {
  71    my @imports = @$imports;
  72    my $caller  = (caller 1)[0];
  73    local $@;
  74    my $res = eval <<"IMPORTER";
  75 package
  76         $caller;
  77 BEGIN { \$pkg->import(\@imports) }
  78 1;
  79 IMPORTER
  80    $err = "Could not import '@imports' from $pkg $ver: $@" unless $res;
  81   }
  82  } else {
  83   (my $file = "$pkg.pm") =~ s{::}{/}g;
  84   delete $INC{$file};
  85   $err = "Could not load $spec";
  86  }
  87
  88  if ($err) {
  89   return wantarray ? (0, $err) : 0;
  90  } else {
  91   diag "Using $pkg $ver";
  92   return 1;
  93  }
  94 }
  95
  96 sub load_or_skip {
  97  my ($pkg, $ver, $imports, $tests) = @_;
  98
  99  die 'You must specify how many tests to skip' unless defined $tests;
 100
 101  my ($loaded, $err) = load($pkg, $ver, $imports);
 102  skip $err => $tests unless $loaded;
 103
 104  return $loaded;
 105 }
 106
 107 sub load_or_skip_all {
 108  my ($pkg, $ver, $imports) = @_;
 109
 110  my ($loaded, $err) = load($pkg, $ver, $imports);
 111  skip_all $err unless $loaded;
 112
 113  return $loaded;
 114 }
 115
 116 sub run_perl {
 117  my $code = shift;
 118
 119  my ($SystemRoot, $PATH) = @ENV{qw<SystemRoot PATH>};
 120  my $ld_name  = $Config::Config{ldlibpthname};
 121  my $ldlibpth = $ENV{$ld_name};
 122
 123  local %ENV;
 124  $ENV{$ld_name}   = $ldlibpth   if                      defined $ldlibpth;
 125  $ENV{SystemRoot} = $SystemRoot if $^O eq 'MSWin32' and defined $SystemRoot;
 126  $ENV{PATH}       = $PATH       if $^O eq 'cygwin'  and defined $PATH;
 127
 128  system { $^X } $^X, '-T', map("-I$_", @INC), '-e', $code;
 129 }
 130
 131 package VPIT::TestHelpers::Guard;
 132
 133 sub new {
 134  my ($class, $code) = @_;
 135
 136  bless { code => $code }, $class;
 137 }
 138
 139 sub DESTROY { $_[0]->{code}->() }
 140
 141 1;