lib/Sub/Prototype/Util.pm

   1 package Sub::Prototype::Util;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Carp qw/croak/;
   7 use Scalar::Util qw/reftype/;
   8
   9 =head1 NAME
  10
  11 Sub::Prototype::Util - Prototype-related utility routines.
  12
  13 =head1 VERSION
  14
  15 Version 0.08
  16
  17 =cut
  18
  19 use vars qw/$VERSION/;
  20
  21 $VERSION = '0.08';
  22
  23 =head1 SYNOPSIS
  24
  25     use Sub::Prototype::Util qw/flatten wrap recall/;
  26
  27     my @a = qw/a b c/;
  28     my @args = ( \@a, 1, { d => 2 }, undef, 3 );
  29
  30     my @flat = flatten '\@$;$', @args; # ('a', 'b', 'c', 1, { d => 2 })
  31     recall 'CORE::push', @args; # @a contains 'a', 'b', 'c', 1, { d => 2 }, undef, 3
  32     my $splice = wrap 'CORE::splice';
  33     my @b = $splice->(\@a, 4, 2); # @a is now ('a', 'b', 'c', 1, 3) and @b is ({ d => 2 }, undef)
  34
  35 =head1 DESCRIPTION
  36
  37 Prototypes are evil, but sometimes you just have to bear with them, especially when messing with core functions. This module provides several utilities aimed at facilitating "overloading" of prototyped functions.
  38
  39 They all handle C<5.10>'s C<_> prototype.
  40
  41 =head1 FUNCTIONS
  42
  43 =cut
  44
  45 my %sigils = qw/SCALAR $ ARRAY @ HASH % GLOB * CODE &/;
  46 my %reftypes = reverse %sigils;
  47
  48 sub _check_ref {
  49  my ($a, $p) = @_;
  50  my $r;
  51  if (!defined $a || !defined($r = reftype $a)) { # not defined or plain scalar
  52   croak 'Got ' . ((defined $a) ? 'a plain scalar' : 'undef')
  53                . ' where a reference was expected';
  54  }
  55  croak 'Unexpected ' . $r . ' reference' unless exists $sigils{$r}
  56                                             and $p =~ /\Q$sigils{$r}\E/;
  57  return $r;
  58 }
  59
  60 =head2 C<flatten $proto, @args>
  61
  62 Flattens the array C<@args> according to the prototype C<$proto>. When C<@args> is what C<@_> is after calling a subroutine with prototype C<$proto>, C<flatten> returns the list of what C<@_> would have been if there were no prototype.
  63
  64 =cut
  65
  66 sub flatten {
  67  my $proto = shift;
  68  return @_ unless defined $proto;
  69  my @args;
  70  while ($proto =~ /(\\?)(\[[^\]]+\]|[^\];])/g) {
  71   my $p = $2;
  72   if ($1) {
  73    my $a = shift;
  74    my $r = _check_ref $a, $p;
  75    push @args, $r eq 'SCALAR'
  76                ? $$a
  77                : ($r eq 'ARRAY'
  78                   ? @$a
  79                   : ($r eq 'HASH'
  80                      ? %$a
  81                      : ($r eq 'GLOB'
  82                         ? *$a
  83                         : &$a # _check_ref ensures this must be a code ref
  84                        )
  85                     )
  86                  );
  87   } elsif ($p =~ /[\@\%]/) {
  88    push @args, @_;
  89    last;
  90   } elsif ($p eq '_') {
  91    shift; # without prototype, this argument wouldn't have been passed
  92   } else {
  93    push @args, shift;
  94   }
  95  }
  96  return @args;
  97 }
  98
  99 =head2 C<wrap $name, %opts>
 100
 101 Generates a wrapper that calls the function C<$name> with a prototyped argument list. That is, the wrapper's arguments should be what C<@_> is when you define a subroutine with the same prototype as C<$name>.
 102
 103     my $a = [ 0 .. 2 ];
 104     my $push = wrap 'CORE::push';
 105     $push->($a, 3, 4); # returns 3 + 2 = 5 and $a now contains 0 .. 4
 106
 107 You can force the use of a specific prototype. In this case, C<$name> must be a hash reference that holds exactly one key / value pair, the key being the function name and the value the prototpye that should be used to call it.
 108
 109     my $push = wrap { 'CORE::push' => '\@$' }; # only pushes 1 arg
 110
 111 Others arguments are seen as key / value pairs that are meant to tune the code generated by L</wrap>. Valid keys are :
 112
 113 =over 4
 114
 115 =item C<< ref => $func >>
 116
 117 Specifies the function used in the generated code to test the reference type of scalars. Defaults to C<'ref'>. You may also want to use C<Scalar::Util::reftype>.
 118
 119 =item C<< wrong_ref => $code >>
 120
 121 The code executed when a reference of incorrect type is encountered. The result of this snippet is also the result of the generated code, hence it defaults to C<'undef'>. It's a good place to C<croak> or C<die> too.
 122
 123 =item C<< sub => $bool >>
 124
 125 Encloses the code into a C<sub { }> block. Default is true.
 126
 127 =item C<< compile => $bool >>
 128
 129 Makes L</wrap> compile the code generated and return the resulting code reference. Be careful that in this case C<ref> must be a fully qualified function name. Defaults to true, but turned off when C<sub> is false.
 130
 131 =back
 132
 133 For example, this allows you to recall into C<CORE::grep> and C<CORE::map> by using the C<\&@> prototype :
 134
 135     my $grep = wrap { 'CORE::grep' => '\&@' };
 136     sub mygrep (&@) { $grep->(@_) } # the prototypes are intentionally different
 137
 138 =cut
 139
 140 sub _wrap {
 141  my ($name, $proto, $i, $args, $cr, $opts) = @_;
 142  while ($proto =~ s/(\\?)(\[[^\]]+\]|[^\];])//) {
 143   my ($ref, $p) = ($1, $2);
 144   $p = $1 if $p =~ /^\[([^\]]+)\]/;
 145   my $cur = '$_[' . $i . ']';
 146   if ($ref) {
 147    if (length $p > 1) {
 148     return 'my $r = ' . $opts->{ref} . '(' . $cur . '); '
 149            . join ' els',
 150               map( {
 151                "if (\$r eq '" . $reftypes{$_} ."') { "
 152                . _wrap($name, $proto, ($i + 1),
 153                               $args . $_ . '{' . $cur . '}, ',
 154                               $cr, $opts)
 155                . ' }'
 156               } split //, $p),
 157               'e { ' . $opts->{wrong_ref} . ' }'
 158    } else {
 159     $args .= $p . '{' . $cur . '}, ';
 160    }
 161   } elsif ($p =~ /[\@\%]/) {
 162    $args .= '@_[' . $i . '..$#_]';
 163   } elsif ($p =~ /\&/) {
 164    my %h = do { my $c; map { $_ => $c++ } @$cr };
 165    my $j;
 166    if (not exists $h{$i}) {
 167     push @$cr, $i;
 168     $j = $#{$cr};
 169    } else {
 170     $j = int $h{$i};
 171    }
 172    $args .= 'sub{&{$c[' . $j . ']}}, ';
 173   } elsif ($p eq '_') {
 174    $args .= '((@_ > ' . $i . ') ? ' . $cur . ' : $_), ';
 175   } else {
 176    $args .= $cur . ', ';
 177   }
 178   ++$i;
 179  }
 180  $args =~ s/,\s*$//;
 181  return $name . '(' . $args . ')';
 182 }
 183
 184 sub _check_name {
 185  my $name = $_[0];
 186  croak 'No subroutine specified' unless $name;
 187  my $proto;
 188  my $r = ref $name;
 189  if (!$r) {
 190   $proto = prototype $name;
 191  } elsif ($r eq 'HASH') {
 192   croak 'Forced prototype hash reference must contain exactly one key/value pair' unless keys %$name == 1;
 193   ($name, $proto) = %$name;
 194  } else {
 195   croak 'Unhandled ' . $r . ' reference as first argument';
 196  }
 197  $name =~ s/^\s+//;
 198  $name =~ s/[\s\$\@\%\*\&;].*//;
 199  return $name, $proto;
 200 }
 201
 202 sub wrap {
 203  my ($name, $proto) = _check_name shift;
 204  croak 'Optional arguments must be passed as key => value pairs' if @_ % 2;
 205  my %opts = @_;
 206  $opts{ref}     ||= 'ref';
 207  $opts{sub}       = 1       if not defined $opts{sub};
 208  $opts{compile}   = 1       if not defined $opts{compile} and $opts{sub};
 209  $opts{wrong_ref} = 'undef' if not defined $opts{wrong_ref};
 210  my @cr;
 211  my $call;
 212  if (defined $proto) {
 213   $call = _wrap $name, $proto, 0, '', \@cr, \%opts;
 214  } else {
 215   $call = _wrap $name, '', 0, '@_';
 216  }
 217  if (@cr) {
 218   $call = 'my @c; '
 219         . join('', map { 'push @c, $_[' . $_ . ']; ' } @cr)
 220         . $call
 221  }
 222  $call = '{ ' . $call . ' }';
 223  $call = 'sub ' . $call if $opts{sub};
 224  if ($opts{compile}) {
 225   $call = eval $call;
 226   croak $@ if $@;
 227  }
 228  return $call;
 229 }
 230
 231 =head2 C<recall $name, @args>
 232
 233 Calls the function C<$name> with the prototyped argument list C<@args>. That is, C<@args> should be what C<@_> is when you define a subroutine with the same prototype as C<$name>. You can still force the prototype by passing C<< { $name => $proto } >> as the first argument.
 234
 235     my $a = [ ];
 236     recall { 'CORE::push' => '\@$' }, $a, 1, 2, 3; # $a just contains 1
 237
 238 It's implemented in terms of L</wrap>, and hence calls C<eval> at each run.
 239 If you plan to recall several times, consider using L</wrap> instead.
 240
 241 =cut
 242
 243 sub recall {
 244  my $wrap = eval { wrap shift };
 245  croak $@ if $@;
 246  return $wrap->(@_);
 247 }
 248
 249 =head1 EXPORT
 250
 251 The functions L</flatten>, L</wrap> and L</recall> are only exported on request, either by providing their name or by the C<':funcs'> and C<':all'> tags.
 252
 253 =cut
 254
 255 use base qw/Exporter/;
 256
 257 use vars qw/@EXPORT @EXPORT_OK %EXPORT_TAGS/;
 258
 259 @EXPORT             = ();
 260 %EXPORT_TAGS        = (
 261  'funcs' =>  [ qw/flatten wrap recall/ ]
 262 );
 263 @EXPORT_OK          = map { @$_ } values %EXPORT_TAGS;
 264 $EXPORT_TAGS{'all'} = [ @EXPORT_OK ];
 265
 266 =head1 DEPENDENCIES
 267
 268 L<Carp>, L<Exporter> (core modules since perl 5), L<Scalar::Util> (since 5.7.3).
 269
 270 =head1 AUTHOR
 271
 272 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 273
 274 You can contact me by mail or on C<irc.perl.org> (vincent).
 275
 276 =head1 BUGS
 277
 278 Please report any bugs or feature requests to C<bug-sub-prototype-util at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Sub-Prototype-Util>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 279
 280 =head1 SUPPORT
 281
 282 You can find documentation for this module with the perldoc command.
 283
 284     perldoc Sub::Prototype::Util
 285
 286 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Sub-Prototype-Util>.
 287
 288 =head1 COPYRIGHT & LICENSE
 289
 290 Copyright 2008 Vincent Pit, all rights reserved.
 291
 292 This program is free software; you can redistribute it and/or modify it
 293 under the same terms as Perl itself.
 294
 295 =cut
 296
 297 1; # End of Sub::Prototype::Util