lib/Sub/Prototype/Util.pm

   1 package Sub::Prototype::Util;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Carp qw/croak/;
   7 use Scalar::Util qw/reftype/;
   8
   9 =head1 NAME
  10
  11 Sub::Prototype::Util - Prototype-related utility routines.
  12
  13 =head1 VERSION
  14
  15 Version 0.08
  16
  17 =cut
  18
  19 use vars qw/$VERSION/;
  20
  21 $VERSION = '0.08';
  22
  23 =head1 SYNOPSIS
  24
  25     use Sub::Prototype::Util qw/flatten wrap recall/;
  26
  27     my @a = qw/a b c/;
  28     my @args = ( \@a, 1, { d => 2 }, undef, 3 );
  29
  30     my @flat = flatten '\@$;$', @args; # ('a', 'b', 'c', 1, { d => 2 })
  31     recall 'CORE::push', @args; # @a contains 'a', 'b', 'c', 1, { d => 2 }, undef, 3
  32     my $splice = wrap 'CORE::splice';
  33     my @b = $splice->(\@a, 4, 2); # @a is now ('a', 'b', 'c', 1, 3) and @b is ({ d => 2 }, undef)
  34
  35 =head1 DESCRIPTION
  36
  37 Prototypes are evil, but sometimes you just have to bear with them, especially when messing with core functions. This module provides several utilities aimed at facilitating "overloading" of prototyped functions.
  38
  39 They all handle C<5.10>'s C<_> prototype.
  40
  41 =head1 FUNCTIONS
  42
  43 =cut
  44
  45 my %sigils = qw/SCALAR $ ARRAY @ HASH % GLOB * CODE &/;
  46 my %reftypes = reverse %sigils;
  47
  48 sub _check_ref {
  49  my ($a, $p) = @_;
  50  my $r;
  51  if (!defined $a || !defined($r = reftype $a)) { # not defined or plain scalar
  52   croak 'Got ' . ((defined $a) ? 'a plain scalar' : 'undef')
  53                . ' where a reference was expected';
  54  }
  55  croak 'Unexpected ' . $r . ' reference' unless exists $sigils{$r}
  56                                             and $p =~ /\Q$sigils{$r}\E/;
  57  return $r;
  58 }
  59
  60 sub _clean_msg {
  61  my ($msg) = @_;
  62  $msg =~ s/(?:\s+called)?\s+at\s+.*$//s;
  63  return $msg;
  64 }
  65
  66 =head2 C<flatten $proto, @args>
  67
  68 Flattens the array C<@args> according to the prototype C<$proto>. When C<@args> is what C<@_> is after calling a subroutine with prototype C<$proto>, C<flatten> returns the list of what C<@_> would have been if there were no prototype.
  69
  70 =cut
  71
  72 sub flatten {
  73  my $proto = shift;
  74  return @_ unless defined $proto;
  75  my @args;
  76  while ($proto =~ /(\\?)(\[[^\]]+\]|[^\];])/g) {
  77   my $p = $2;
  78   if ($1) {
  79    my $a = shift;
  80    my $r = _check_ref $a, $p;
  81    push @args, $r eq 'SCALAR'
  82                ? $$a
  83                : ($r eq 'ARRAY'
  84                   ? @$a
  85                   : ($r eq 'HASH'
  86                      ? %$a
  87                      : ($r eq 'GLOB'
  88                         ? *$a
  89                         : &$a # _check_ref ensures this must be a code ref
  90                        )
  91                     )
  92                  );
  93   } elsif ($p =~ /[\@\%]/) {
  94    push @args, @_;
  95    last;
  96   } elsif ($p eq '_') {
  97    shift; # without prototype, this argument wouldn't have been passed
  98   } else {
  99    push @args, shift;
 100   }
 101  }
 102  return @args;
 103 }
 104
 105 =head2 C<wrap $name, %opts>
 106
 107 Generates a wrapper that calls the function C<$name> with a prototyped argument list. That is, the wrapper's arguments should be what C<@_> is when you define a subroutine with the same prototype as C<$name>.
 108
 109     my $a = [ 0 .. 2 ];
 110     my $push = wrap 'CORE::push';
 111     $push->($a, 3, 4); # returns 3 + 2 = 5 and $a now contains 0 .. 4
 112
 113 You can force the use of a specific prototype. In this case, C<$name> must be a hash reference that holds exactly one key / value pair, the key being the function name and the value the prototpye that should be used to call it.
 114
 115     my $push = wrap { 'CORE::push' => '\@$' }; # only pushes 1 arg
 116
 117 Others arguments are seen as key / value pairs that are meant to tune the code generated by L</wrap>. Valid keys are :
 118
 119 =over 4
 120
 121 =item C<< ref => $func >>
 122
 123 Specifies the function used in the generated code to test the reference type of scalars. Defaults to C<'ref'>. You may also want to use C<Scalar::Util::reftype>.
 124
 125 =item C<< wrong_ref => $code >>
 126
 127 The code executed when a reference of incorrect type is encountered. The result of this snippet is also the result of the generated code, hence it defaults to C<'undef'>. It's a good place to C<croak> or C<die> too.
 128
 129 =item C<< sub => $bool >>
 130
 131 Encloses the code into a C<sub { }> block. Default is true.
 132
 133 =item C<< compile => $bool >>
 134
 135 Makes L</wrap> compile the code generated and return the resulting code reference. Be careful that in this case C<ref> must be a fully qualified function name. Defaults to true, but turned off when C<sub> is false.
 136
 137 =back
 138
 139 For example, this allows you to recall into C<CORE::grep> and C<CORE::map> by using the C<\&@> prototype :
 140
 141     my $grep = wrap { 'CORE::grep' => '\&@' };
 142     sub mygrep (&@) { $grep->(@_) } # the prototypes are intentionally different
 143
 144 =cut
 145
 146 sub _wrap {
 147  my ($name, $proto, $i, $args, $cr, $opts) = @_;
 148  while ($proto =~ s/(\\?)(\[[^\]]+\]|[^\];])//) {
 149   my ($ref, $p) = ($1, $2);
 150   $p = $1 if $p =~ /^\[([^\]]+)\]/;
 151   my $cur = '$_[' . $i . ']';
 152   if ($ref) {
 153    if (length $p > 1) {
 154     return 'my $r = ' . $opts->{ref} . '(' . $cur . '); '
 155            . join ' els',
 156               map( {
 157                "if (\$r eq '" . $reftypes{$_} ."') { "
 158                . _wrap($name, $proto, ($i + 1),
 159                               $args . $_ . '{' . $cur . '}, ',
 160                               $cr, $opts)
 161                . ' }'
 162               } split //, $p),
 163               'e { ' . $opts->{wrong_ref} . ' }'
 164    } else {
 165     $args .= $p . '{' . $cur . '}, ';
 166    }
 167   } elsif ($p =~ /[\@\%]/) {
 168    $args .= '@_[' . $i . '..$#_]';
 169   } elsif ($p =~ /\&/) {
 170    my %h = do { my $c; map { $_ => $c++ } @$cr };
 171    my $j;
 172    if (not exists $h{$i}) {
 173     push @$cr, $i;
 174     $j = $#{$cr};
 175    } else {
 176     $j = int $h{$i};
 177    }
 178    $args .= 'sub{&{$c[' . $j . ']}}, ';
 179   } elsif ($p eq '_') {
 180    $args .= '((@_ > ' . $i . ') ? ' . $cur . ' : $_), ';
 181   } else {
 182    $args .= $cur . ', ';
 183   }
 184   ++$i;
 185  }
 186  $args =~ s/,\s*$//;
 187  return $name . '(' . $args . ')';
 188 }
 189
 190 sub _check_name {
 191  my $name = $_[0];
 192  croak 'No subroutine specified' unless $name;
 193  my $proto;
 194  my $r = ref $name;
 195  if (!$r) {
 196   $proto = prototype $name;
 197  } elsif ($r eq 'HASH') {
 198   croak 'Forced prototype hash reference must contain exactly one key/value pair' unless keys %$name == 1;
 199   ($name, $proto) = %$name;
 200  } else {
 201   croak 'Unhandled ' . $r . ' reference as first argument';
 202  }
 203  $name =~ s/^\s+//;
 204  $name =~ s/[\s\$\@\%\*\&;].*//;
 205  return $name, $proto;
 206 }
 207
 208 sub wrap {
 209  my ($name, $proto) = _check_name shift;
 210  croak 'Optional arguments must be passed as key => value pairs' if @_ % 2;
 211  my %opts = @_;
 212  $opts{ref}     ||= 'ref';
 213  $opts{sub}       = 1       if not defined $opts{sub};
 214  $opts{compile}   = 1       if not defined $opts{compile} and $opts{sub};
 215  $opts{wrong_ref} = 'undef' if not defined $opts{wrong_ref};
 216  my @cr;
 217  my $call;
 218  if (defined $proto) {
 219   $call = _wrap $name, $proto, 0, '', \@cr, \%opts;
 220  } else {
 221   $call = _wrap $name, '', 0, '@_';
 222  }
 223  if (@cr) {
 224   $call = 'my @c; '
 225         . join('', map { 'push @c, $_[' . $_ . ']; ' } @cr)
 226         . $call
 227  }
 228  $call = '{ ' . $call . ' }';
 229  $call = 'sub ' . $call if $opts{sub};
 230  if ($opts{compile}) {
 231   $call = eval $call;
 232   croak _clean_msg $@ if $@;
 233  }
 234  return $call;
 235 }
 236
 237 =head2 C<recall $name, @args>
 238
 239 Calls the function C<$name> with the prototyped argument list C<@args>. That is, C<@args> should be what C<@_> is when you define a subroutine with the same prototype as C<$name>. You can still force the prototype by passing C<< { $name => $proto } >> as the first argument.
 240
 241     my $a = [ ];
 242     recall { 'CORE::push' => '\@$' }, $a, 1, 2, 3; # $a just contains 1
 243
 244 It's implemented in terms of L</wrap>, and hence calls C<eval> at each run.
 245 If you plan to recall several times, consider using L</wrap> instead.
 246
 247 =cut
 248
 249 sub recall {
 250  my $wrap = eval { wrap shift };
 251  croak _clean_msg $@ if $@;
 252  return $wrap->(@_);
 253 }
 254
 255 =head1 EXPORT
 256
 257 The functions L</flatten>, L</wrap> and L</recall> are only exported on request, either by providing their name or by the C<':funcs'> and C<':all'> tags.
 258
 259 =cut
 260
 261 use base qw/Exporter/;
 262
 263 use vars qw/@EXPORT @EXPORT_OK %EXPORT_TAGS/;
 264
 265 @EXPORT             = ();
 266 %EXPORT_TAGS        = (
 267  'funcs' =>  [ qw/flatten wrap recall/ ]
 268 );
 269 @EXPORT_OK          = map { @$_ } values %EXPORT_TAGS;
 270 $EXPORT_TAGS{'all'} = [ @EXPORT_OK ];
 271
 272 =head1 DEPENDENCIES
 273
 274 L<Carp>, L<Exporter> (core modules since perl 5), L<Scalar::Util> (since 5.7.3).
 275
 276 =head1 AUTHOR
 277
 278 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 279
 280 You can contact me by mail or on C<irc.perl.org> (vincent).
 281
 282 =head1 BUGS
 283
 284 Please report any bugs or feature requests to C<bug-sub-prototype-util at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Sub-Prototype-Util>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 285
 286 =head1 SUPPORT
 287
 288 You can find documentation for this module with the perldoc command.
 289
 290     perldoc Sub::Prototype::Util
 291
 292 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Sub-Prototype-Util>.
 293
 294 =head1 COPYRIGHT & LICENSE
 295
 296 Copyright 2008 Vincent Pit, all rights reserved.
 297
 298 This program is free software; you can redistribute it and/or modify it
 299 under the same terms as Perl itself.
 300
 301 =cut
 302
 303 1; # End of Sub::Prototype::Util