lib/Test/Valgrind/Tool/memcheck.pm

   1 package Test::Valgrind::Tool::memcheck;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 Test::Valgrind::Tool::memcheck - Run an analysis through the memcheck tool.
   9
  10 =head1 VERSION
  11
  12 Version 1.02
  13
  14 =cut
  15
  16 our $VERSION = '1.02';
  17
  18 =head1 DESCRIPTION
  19
  20 This tool parses the XML output of a C<memcheck> run with L<XML::Twig>.
  21
  22 =cut
  23
  24 use base qw/Test::Valgrind::Tool/;
  25
  26 =head1 METHODS
  27
  28 This class inherits L<Test::Valgrind::Tool>.
  29
  30 =head2 C<requires_version>
  31
  32 This tool requires C<valgrind> C<3.1.0>.
  33
  34 =cut
  35
  36 sub requires_version { '3.1.0' }
  37
  38 =head2 C<< new callers => $callers, ... >>
  39
  40 Your usual constructor.
  41
  42 C<$callers> specifies the number of stack frames to inspect for errors : the bigger you set it, the more granular the analysis is.
  43
  44 Other arguments are passed straight to C<< Test::Valgrind::Tool->new >>.
  45
  46 =cut
  47
  48 sub new {
  49  my $class = shift;
  50  $class = ref($class) || $class;
  51
  52  my %args = @_;
  53
  54  my $callers = delete $args{callers} || 12;
  55  $callers =~ s/\D//g;
  56
  57  my $self = bless $class->Test::Valgrind::Tool::new(%args), $class;
  58
  59  $self->{callers} = $callers;
  60
  61  $self;
  62 }
  63
  64 sub new_trainer { shift->new(callers => 50) }
  65
  66 =head2 C<callers>
  67
  68 Read-only accessor for the C<callers> option.
  69
  70 =cut
  71
  72 sub callers { $_[0]->{callers} }
  73
  74 sub suppressions_tag { 'memcheck-' . $_[1]->version }
  75
  76 =head2 C<report_class_analysis $session>
  77
  78 This tool emits C<Test::Valgrind::Tool::memcheck::Report> object reports in analysis mode.
  79
  80 =cut
  81
  82 sub report_class_analysis { 'Test::Valgrind::Tool::memcheck::Report' }
  83
  84 sub args {
  85  my $self = shift;
  86  my ($sess) = @_;
  87
  88  my @args = (
  89   '--tool=memcheck',
  90   '--leak-check=full',
  91   '--leak-resolution=high',
  92   '--show-reachable=yes',
  93   '--num-callers=' . $self->callers,
  94   '--error-limit=yes',
  95  );
  96
  97  unless ($sess->do_suppressions) {
  98   push @args, '--track-origins=yes' if $sess->version ge '3.4.0';
  99   push @args, '--xml=yes';
 100  }
 101
 102  push @args, $self->SUPER::args(@_);
 103
 104  return @args;
 105 }
 106
 107 =head1 SEE ALSO
 108
 109 L<Test::Valgrind>, L<Test::Valgrind::Tool>.
 110
 111 L<XML::Twig>.
 112
 113 =head1 AUTHOR
 114
 115 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 116
 117 You can contact me by mail or on C<irc.perl.org> (vincent).
 118
 119 =head1 BUGS
 120
 121 Please report any bugs or feature requests to C<bug-test-valgrind at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Test-Valgrind>.
 122 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 123
 124 =head1 SUPPORT
 125
 126 You can find documentation for this module with the perldoc command.
 127
 128     perldoc Test::Valgrind::Tool::memcheck
 129
 130 =head1 COPYRIGHT & LICENSE
 131
 132 Copyright 2009 Vincent Pit, all rights reserved.
 133
 134 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 135
 136 =cut
 137
 138 # End of Test::Valgrind::Tool::memcheck
 139
 140 package Test::Valgrind::Tool::memcheck::Report;
 141
 142 use base qw/Test::Valgrind::Report/;
 143
 144 our $VERSION = '1.02';
 145
 146 my @kinds = qw/
 147  InvalidFree
 148  MismatchedFree
 149  InvalidRead
 150  InvalidWrite
 151  InvalidJump
 152  Overlap
 153  InvalidMemPool
 154  UninitCondition
 155  UninitValue
 156  SyscallParam
 157  ClientCheck
 158  Leak_DefinitelyLost
 159  Leak_IndirectlyLost
 160  Leak_PossiblyLost
 161  Leak_StillReachable
 162 /;
 163 push @kinds, __PACKAGE__->SUPER::kinds();
 164
 165 my %kinds_hashed = map { $_ => 1 } @kinds;
 166
 167 sub kinds      { @kinds }
 168
 169 sub valid_kind { exists $kinds_hashed{$_[1]} }
 170
 171 sub is_leak    { $_[0]->kind =~ /^Leak_/ ? 1 : '' }
 172
 173 my $pad;
 174 BEGIN {
 175  require Config;
 176  $pad = 2 * ($Config::Config{ptrsize} || 4);
 177 }
 178
 179 sub dump {
 180  my ($self) = @_;
 181
 182  my $data = $self->data;
 183
 184  my $desc = '';
 185
 186  for ([ '', 2, 4 ], [ 'aux', 4, 6 ], [ 'orig', 4, 6 ]) {
 187   my ($prefix, $wind, $sind) = @$_;
 188
 189   my ($what, $stack) = @{$data}{"${prefix}what", "${prefix}stack"};
 190   next unless defined $what and defined $stack;
 191
 192   $_ = ' ' x $_ for $wind, $sind;
 193
 194   $desc .= "$wind$what\n";
 195   for (@$stack) {
 196    my ($ip, $obj, $fn, $dir, $file, $line) = map { (defined) ? $_ : '?' } @$_;
 197    my $frame;
 198    if ($fn eq '?' and $obj eq '?') {
 199     $ip =~ s/^0x//g;
 200     $ip = hex $ip;
 201     $frame = sprintf "0x%0${pad}X", $ip;
 202    } else {
 203     $frame = sprintf '%s (%s) [%s:%s]', $fn, $obj, $file, $line;
 204    }
 205    $desc .= "$sind$frame\n";
 206   }
 207  }
 208
 209  return $desc;
 210 }
 211
 212 # End of Test::Valgrind::Tool::memcheck::Report
 213