lib/Test/Valgrind/Session.pm

   1 package Test::Valgrind::Session;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 Test::Valgrind::Session - Test::Valgrind session object.
   9
  10 =head1 VERSION
  11
  12 Version 1.01
  13
  14 =cut
  15
  16 our $VERSION = '1.01';
  17
  18 =head1 DESCRIPTION
  19
  20 This class supervises the execution of the C<valgrind> process.
  21 It also acts as a dispatcher between the different components.
  22
  23 =cut
  24
  25 # All these modules are required at configure time.
  26
  27 BEGIN {
  28  require File::Spec;
  29  require Scalar::Util;
  30
  31  require Fcntl; # F_SETFD
  32  require POSIX; # SIGKILL
  33 }
  34
  35 use base qw/Test::Valgrind::Carp/;
  36
  37 use Test::Valgrind::Report;
  38
  39 =head1 METHODS
  40
  41 =head2 C<< new search_dirs => \@search_dirs, valgrind => [ $valgrind | \@valgrind ], min_version => $min_version, no_def_supp => $no_def_supp, extra_supps => \@extra_supps >>
  42
  43 The package constructor, which takes several options :
  44
  45 =over 4
  46
  47 =item *
  48
  49 All the directories from C<@search_dirs> will have F<valgrind> appended to create a list of candidates for the C<valgrind> executable.
  50
  51 Defaults to the current C<PATH> environment variable.
  52
  53 =item *
  54
  55 If a simple scalar C<$valgrind> is passed as the value to C<'valgrind'>, it will be the only candidate.
  56 C<@search_dirs> will then be ignored.
  57
  58 If an array refernce C<\@valgrind> is passed, its values will be I<prepended> to the list of the candidates resulting from C<@search_dirs>.
  59
  60 =item *
  61
  62 C<$min_version> specifies the minimal C<valgrind> version required.
  63 The constructor will croak if it's not able to find an adequate C<valgrind> from the supplied candidates list and search path.
  64
  65 Defaults to none.
  66
  67 =item *
  68
  69 If C<$no_def_supp> is false, C<valgrind> won't read the default suppression file associated with the tool and the command.
  70
  71 Defaults to false.
  72
  73 =item *
  74
  75 C<$extra_supps> is a reference to an array of optional suppression files that will be passed to C<valgrind>.
  76
  77 Defaults to none.
  78
  79 =back
  80
  81 =cut
  82
  83 my $build_version = sub {
  84  require version;
  85  version->new($_[0]);
  86 };
  87
  88 sub new {
  89  my $class = shift;
  90  $class = ref($class) || $class;
  91
  92  my %args = @_;
  93
  94  my @paths;
  95  my $vg = delete $args{vg};
  96  if (defined $vg and not ref $vg) {
  97   @paths = ($vg);
  98  } else {
  99   push @paths, @$vg if $vg and ref $vg eq 'ARRAY';
 100   my $dirs = delete $args{search_dirs};
 101   $dirs = [ File::Spec->path ] unless $dirs;
 102   push @paths, map File::Spec->catfile($_, 'valgrind'), @$dirs
 103                                                         if ref $dirs eq 'ARRAY';
 104  }
 105  $class->_croak('Empty valgrind candidates list') unless @paths;
 106
 107  my $min_version = delete $args{min_version};
 108  defined and not ref and $_ = $build_version->($_) for $min_version;
 109
 110  my ($valgrind, $version);
 111  for (@paths) {
 112   next unless -x;
 113   my $ver = qx/$_ --version/;
 114   if ($ver =~ /^valgrind-(\d+(\.\d+)*)/) {
 115    if ($min_version) {
 116     $version = $build_version->($1);
 117     next if $version < $min_version;
 118    } else {
 119     $version = $1;
 120    }
 121    $valgrind = $_;
 122    last;
 123   }
 124  }
 125  $class->_croak('No appropriate valgrind executable could be found')
 126                                                        unless defined $valgrind;
 127
 128  my $extra_supps = delete $args{extra_supps};
 129  $extra_supps    = [ ] unless $extra_supps and ref $extra_supps eq 'ARRAY';
 130  @$extra_supps   = grep { defined && -f $_ && -r _ } @$extra_supps;
 131
 132  bless {
 133   valgrind    => $valgrind,
 134   version     => $version,
 135   no_def_supp => delete($args{no_def_supp}),
 136   extra_supps => $extra_supps,
 137  }, $class;
 138 }
 139
 140 =head2 C<valgrind>
 141
 142 The path to the selected C<valgrind> executable.
 143
 144 =head2 C<version>
 145
 146 The L<version> object associated to the selected C<valgrind>.
 147
 148 =cut
 149
 150 sub version {
 151  my ($self) = @_;
 152
 153  my $version = $self->{version};
 154  $self->{version} = $version = $build_version->($version) unless ref $version;
 155
 156  return $version;
 157 }
 158
 159 =head2 C<no_def_supp>
 160
 161 Read-only accessor for the C<no_def_supp> option.
 162
 163 =cut
 164
 165 eval "sub $_ { \$_[0]->{$_} }" for qw/valgrind no_def_supp/;
 166
 167 =head2 C<extra_supps>
 168
 169 Read-only accessor for the C<extra_supps> option.
 170
 171 =cut
 172
 173 sub extra_supps { @{$_[0]->{extra_supps} || []} }
 174
 175 =head2 C<< run action => $action, tool => $tool, command => $command >>
 176
 177 Runs the command C<$command> through C<valgrind> with the tool C<$tool>, which will report to the action C<$action>.
 178
 179 =cut
 180
 181 sub run {
 182  my $self = shift;
 183
 184  $self->start(@_);
 185  my $guard = bless sub { $self->finish } => 'Test::Valgrind::Session::Guard';
 186
 187  $self->report(Test::Valgrind::Report->new_diag(
 188   'Using valgrind ' . $self->version . ' located at ' . $self->valgrind
 189  ));
 190
 191  my $env = $self->command->env($self);
 192
 193  my @supp_args;
 194  if ($self->do_suppressions) {
 195   push @supp_args, '--gen-suppressions=all';
 196  } else {
 197   my @supps;
 198   if (not $self->no_def_supp) {
 199    my $def_supp = $self->def_supp_file;
 200    if (defined $def_supp and not -e $def_supp) {
 201     $self->report(Test::Valgrind::Report->new_diag("Generating suppressions..."));
 202     require Test::Valgrind::Suppressions;
 203     Test::Valgrind::Suppressions->generate(
 204      tool    => $self->tool,
 205      command => $self->command,
 206      target  => $def_supp,
 207     );
 208     $self->_croak('Couldn\'t generate suppressions') unless -e $def_supp;
 209     $self->report(Test::Valgrind::Report->new_diag("Suppressions for this perl stored in $def_supp"));
 210    }
 211   }
 212   push @supp_args, '--suppressions=' . $_ for $self->suppressions;
 213  }
 214
 215  pipe my $vrdr, my $vwtr or $self->_croak("pipe(\$vrdr, \$vwtr): $!");
 216  {
 217   my $oldfh = select $vrdr;
 218   $|++;
 219   select $oldfh;
 220  }
 221
 222  my $pid = fork;
 223  $self->_croak("fork(): $!") unless defined $pid;
 224
 225  if ($pid == 0) {
 226   eval 'setpgrp 0, 0';
 227   close $vrdr or $self->_croak("close(\$vrdr): $!");
 228   fcntl $vwtr, Fcntl::F_SETFD(), 0
 229                               or $self->_croak("fcntl(\$vwtr, F_SETFD, 0): $!");
 230
 231   my @args = (
 232    $self->valgrind,
 233    '--log-fd=' . fileno($vwtr),
 234    $self->tool->args($self),
 235    @supp_args,
 236    $self->command->args($self),
 237   );
 238
 239 #  $self->report(Test::Valgrind::Report->new_diag("@args"));
 240
 241   exec { $args[0] } @args or $self->_croak("exec @args: $!");
 242  }
 243
 244  local $SIG{INT} = sub {
 245   kill -(POSIX::SIGKILL()) => $pid;
 246   waitpid $pid, 0;
 247   die 'interrupted';
 248  };
 249
 250  close $vwtr or $self->_croak("close(\$vwtr): $!");
 251
 252  $self->tool->parse($self, $vrdr);
 253
 254  $self->{exit_code} = (waitpid($pid, 0) == $pid) ? $? >> 8 : 255;
 255
 256  close $vrdr or $self->_croak("close(\$vrdr): $!");
 257
 258  return;
 259 }
 260
 261 sub Test::Valgrind::Session::Guard::DESTROY { $_[0]->() }
 262
 263 =head2 C<action>
 264
 265 Read-only accessor for the C<action> associated to the current run.
 266
 267 =head2 C<tool>
 268
 269 Read-only accessor for the C<tool> associated to the current run.
 270
 271 =head2 C<command>
 272
 273 Read-only accessor for the C<command> associated to the current run.
 274
 275 =cut
 276
 277 my @members;
 278 BEGIN {
 279  @members = qw/action tool command/;
 280  for (@members) {
 281   eval "sub $_ { \@_ <= 1 ? \$_[0]->{$_} : (\$_[0]->{$_} = \$_[1]) }";
 282   die if $@;
 283  }
 284 }
 285
 286 =head2 C<do_suppressions>
 287
 288 Forwards to C<< ->action->do_suppressions >>.
 289
 290 =cut
 291
 292 sub do_suppressions { $_[0]->action->do_suppressions }
 293
 294 =head2 C<report_class>
 295
 296 Calls C<< ->action->report_class >> with the current session object as the sole argument.
 297
 298 =cut
 299
 300 sub report_class { $_[0]->tool->report_class($_[0]) }
 301
 302 =head2 C<def_supp_file>
 303
 304 Returns an absolute path to the default suppression file associated to the current session.
 305 C<undef> will be returned as soon as any of C<< ->tool->suppressions_tag >> or C<< ->tool->suppressions_tag >> are also C<undef>.
 306 Otherwise, the file part of the name is builded by joining those two together, and the directory part is roughly F<< File::HomeDir->my_home / .perl / Test-Valgrind / suppressions / $VERSION >>.
 307
 308 =cut
 309
 310 sub def_supp_file {
 311  my ($self) = @_;
 312
 313  my $tool_tag = $self->tool->suppressions_tag($self);
 314  return unless defined $tool_tag;
 315
 316  my $cmd_tag = $self->command->suppressions_tag($self);
 317  return unless defined $cmd_tag;
 318
 319  require File::HomeDir; # So that it's not needed at configure time.
 320
 321  return File::Spec->catfile(
 322   File::HomeDir->my_home,
 323   '.perl',
 324   'Test-Valgrind',
 325   'suppressions',
 326   $VERSION,
 327   "$tool_tag-$cmd_tag.supp",
 328  );
 329 }
 330
 331 =head2 C<suppressions>
 332
 333 Returns the list of all the suppressions that will be passed to C<valgrind>.
 334 Honors L</no_def_supp> and L</extra_supps>.
 335
 336 =cut
 337
 338 sub suppressions {
 339  my ($self) = @_;
 340
 341  my @supps;
 342  unless ($self->no_def_supp) {
 343   my $def_supp = $self->def_supp_file;
 344   push @supps, $def_supp if defined $def_supp;
 345  }
 346  push @supps, $self->extra_supps;
 347
 348  return @supps;
 349 }
 350
 351 =head2 C<start>
 352
 353 Starts the action and tool associated to the current run.
 354 It's automatically called at the beginning of L</run>.
 355
 356 =cut
 357
 358 sub start {
 359  my $self = shift;
 360
 361  my %args = @_;
 362
 363  for (@members) {
 364   my $base = 'Test::Valgrind::' . ucfirst;
 365   my $value = $args{$_};
 366   $self->_croak("Invalid $_") unless Scalar::Util::blessed($value)
 367                                                          and $value->isa($base);
 368   $self->$_($args{$_})
 369  }
 370
 371  delete @{$self}{qw/last_status exit_code/};
 372
 373  $self->tool->start($self);
 374  $self->action->start($self);
 375
 376  return;
 377 }
 378
 379 =head2 C<abort $msg>
 380
 381 Forwards to C<< ->action->abort >> after unshifting the session object to the argument list.
 382
 383 =cut
 384
 385 sub abort {
 386  my $self = shift;
 387  $self->action->abort($self, @_);
 388 }
 389
 390 =head2 C<report $report>
 391
 392 Forwards to C<< ->action->report >> after unshifting the session object to the argument list.
 393
 394 =cut
 395
 396 sub report {
 397  my $self = shift;
 398  $self->action->report($self, @_);
 399 }
 400
 401 =head2 C<finish>
 402
 403 Finishes the action and tool associated to the current run.
 404 It's automatically called at the end of L</run>.
 405
 406 =cut
 407
 408 sub finish {
 409  my ($self) = @_;
 410
 411  my $action = $self->action;
 412  $action->finish($self);
 413  $self->tool->finish($self);
 414
 415  my $status = $action->status($self);
 416  $self->{last_status} = defined $status ? $status : $self->{exit_code};
 417
 418  $self->$_(undef) for @members;
 419
 420  return;
 421 }
 422
 423 =head2 C<status>
 424
 425 Returns the status code of the last run of the session.
 426
 427 =cut
 428
 429 sub status { $_[0]->{last_status} }
 430
 431 =head1 SEE ALSO
 432
 433 L<Test::Valgrind>, L<Test::Valgrind::Action>, L<Test::Valgrind::Tool>, L<Test::Valgrind::Command>.
 434
 435 L<version>, L<File::HomeDir>.
 436
 437 =head1 AUTHOR
 438
 439 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 440
 441 You can contact me by mail or on C<irc.perl.org> (vincent).
 442
 443 =head1 BUGS
 444
 445 Please report any bugs or feature requests to C<bug-test-valgrind at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Test-Valgrind>.
 446 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 447
 448 =head1 SUPPORT
 449
 450 You can find documentation for this module with the perldoc command.
 451
 452     perldoc Test::Valgrind::Session
 453
 454 =head1 COPYRIGHT & LICENSE
 455
 456 Copyright 2009 Vincent Pit, all rights reserved.
 457
 458 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 459
 460 =cut
 461
 462 1; # End of Test::Valgrind::Session