lib/Test/Valgrind/Session.pm

   1 package Test::Valgrind::Session;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 Test::Valgrind::Session - Test::Valgrind session object.
   9
  10 =head1 VERSION
  11
  12 Version 1.10
  13
  14 =cut
  15
  16 our $VERSION = '1.10';
  17
  18 =head1 DESCRIPTION
  19
  20 This class supervises the execution of the C<valgrind> process.
  21 It also acts as a dispatcher between the different components.
  22
  23 =cut
  24
  25 use File::Spec   ();
  26 use Scalar::Util ();
  27
  28 use Fcntl (); # F_SETFD
  29 use POSIX (); # SIGKILL
  30
  31 use version ();
  32
  33 use base qw/Test::Valgrind::Carp/;
  34
  35 =head1 METHODS
  36
  37 =head2 C<< new search_dirs => \@search_dirs, valgrind => [ $valgrind | \@valgrind ], min_version => $min_version, no_def_supp => $no_def_supp, extra_supps => \@extra_supps >>
  38
  39 The package constructor, which takes several options :
  40
  41 =over 4
  42
  43 =item *
  44
  45 All the directories from C<@search_dirs> will have F<valgrind> appended to create a list of candidates for the C<valgrind> executable.
  46
  47 Defaults to the current C<PATH> environment variable.
  48
  49 =item *
  50
  51 If a simple scalar C<$valgrind> is passed as the value to C<'valgrind'>, it will be the only candidate.
  52 C<@search_dirs> will then be ignored.
  53
  54 If an array refernce C<\@valgrind> is passed, its values will be I<prepended> to the list of the candidates resulting from C<@search_dirs>.
  55
  56 =item *
  57
  58 C<$min_version> specifies the minimal C<valgrind> version required.
  59 The constructor will croak if it's not able to find an adequate C<valgrind> from the supplied candidates list and search path.
  60
  61 Defaults to none.
  62
  63 =item *
  64
  65 If C<$no_def_supp> is false, C<valgrind> won't read the default suppression file associated with the tool and the command.
  66
  67 Defaults to false.
  68
  69 =item *
  70
  71 C<$extra_supps> is a reference to an array of optional suppression files that will be passed to C<valgrind>.
  72
  73 Defaults to none.
  74
  75 =back
  76
  77 =cut
  78
  79 sub new {
  80  my $class = shift;
  81  $class = ref($class) || $class;
  82
  83  my %args = @_;
  84
  85  my @paths;
  86  my $vg = delete $args{valgrind};
  87  if (defined $vg and not ref $vg) {
  88   @paths = ($vg);
  89  } else {
  90   push @paths, @$vg if $vg and ref $vg eq 'ARRAY';
  91   my $dirs = delete $args{search_dirs};
  92   $dirs = [ File::Spec->path ] unless $dirs;
  93   push @paths, map File::Spec->catfile($_, 'valgrind'), @$dirs
  94                                                         if ref $dirs eq 'ARRAY';
  95  }
  96  $class->_croak('Empty valgrind candidates list') unless @paths;
  97
  98  my $min_version = delete $args{min_version};
  99  defined and not ref and $_ = version->new($_) for $min_version;
 100
 101  my ($valgrind, $version);
 102  for (@paths) {
 103   next unless -x;
 104   my $ver = qx/$_ --version/;
 105   if ($ver =~ /^valgrind-(\d+(\.\d+)*)/) {
 106    if ($min_version) {
 107     $version = version->new($1);
 108     next if $version < $min_version;
 109    } else {
 110     $version = $1;
 111    }
 112    $valgrind = $_;
 113    last;
 114   }
 115  }
 116  $class->_croak('No appropriate valgrind executable could be found')
 117                                                        unless defined $valgrind;
 118
 119  my $extra_supps = delete $args{extra_supps};
 120  $extra_supps    = [ ] unless $extra_supps and ref $extra_supps eq 'ARRAY';
 121  @$extra_supps   = grep { defined && -f $_ && -r _ } @$extra_supps;
 122
 123  bless {
 124   valgrind    => $valgrind,
 125   version     => $version,
 126   no_def_supp => delete($args{no_def_supp}),
 127   extra_supps => $extra_supps,
 128  }, $class;
 129 }
 130
 131 =head2 C<valgrind>
 132
 133 The path to the selected C<valgrind> executable.
 134
 135 =head2 C<version>
 136
 137 The L<version> object associated to the selected C<valgrind>.
 138
 139 =cut
 140
 141 sub version {
 142  my ($self) = @_;
 143
 144  my $version = $self->{version};
 145  $self->{version} = $version = version->new($version) unless ref $version;
 146
 147  return $version;
 148 }
 149
 150 =head2 C<no_def_supp>
 151
 152 Read-only accessor for the C<no_def_supp> option.
 153
 154 =cut
 155
 156 eval "sub $_ { \$_[0]->{$_} }" for qw/valgrind no_def_supp/;
 157
 158 =head2 C<extra_supps>
 159
 160 Read-only accessor for the C<extra_supps> option.
 161
 162 =cut
 163
 164 sub extra_supps { @{$_[0]->{extra_supps} || []} }
 165
 166 =head2 C<< run action => $action, tool => $tool, command => $command >>
 167
 168 Runs the command C<$command> through C<valgrind> with the tool C<$tool>, which will report to the action C<$action>.
 169
 170 If the command is a L<Test::Valgrind::Command::Aggregate> object, the action and the tool will be initialized once before running all the aggregated commands.
 171
 172 =cut
 173
 174 sub run {
 175  my $self = shift;
 176
 177  my %args = @_;
 178
 179  $self->start(%args);
 180  my $guard = bless sub { $self->finish } => 'Test::Valgrind::Session::Guard';
 181
 182  $self->_run($args{command});
 183 }
 184
 185 sub _run {
 186  my ($self, $cmd) = @_;
 187
 188  if ($cmd->isa('Test::Valgrind::Command::Aggregate')) {
 189   $self->_run($_) for $cmd->commands;
 190   return;
 191  }
 192
 193  $self->command($cmd);
 194
 195  $self->report($self->report_class->new_diag(
 196   'Using valgrind ' . $self->version . ' located at ' . $self->valgrind
 197  ));
 198
 199  my $env = $self->command->env($self);
 200
 201  my @supp_args;
 202  if ($self->do_suppressions) {
 203   push @supp_args, '--gen-suppressions=all';
 204  } elsif (not $self->no_def_supp) {
 205   my $def_supp = $self->def_supp_file;
 206   if (defined $def_supp and not -e $def_supp) {
 207    $self->report($self->report_class->new_diag(
 208     "Generating suppressions..."
 209    ));
 210    require Test::Valgrind::Suppressions;
 211    Test::Valgrind::Suppressions->generate(
 212     tool    => $self->tool,
 213     command => $self->command,
 214     target  => $def_supp,
 215    );
 216    $self->_croak('Couldn\'t generate suppressions') unless -e $def_supp;
 217    $self->report($self->report_class->new_diag(
 218     "Suppressions for this perl stored in $def_supp"
 219    ));
 220   }
 221   push @supp_args, '--suppressions=' . $_ for $self->suppressions;
 222  }
 223
 224  pipe my $vrdr, my $vwtr or $self->_croak("pipe(\$vrdr, \$vwtr): $!");
 225  {
 226   my $oldfh = select $vrdr;
 227   $|++;
 228   select $oldfh;
 229  }
 230
 231  my $pid = fork;
 232  $self->_croak("fork(): $!") unless defined $pid;
 233
 234  if ($pid == 0) {
 235   eval 'setpgrp 0, 0';
 236   close $vrdr or $self->_croak("close(\$vrdr): $!");
 237   fcntl $vwtr, Fcntl::F_SETFD(), 0
 238                               or $self->_croak("fcntl(\$vwtr, F_SETFD, 0): $!");
 239
 240   my @args = (
 241    $self->valgrind,
 242    $self->tool->args($self),
 243    @supp_args,
 244    $self->parser->args($self, $vwtr),
 245    $self->command->args($self),
 246   );
 247
 248 #  $self->report($self->report_class->new_diag("@args"));
 249
 250   exec { $args[0] } @args or $self->_croak("exec @args: $!");
 251  }
 252
 253  local $SIG{INT} = sub {
 254   kill -(POSIX::SIGKILL()) => $pid;
 255   waitpid $pid, 0;
 256   die 'interrupted';
 257  };
 258
 259  close $vwtr or $self->_croak("close(\$vwtr): $!");
 260
 261  $self->parser->parse($self, $vrdr);
 262
 263  $self->{exit_code} = (waitpid($pid, 0) == $pid) ? $? >> 8 : 255;
 264
 265  close $vrdr or $self->_croak("close(\$vrdr): $!");
 266
 267  return;
 268 }
 269
 270 sub Test::Valgrind::Session::Guard::DESTROY { $_[0]->() }
 271
 272 =head2 C<action>
 273
 274 Read-only accessor for the C<action> associated to the current run.
 275
 276 =head2 C<tool>
 277
 278 Read-only accessor for the C<tool> associated to the current run.
 279
 280 =head2 C<parser>
 281
 282 Read-only accessor for the C<parser> associated to the current tool.
 283
 284 =head2 C<command>
 285
 286 Read-only accessor for the C<command> associated to the current run.
 287
 288 =cut
 289
 290 my @members;
 291 BEGIN {
 292  @members = qw/action tool command parser/;
 293  for (@members) {
 294   eval "sub $_ { \@_ <= 1 ? \$_[0]->{$_} : (\$_[0]->{$_} = \$_[1]) }";
 295   die if $@;
 296  }
 297 }
 298
 299 =head2 C<do_suppressions>
 300
 301 Forwards to C<< ->action->do_suppressions >>.
 302
 303 =cut
 304
 305 sub do_suppressions { $_[0]->action->do_suppressions }
 306
 307 =head2 C<report_class>
 308
 309 Calls C<< ->action->report_class >> with the current session object as the unique argument.
 310
 311 =cut
 312
 313 sub report_class { $_[0]->tool->report_class($_[0]) }
 314
 315 =head2 C<def_supp_file>
 316
 317 Returns an absolute path to the default suppression file associated to the current session.
 318
 319 C<undef> will be returned as soon as any of C<< ->command->suppressions_tag >> or C<< ->tool->suppressions_tag >> are also C<undef>.
 320 Otherwise, the file part of the name is builded by joining those two together, and the directory part is roughly F<< File::HomeDir->my_home / .perl / Test-Valgrind / suppressions / $VERSION >>.
 321
 322 =cut
 323
 324 sub def_supp_file {
 325  my ($self) = @_;
 326
 327  my $tool_tag = $self->tool->suppressions_tag($self);
 328  return unless defined $tool_tag;
 329
 330  my $cmd_tag = $self->command->suppressions_tag($self);
 331  return unless defined $cmd_tag;
 332
 333  require File::HomeDir; # So that it's not needed at configure time.
 334
 335  return File::Spec->catfile(
 336   File::HomeDir->my_home,
 337   '.perl',
 338   'Test-Valgrind',
 339   'suppressions',
 340   $VERSION,
 341   "$tool_tag-$cmd_tag.supp",
 342  );
 343 }
 344
 345 =head2 C<suppressions>
 346
 347 Returns the list of all the suppressions that will be passed to C<valgrind>.
 348 Honors L</no_def_supp> and L</extra_supps>.
 349
 350 =cut
 351
 352 sub suppressions {
 353  my ($self) = @_;
 354
 355  my @supps;
 356  unless ($self->no_def_supp) {
 357   my $def_supp = $self->def_supp_file;
 358   push @supps, $def_supp if defined $def_supp;
 359  }
 360  push @supps, $self->extra_supps;
 361
 362  return @supps;
 363 }
 364
 365 =head2 C<start>
 366
 367 Starts the action and tool associated to the current run.
 368 It's automatically called at the beginning of L</run>.
 369
 370 =cut
 371
 372 sub start {
 373  my $self = shift;
 374
 375  my %args = @_;
 376
 377  for (qw/action tool command/) {
 378   my $base = 'Test::Valgrind::' . ucfirst;
 379   my $value = $args{$_};
 380   $self->_croak("Invalid $_") unless Scalar::Util::blessed($value)
 381                                                          and $value->isa($base);
 382   $self->$_($args{$_})
 383  }
 384
 385  delete @{$self}{qw/last_status exit_code/};
 386
 387  $self->tool->start($self);
 388  $self->parser($self->tool->parser_class($self)->new)->start($self);
 389  $self->action->start($self);
 390
 391  return;
 392 }
 393
 394 =head2 C<abort $msg>
 395
 396 Forwards to C<< ->action->abort >> after unshifting the session object to the argument list.
 397
 398 =cut
 399
 400 sub abort {
 401  my $self = shift;
 402
 403  $self->action->abort($self, @_);
 404 }
 405
 406 =head2 C<report $report>
 407
 408 Forwards to C<< ->action->report >> after unshifting the session object to the argument list.
 409
 410 =cut
 411
 412 sub report {
 413  my ($self, $report) = @_;
 414
 415  return unless defined $report;
 416
 417  for my $handler (qw/tool command/) {
 418   $report = $self->$handler->filter($self, $report);
 419   return unless defined $report;
 420  }
 421
 422  $self->action->report($self, $report);
 423 }
 424
 425 =head2 C<finish>
 426
 427 Finishes the action and tool associated to the current run.
 428 It's automatically called at the end of L</run>.
 429
 430 =cut
 431
 432 sub finish {
 433  my ($self) = @_;
 434
 435  my $action = $self->action;
 436
 437  $action->finish($self);
 438  $self->parser->finish($self);
 439  $self->tool->finish($self);
 440
 441  my $status = $action->status($self);
 442  $self->{last_status} = defined $status ? $status : $self->{exit_code};
 443
 444  $self->$_(undef) for @members;
 445
 446  return;
 447 }
 448
 449 =head2 C<status>
 450
 451 Returns the status code of the last run of the session.
 452
 453 =cut
 454
 455 sub status { $_[0]->{last_status} }
 456
 457 =head1 SEE ALSO
 458
 459 L<Test::Valgrind>, L<Test::Valgrind::Action>, L<Test::Valgrind::Command>, L<Test::Valgrind::Tool>, L<Test::Valgrind::Parser>.
 460
 461 L<version>, L<File::HomeDir>.
 462
 463 =head1 AUTHOR
 464
 465 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 466
 467 You can contact me by mail or on C<irc.perl.org> (vincent).
 468
 469 =head1 BUGS
 470
 471 Please report any bugs or feature requests to C<bug-test-valgrind at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Test-Valgrind>.
 472 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 473
 474 =head1 SUPPORT
 475
 476 You can find documentation for this module with the perldoc command.
 477
 478     perldoc Test::Valgrind::Session
 479
 480 =head1 COPYRIGHT & LICENSE
 481
 482 Copyright 2009 Vincent Pit, all rights reserved.
 483
 484 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 485
 486 =cut
 487
 488 1; # End of Test::Valgrind::Session