lib/Test/Valgrind/Parser/Suppressions/Text.pm

   1 package Test::Valgrind::Parser::Suppressions::Text;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 Test::Valgrind::Parser::Suppressions::Text - Parse valgrind suppressions output as text blocks.
   9
  10 =head1 VERSION
  11
  12 Version 1.11
  13
  14 =cut
  15
  16 our $VERSION = '1.11';
  17
  18 =head1 DESCRIPTION
  19
  20 This is a L<Test::Valgrind::Parser::Text> object that can extract suppressions from C<valgrind>'s text output.
  21
  22 =cut
  23
  24 use Test::Valgrind::Suppressions;
  25
  26 use base qw/Test::Valgrind::Parser::Text Test::Valgrind::Carp/;
  27
  28 =head1 METHODS
  29
  30 =head2 C<report_class>
  31
  32 Generated reports are C<Test::Valgrind::Report::Suppressions> objects.
  33 Their C<data> member contains the raw text of the suppression.
  34
  35 =cut
  36
  37 sub report_class { 'Test::Valgrind::Report::Suppressions' }
  38
  39 sub parse {
  40  my ($self, $sess, $fh) = @_;
  41
  42  my ($s, $in) = ('', 0);
  43  my @supps;
  44
  45  while (<$fh>) {
  46   s/^\s*#\s//;        # Strip comments
  47
  48   next if /^==/;      # Valgrind info line
  49   next if /valgrind/; # and /\Q$file\E/;
  50
  51   s/^\s*//;           # Strip leading spaces
  52   s/<[^>]+>//;        # Strip tags
  53   s/\s*$//;           # Strip trailing spaces
  54   next unless length;
  55
  56   if ($_ eq '{') {      # A suppression block begins
  57    $in = 1;
  58   } elsif ($_ eq '}') { # A suppression block ends
  59    $s = Test::Valgrind::Suppressions->strip_tail($sess, $s); # Strip the tail
  60    push @supps, $s;     # Add the suppression that just ended to the list
  61    $s  = '';            # Reset the state
  62    $in = 0;
  63   } elsif ($in) {       # We're inside a suppresion block
  64    $s .= "$_\n";        # Append the current line to the state
  65   }
  66  }
  67
  68  my @extra;
  69
  70  for (@supps) {
  71   if (/\bfun:(m|c|re)alloc\b/) {
  72    my $t = $1;
  73
  74    my %call; # Frames to append (if the value is 1) or to prepend (if it's 0)
  75    if ($t eq 'm') {       # malloc can also be called by calloc or realloc
  76     $call{$_} = 1 for qw/calloc realloc/;
  77    } elsif ($t eq 're') { # realloc can also call malloc or free
  78     $call{$_} = 0 for qw/malloc free/;
  79    } elsif ($t eq 'c') {  # calloc can also call malloc
  80     $call{$_} = 0 for qw/malloc/;
  81    }
  82
  83    my $c = $_;
  84    for (keys %call) {
  85     my $d = $c;
  86     $d =~ s/\b(fun:${t}alloc)\b/$call{$_} ? "$1\nfun:$_" : "fun:$_\n$1"/e;
  87     # Remove one line for each line added or valgrind will hate us
  88     $d =~ s/\n(.+?)\s*$/\n/;
  89     push @extra, $d;
  90    }
  91   }
  92  }
  93
  94  my $num;
  95  $sess->report($self->report_class($sess)->new(
  96   id   => ++$num,
  97   kind => 'Suppression',
  98   data => $_,
  99  )) for @supps, @extra;
 100 }
 101
 102 =head1 SEE ALSO
 103
 104 L<Test::Valgrind>, L<Test::Valgrind::Parser::Text>.
 105
 106 =head1 AUTHOR
 107
 108 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 109
 110 You can contact me by mail or on C<irc.perl.org> (vincent).
 111
 112 =head1 BUGS
 113
 114 Please report any bugs or feature requests to C<bug-test-valgrind at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Test-Valgrind>.
 115 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 116
 117 =head1 SUPPORT
 118
 119 You can find documentation for this module with the perldoc command.
 120
 121     perldoc Test::Valgrind::Parser::Suppressions::Text
 122
 123 =head1 COPYRIGHT & LICENSE
 124
 125 Copyright 2009 Vincent Pit, all rights reserved.
 126
 127 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 128
 129 =cut
 130
 131 # End of Test::Valgrind::Parser::Suppressions::Text
 132
 133 package Test::Valgrind::Report::Suppressions;
 134
 135 use base qw/Test::Valgrind::Report/;
 136
 137 sub kinds { shift->SUPER::kinds(), 'Suppression' }
 138
 139 sub valid_kind {
 140  my ($self, $kind) = @_;
 141
 142  $self->SUPER::valid_kind($kind) or $kind eq 'Suppression'
 143 }
 144
 145 1; # End of Test::Valgrind::Report::Suppressions