lib/Sub/Prototype/Util.pm

   1 package Sub::Prototype::Util;
   2
   3 use 5.006;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp qw/croak/;
   9 use Scalar::Util qw/reftype/;
  10
  11 =head1 NAME
  12
  13 Sub::Prototype::Util - Prototype-related utility routines.
  14
  15 =head1 VERSION
  16
  17 Version 0.09
  18
  19 =cut
  20
  21 use vars qw/$VERSION/;
  22
  23 $VERSION = '0.09';
  24
  25 =head1 SYNOPSIS
  26
  27     use Sub::Prototype::Util qw/flatten wrap recall/;
  28
  29     my @a = qw/a b c/;
  30     my @args = ( \@a, 1, { d => 2 }, undef, 3 );
  31
  32     my @flat = flatten '\@$;$', @args; # ('a', 'b', 'c', 1, { d => 2 })
  33     recall 'CORE::push', @args; # @a contains 'a', 'b', 'c', 1, { d => 2 }, undef, 3
  34     my $splice = wrap 'CORE::splice';
  35     my @b = $splice->(\@a, 4, 2); # @a is now ('a', 'b', 'c', 1, 3) and @b is ({ d => 2 }, undef)
  36
  37 =head1 DESCRIPTION
  38
  39 Prototypes are evil, but sometimes you just have to bear with them, especially when messing with core functions.
  40 This module provides several utilities aimed at facilitating "overloading" of prototyped functions.
  41
  42 They all handle C<5.10>'s C<_> prototype.
  43
  44 =head1 FUNCTIONS
  45
  46 =cut
  47
  48 my %sigils = qw/SCALAR $ ARRAY @ HASH % GLOB * CODE &/;
  49 my %reftypes = reverse %sigils;
  50
  51 sub _check_ref {
  52  my ($a, $p) = @_;
  53  my $r;
  54  if (!defined $a || !defined($r = reftype $a)) { # not defined or plain scalar
  55   croak 'Got ' . ((defined $a) ? 'a plain scalar' : 'undef')
  56                . ' where a reference was expected';
  57  }
  58  croak 'Unexpected ' . $r . ' reference' unless exists $sigils{$r}
  59                                             and $p =~ /\Q$sigils{$r}\E/;
  60  return $r;
  61 }
  62
  63 sub _clean_msg {
  64  my ($msg) = @_;
  65  $msg =~ s/(?:\s+called)?\s+at\s+.*$//s;
  66  return $msg;
  67 }
  68
  69 =head2 C<flatten $proto, @args>
  70
  71 Flattens the array C<@args> according to the prototype C<$proto>.
  72 When C<@args> is what C<@_> is after calling a subroutine with prototype C<$proto>, C<flatten> returns the list of what C<@_> would have been if there were no prototype.
  73 It croaks if the arguments can't possibly match the required prototype, e.g. when a reference type is wrong or when not enough elements were provided.
  74
  75 =cut
  76
  77 sub flatten {
  78  my $proto = shift;
  79  return @_ unless defined $proto;
  80  my @args;
  81  while ($proto =~ /(\\?)(\[[^\]]+\]|[^\];])/g) {
  82   my $p = $2;
  83   if ($1) {
  84    my $a = shift;
  85    my $r = _check_ref $a, $p;
  86    push @args, $r eq 'SCALAR'
  87                ? $$a
  88                : ($r eq 'ARRAY'
  89                   ? @$a
  90                   : ($r eq 'HASH'
  91                      ? %$a
  92                      : ($r eq 'GLOB'
  93                         ? *$a
  94                         : &$a # _check_ref ensures this must be a code ref
  95                        )
  96                     )
  97                  );
  98   } elsif ($p =~ /[\@\%]/) {
  99    push @args, @_;
 100    last;
 101   } else {
 102    croak 'Not enough arguments to match this prototype' unless @_;
 103    push @args, shift;
 104   }
 105  }
 106  return @args;
 107 }
 108
 109 =head2 C<wrap $name, %opts>
 110
 111 Generates a wrapper that calls the function C<$name> with a prototyped argument list.
 112 That is, the wrapper's arguments should be what C<@_> is when you define a subroutine with the same prototype as C<$name>.
 113
 114     my $a = [ 0 .. 2 ];
 115     my $push = wrap 'CORE::push';
 116     $push->($a, 3, 4); # returns 3 + 2 = 5 and $a now contains 0 .. 4
 117
 118 You can force the use of a specific prototype.
 119 In this case, C<$name> must be a hash reference that holds exactly one key / value pair, the key being the function name and the value the prototpye that should be used to call it.
 120
 121     my $push = wrap { 'CORE::push' => '\@$' }; # only pushes 1 arg
 122
 123 Others arguments are seen as key / value pairs that are meant to tune the code generated by L</wrap>.
 124 Valid keys are :
 125
 126 =over 4
 127
 128 =item C<< ref => $func >>
 129
 130 Specifies the function used in the generated code to test the reference type of scalars.
 131 Defaults to C<'ref'>.
 132 You may also want to use L<Scalar::Util/reftype>.
 133
 134 =item C<< wrong_ref => $code >>
 135
 136 The code executed when a reference of incorrect type is encountered.
 137 The result of this snippet is also the result of the generated code, hence it defaults to C<'undef'>.
 138 It's a good place to C<croak> or C<die> too.
 139
 140 =item C<< sub => $bool >>
 141
 142 Encloses the code into a C<sub { }> block.
 143 Default is true.
 144
 145 =item C<< compile => $bool >>
 146
 147 Makes L</wrap> compile the code generated and return the resulting code reference.
 148 Be careful that in this case C<ref> must be a fully qualified function name.
 149 Defaults to true, but turned off when C<sub> is false.
 150
 151 =back
 152
 153 For example, this allows you to recall into C<CORE::grep> and C<CORE::map> by using the C<\&@> prototype :
 154
 155     my $grep = wrap { 'CORE::grep' => '\&@' };
 156     sub mygrep (&@) { $grep->(@_) } # the prototypes are intentionally different
 157
 158 =cut
 159
 160 sub _wrap {
 161  my ($name, $proto, $i, $args, $cr, $opts) = @_;
 162  while ($proto =~ s/(\\?)(\[[^\]]+\]|[^\];])//) {
 163   my ($ref, $p) = ($1, $2);
 164   $p = $1 if $p =~ /^\[([^\]]+)\]/;
 165   my $cur = '$_[' . $i . ']';
 166   if ($ref) {
 167    if (length $p > 1) {
 168     return 'my $r = ' . $opts->{ref} . '(' . $cur . '); '
 169            . join ' els',
 170               map( {
 171                "if (\$r eq '" . $reftypes{$_} ."') { "
 172                . _wrap($name, $proto, ($i + 1),
 173                               $args . $_ . '{' . $cur . '}, ',
 174                               $cr, $opts)
 175                . ' }'
 176               } split //, $p),
 177               'e { ' . $opts->{wrong_ref} . ' }'
 178    } else {
 179     $args .= $p . '{' . $cur . '}, ';
 180    }
 181   } elsif ($p =~ /[\@\%]/) {
 182    $args .= '@_[' . $i . '..$#_]';
 183   } elsif ($p =~ /\&/) {
 184    my %h = do { my $c; map { $_ => $c++ } @$cr };
 185    my $j;
 186    if (not exists $h{$i}) {
 187     push @$cr, $i;
 188     $j = $#{$cr};
 189    } else {
 190     $j = int $h{$i};
 191    }
 192    $args .= 'sub{&{$c[' . $j . ']}}, ';
 193   } elsif ($p eq '_') {
 194    $args .= '((@_ > ' . $i . ') ? ' . $cur . ' : $_), ';
 195   } else {
 196    $args .= $cur . ', ';
 197   }
 198   ++$i;
 199  }
 200  $args =~ s/,\s*$//;
 201  return $name . '(' . $args . ')';
 202 }
 203
 204 sub _check_name {
 205  my $name = $_[0];
 206  croak 'No subroutine specified' unless $name;
 207  my $proto;
 208  my $r = ref $name;
 209  if (!$r) {
 210   $proto = prototype $name;
 211  } elsif ($r eq 'HASH') {
 212   croak 'Forced prototype hash reference must contain exactly one key/value pair' unless keys %$name == 1;
 213   ($name, $proto) = %$name;
 214  } else {
 215   croak 'Unhandled ' . $r . ' reference as first argument';
 216  }
 217  $name =~ s/^\s+//;
 218  $name =~ s/[\s\$\@\%\*\&;].*//;
 219  return $name, $proto;
 220 }
 221
 222 sub wrap {
 223  my ($name, $proto) = _check_name shift;
 224  croak 'Optional arguments must be passed as key => value pairs' if @_ % 2;
 225  my %opts = @_;
 226  $opts{ref}     ||= 'ref';
 227  $opts{sub}       = 1       if not defined $opts{sub};
 228  $opts{compile}   = 1       if not defined $opts{compile} and $opts{sub};
 229  $opts{wrong_ref} = 'undef' if not defined $opts{wrong_ref};
 230  my @cr;
 231  my $call;
 232  if (defined $proto) {
 233   $call = _wrap $name, $proto, 0, '', \@cr, \%opts;
 234  } else {
 235   $call = _wrap $name, '', 0, '@_';
 236  }
 237  if (@cr) {
 238   $call = 'my @c; '
 239         . join('', map { 'push @c, $_[' . $_ . ']; ' } @cr)
 240         . $call
 241  }
 242  $call = '{ ' . $call . ' }';
 243  $call = 'sub ' . $call if $opts{sub};
 244  if ($opts{compile}) {
 245   $call = eval $call;
 246   croak _clean_msg $@ if $@;
 247  }
 248  return $call;
 249 }
 250
 251 =head2 C<recall $name, @args>
 252
 253 Calls the function C<$name> with the prototyped argument list C<@args>.
 254 That is, C<@args> should be what C<@_> is when you call a subroutine with C<$name> as prototype.
 255 You can still force the prototype by passing C<< { $name => $proto } >> as the first argument.
 256
 257     my $a = [ ];
 258     recall { 'CORE::push' => '\@$' }, $a, 1, 2, 3; # $a just contains 1
 259
 260 It's implemented in terms of L</wrap>, and hence calls C<eval> at each run.
 261 If you plan to recall several times, consider using L</wrap> instead.
 262
 263 =cut
 264
 265 sub recall {
 266  my $wrap = eval { wrap shift };
 267  croak _clean_msg $@ if $@;
 268  return $wrap->(@_);
 269 }
 270
 271 =head1 EXPORT
 272
 273 The functions L</flatten>, L</wrap> and L</recall> are only exported on request, either by providing their name or by the C<':funcs'> and C<':all'> tags.
 274
 275 =cut
 276
 277 use base qw/Exporter/;
 278
 279 use vars qw/@EXPORT @EXPORT_OK %EXPORT_TAGS/;
 280
 281 @EXPORT             = ();
 282 %EXPORT_TAGS        = (
 283  'funcs' =>  [ qw/flatten wrap recall/ ]
 284 );
 285 @EXPORT_OK          = map { @$_ } values %EXPORT_TAGS;
 286 $EXPORT_TAGS{'all'} = [ @EXPORT_OK ];
 287
 288 =head1 DEPENDENCIES
 289
 290 L<Carp>, L<Exporter> (core modules since perl 5), L<Scalar::Util> (since 5.7.3).
 291
 292 =head1 AUTHOR
 293
 294 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 295
 296 You can contact me by mail or on C<irc.perl.org> (vincent).
 297
 298 =head1 BUGS
 299
 300 Please report any bugs or feature requests to C<bug-sub-prototype-util at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Sub-Prototype-Util>.
 301 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 302
 303 =head1 SUPPORT
 304
 305 You can find documentation for this module with the perldoc command.
 306
 307     perldoc Sub::Prototype::Util
 308
 309 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Sub-Prototype-Util>.
 310
 311 =head1 COPYRIGHT & LICENSE
 312
 313 Copyright 2008,2009,2010,2011 Vincent Pit, all rights reserved.
 314
 315 This program is free software; you can redistribute it and/or modify it
 316 under the same terms as Perl itself.
 317
 318 =cut
 319
 320 1; # End of Sub::Prototype::Util