lib/Sub/Prototype/Util.pm

   1 package Sub::Prototype::Util;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Carp qw/croak/;
   7 use Scalar::Util qw/reftype/;
   8
   9 =head1 NAME
  10
  11 Sub::Prototype::Util - Prototype-related utility routines.
  12
  13 =head1 VERSION
  14
  15 Version 0.06
  16
  17 =cut
  18
  19 use vars qw/$VERSION/;
  20
  21 $VERSION = '0.06';
  22
  23 =head1 SYNOPSIS
  24
  25     use Sub::Prototype::Util qw/flatten recall/;
  26
  27     my @a = qw/a b c/;
  28     my @args = ( \@a, 1, { d => 2 }, undef, 3 );
  29
  30     my @flat = flatten '\@$;$', @args; # ('a', 'b', 'c', 1, { d => 2 })
  31     recall 'CORE::push', @args; # @a contains 'a', 'b', 'c', 1, { d => 2 }, undef, 3
  32
  33 =head1 DESCRIPTION
  34
  35 Prototypes are evil, but sometimes you just have to bear with them, especially when messing with core functions. This module provides several utilities aimed at facilitating "overloading" of prototyped functions.
  36
  37 They all handle C<5.10>'s C<_> prototype.
  38
  39 =head1 FUNCTIONS
  40
  41 =cut
  42
  43 my %sigils = qw/SCALAR $ ARRAY @ HASH % GLOB * CODE &/;
  44 my %reftypes = reverse %sigils;
  45
  46 sub _check_ref {
  47  my ($a, $p) = @_;
  48  my $r;
  49  if (!defined $a || !defined($r = reftype $a)) { # not defined or plain scalar
  50   croak 'Got ' . ((defined $a) ? 'a plain scalar' : 'undef')
  51                . ' where a reference was expected';
  52  }
  53  croak 'Unexpected ' . $r . ' reference' unless exists $sigils{$r}
  54                                             and $p =~ /\Q$sigils{$r}\E/;
  55  return $r;
  56 }
  57
  58 =head2 C<flatten $proto, @args>
  59
  60 Flattens the array C<@args> according to the prototype C<$proto>. When C<@args> is what C<@_> is after calling a subroutine with prototype C<$proto>, C<flatten> returns the list of what C<@_> would have been if there were no prototype.
  61
  62 =cut
  63
  64 sub flatten {
  65  my $proto = shift;
  66  return @_ unless defined $proto;
  67  my @args;
  68  while ($proto =~ /(\\?)(\[[^\]]+\]|[^\];])/g) {
  69   my $p = $2;
  70   if ($1) {
  71    my $a = shift;
  72    my $r = _check_ref $a, $p;
  73    my %deref = (
  74     SCALAR => sub { push @args, $$a },
  75     ARRAY  => sub { push @args, @$a },
  76     HASH   => sub { push @args, %$a },
  77     GLOB   => sub { push @args, *$a },
  78     CODE   => sub { push @args, &$a }
  79    );
  80    $deref{$r}->();
  81   } elsif ($p =~ /[\@\%]/) {
  82    push @args, @_;
  83    last;
  84   } elsif ($p eq '_' && @_ == 0) {
  85    push @args, $_;
  86   } else {
  87    push @args, shift;
  88   }
  89  }
  90  return @args;
  91 }
  92
  93 =head2 C<recall $name, @args>
  94
  95 Calls the function C<$name> with the prototyped argument list C<@args>. That is, C<@args> should be what C<@_> is when you define a subroutine with the same prototype as C<$name>. For example,
  96
  97     my $a = [ ];
  98     recall 'CORE::push', $a, 1, 2, 3;
  99
 100 will call C<push @$a, 1, 2, 3> and so fill the arrayref C<$a> with C<1, 2, 3>. This is especially needed for core functions because you can't C<goto> into them.
 101
 102 You can also force the use of a specific prototype. In this case, C<$name> must be a hash reference that holds exactly one key/value pair, the key being the function name and the value the prototpye that should be used to call it.
 103
 104     recall { 'CORE::push' => '\@$' }, $a, 1, 2, 3; # will only push 1
 105
 106 This allows you to recall into C<CORE::grep> and C<CORE::map> by using the C<\&@> prototype :
 107
 108     sub mygrep (&@) { recall { 'CORE::grep' => '\&@' }, @_ } # the prototypes are intentionally different
 109
 110 =cut
 111
 112 sub _check_name {
 113  my $name = $_[0];
 114  croak 'No subroutine specified' unless $name;
 115  my $proto;
 116  my $r = ref $name;
 117  if ($r eq 'HASH') {
 118   croak 'Forced prototype hash reference must contain exactly one key/value pair' unless keys %$name == 1;
 119   ($name, $proto) = %$name;
 120  } elsif (length $r) {
 121   croak 'Unhandled ' . $r . ' reference as first argument';
 122  }
 123  $name =~ s/^\s+//;
 124  $name =~ s/[\s\$\@\%\*\&;].*//;
 125  $proto = prototype $name unless $proto;
 126  return $name, $proto;
 127 }
 128
 129 sub recall {
 130  my ($name, $proto) = _check_name shift;
 131  my $call = $name . '(';
 132  my @cr;
 133  if (defined $proto) {
 134   my $i = 0;
 135   while ($proto =~ /(\\?)(\[[^\]]+\]|[^\];])/g) {
 136    my $p = $2;
 137    if ($1) {
 138     my $r = _check_ref $_[$i], $p;
 139     $call .= $sigils{$r} . '{$_[' . $i . ']},';
 140    } elsif ($p =~ /[\@\%]/) {
 141     $call .= '@_[' . $i . '..' . (@_ - 1) . ']';
 142     last;
 143    } elsif ($p =~ /\&/) {
 144     push @cr, $_[$i];
 145     $call .= 'sub{&{$cr[' . $#cr . ']}},';
 146    } elsif ($p eq '_' && $i >= @_) {
 147     $call .= '$_,';
 148    } else {
 149     $call .= '$_[' . $i . '],';
 150    }
 151    ++$i;
 152   }
 153   $call =~ s/,$//;
 154  } else {
 155   $call .= join ',', map '$_[' . $_ . ']', 0 .. @_ - 1;
 156  }
 157  $call .= ');';
 158  my @ret = eval $call;
 159  croak $@ if $@;
 160  return @ret;
 161 }
 162
 163 =head2 C<wrap $name, %opts>
 164
 165 Generates a wrapper that does the same thing as L</recall>, but specialized for a given function. This wrapper can be compiled once for all to avoid calling C<eval> at each run (like L</recall> does). You can still force the prototype by passing C<< { $name => $proto } >> as the first argument. Others arguments are seen as key / value pairs and tune the code generated by L</wrap>. Valid keys are :
 166
 167 =over 4
 168
 169 =item C<< ref => $func >>
 170
 171 Specifies the function used in the generated code to test the reference type of scalars. Defaults to C<'ref'>. You may also want to use C<Scalar::Util::reftype>.
 172
 173 =item C<< wrong_ref => $code >>
 174
 175 The code executed when a reference of incorrect type is encountered. The result of this snippet is also the result of the generated code, hence it defaults to C<'undef'>. It's a good place to C<croak> or C<die> too.
 176
 177 =item C<< sub => $bool >>
 178
 179 Encloses the code into a C<sub { }> block. Default is true.
 180
 181 =item C<< compile => $bool >>
 182
 183 Makes L</wrap> compile the code generated and return the resulting code reference. Implies C<< sub => 1 >>. Be careful that in this case C<ref> must be a fully qualified function name. Defaults to false.
 184
 185 =back
 186
 187 This is how you make your own C<push> that pushes into array references :
 188
 189     my @a = (0 .. 2);
 190     my $push = wrap 'CORE::push', compile => 1;
 191     $push->(\@a, 3 .. 7); # returns 3 + 5 = 8, and @a now contains 0 .. 7
 192
 193 =cut
 194
 195 sub _wrap {
 196  my ($name, $proto, $i, $args, $cr, $opts) = @_;
 197  if ($proto =~ /(\\?)(\[[^\]]+\]|[^\];])(.*)/g) {
 198   my ($ref, $p) = ($1, $2);
 199   $proto = $3;
 200   $p = $1 if $p =~ /^\[([^\]]+)\]/;
 201   if ($ref) {
 202    if (length $p > 1) {
 203     return 'my $r = ' . $opts->{ref} . '($_[' . $i . ']); '
 204            . join ' els',
 205               map( {
 206                "if (\$r eq '" . $reftypes{$_} ."') { "
 207                . _wrap($name, $proto, ($i + 1),
 208                               $args . $_ . '{$_[' . $i . ']}, ',
 209                               $cr, $opts)
 210                . ' }'
 211               } split //, $p),
 212               'e { ' . $opts->{wrong_ref} . ' }'
 213    } else {
 214     $args .= $p . '{$_[' . $i . ']}, ';
 215    }
 216   } elsif ($p =~ /[\@\%]/) {
 217    $args .= '@_[' . $i . '..$#_]';
 218   } elsif ($p =~ /\&/) {
 219    my %h = do { my $c; map { $_ => $c++ } @$cr };
 220    my $j;
 221    if (not exists $h{$i}) {
 222     push @$cr, $i;
 223     $j = $#{$cr};
 224    } else {
 225     $j = int $h{$i};
 226    }
 227    $args .= 'sub{&{$c[' . $j . ']}}, ';
 228   } elsif ($p eq '_') {
 229    $args .= '((@_ > ' . $i . ') ? $_[' . $i . '] : $_), ';
 230   } else {
 231    $args .= '$_[' . $i . '], ';
 232   }
 233   return _wrap($name, $proto, ($i + 1), $args, $cr, $opts);
 234  } else {
 235   $args =~ s/,\s*$//;
 236   return $name . '(' . $args . ')';
 237  }
 238 }
 239
 240 sub wrap {
 241  my ($name, $proto) = _check_name shift;
 242  croak 'Optional arguments must be passed as key => value pairs' if @_ % 2;
 243  my %opts = @_;
 244  $opts{ref}     ||= 'ref';
 245  $opts{sub}       = 1       if not exists $opts{sub} or $opts{compile};
 246  $opts{wrong_ref} = 'undef' if not defined $opts{wrong_ref};
 247  my @cr;
 248  my $call;
 249  if (defined $proto) {
 250   $call = _wrap $name, $proto, 0, '', \@cr, \%opts;
 251  } else {
 252   $call = _wrap $name, '', 0, '@_';
 253  }
 254  if (@cr) {
 255   $call = 'my @c; '
 256         . join('', map { 'push @c, $_[' . $_ . ']; ' } @cr)
 257         . $call
 258  }
 259  $call = '{ ' . $call . ' }';
 260  $call = 'sub ' . $call if $opts{sub};
 261  $call = eval $call     if $opts{compile};
 262  return $call;
 263 }
 264
 265 =head1 EXPORT
 266
 267 The functions L</flatten>, L</recall> and L</wrap> are only exported on request, either by providing their name or by the C<':funcs'> and C<':all'> tags.
 268
 269 =cut
 270
 271 use base qw/Exporter/;
 272
 273 use vars qw/@EXPORT @EXPORT_OK %EXPORT_TAGS/;
 274
 275 @EXPORT             = ();
 276 %EXPORT_TAGS        = (
 277  'funcs' =>  [ qw/flatten recall wrap/ ]
 278 );
 279 @EXPORT_OK          = map { @$_ } values %EXPORT_TAGS;
 280 $EXPORT_TAGS{'all'} = [ @EXPORT_OK ];
 281
 282 =head1 DEPENDENCIES
 283
 284 L<Carp>, L<Exporter> (core modules since perl 5), L<Scalar::Util> (since 5.7.3).
 285
 286 =head1 AUTHOR
 287
 288 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 289
 290 You can contact me by mail or on #perl @ FreeNode (vincent or Prof_Vince).
 291
 292 =head1 BUGS
 293
 294 Please report any bugs or feature requests to C<bug-sub-prototype-util at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Sub-Prototype-Util>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 295
 296 =head1 SUPPORT
 297
 298 You can find documentation for this module with the perldoc command.
 299
 300     perldoc Sub::Prototype::Util
 301
 302 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Sub-Prototype-Util>.
 303
 304 =head1 COPYRIGHT & LICENSE
 305
 306 Copyright 2008 Vincent Pit, all rights reserved.
 307
 308 This program is free software; you can redistribute it and/or modify it
 309 under the same terms as Perl itself.
 310
 311 =cut
 312
 313 1; # End of Sub::Prototype::Util