t/20-return.t

   1 #!perl -T
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More tests => 69;
   7
   8 use Sub::Nary;
   9
  10 my $sn = Sub::Nary->new();
  11
  12 my ($x, $y, @a, %h);
  13
  14 my @tests = (
  15  [ sub { return },               0 ],
  16  [ sub { return () },            0 ],
  17  [ sub { return return },        0 ],
  18  [ sub { return do { return } }, 0 ],
  19
  20  [ sub { return 1 },                           1 ],
  21  [ sub { return 1, 2 },                        2 ],
  22  [ sub { my $x = 1; $x = 2; return 3, 4, 5; }, 3 ],
  23  [ sub { do { 1; return 2, 3 } },              2 ],
  24  [ sub { do { 1; return 2, 3; 4 } },           2 ],
  25  [ sub { do { 1; return 2, return 3 } },       1 ],
  26  [ sub { do { return if $x; 2, 3 }, 4 },       { 0 => 0.5, 3 => 0.5 } ],
  27  [ sub { do { do { return if $x }, 3 }, 4 },   { 0 => 0.5, 3 => 0.5 } ],
  28  [ sub { do { return if $x; 2, 3 }, do { return 1 if $y; 4, 5, 6 } },
  29                                            { 0 => 0.5, 1 => 0.25, 5 => 0.25 } ],
  30  [ sub { my $x = do { return 2, 3; 4 } },      2 ],
  31
  32  [ sub { return $x },     1 ],
  33  [ sub { return $x, $y }, 2 ],
  34
  35  [ sub { return @a },                'list' ],
  36  [ sub { return $a[0] },             1 ],
  37  [ sub { return @a[1, 2] },          2 ],
  38  [ sub { return @a[2 .. 4] },        3 ],
  39  [ sub { return @a[1, 4 .. 7, 2] },  6 ],
  40  [ sub { return @a[do{ 1 .. 5 }] },  5 ],
  41  [ sub { return @a[do{ 1 .. $x }] }, 'list' ],
  42
  43  [ sub { return %h },              'list' ],
  44  [ sub { return $h{a} },           1 ],
  45  [ sub { return @h{qw<a b>} },     2 ],
  46  [ sub { return @h{@a[1 .. 3]} },  3 ],
  47  [ sub { return @h{@a[$y .. 3]} }, 'list' ],
  48  [ sub { return keys %h },         'list' ],
  49  [ sub { return values %h },       'list' ],
  50
  51  [ sub { return $x, $a[3], $h{c} }, 3 ],
  52  [ sub { return $x, @a },           'list' ],
  53  [ sub { return %h, $y },           'list' ],
  54
  55  [ sub { return 2 .. 4 },                  3 ],
  56  [ sub { return $x .. 3 },                 'list' ],
  57  [ sub { return 1 .. $x },                 'list' ],
  58  [ sub { return '2foo' .. 4 },             3 ],
  59  [ sub { my @a = (7, 8); return @a .. 4 }, 'list' ],
  60  [ sub { return do { return 1, 2 } .. 3 }, 2 ],
  61  [ sub { return 1 .. do { return 2, 3 } }, 2 ],
  62  [ sub { my @a = return 6, $x },           2 ],
  63
  64  [ sub { for (1, 2, 3) { return } },                                     0 ],
  65  [ sub { for (1, 2, 3) { } return 1, 2; },                               2 ],
  66  [ sub { for (do { return 1, 2, 3 }) { } return 1, 2; },                 3 ],
  67  [ sub { for (do { return 2, 3 if $x }) { } },      { 2 => 0.5, 0 => 0.5 } ],
  68  [ sub { for (1, 2, 3) { return 1, 2 if $x } },                     'list' ],
  69  [ sub { for ($x, 1, $y) { return 1, 2 } },                              2 ],
  70  [ sub { for (@a) { return 1, do { $x } } },                             2 ],
  71  [ sub { for (keys %h) { return do { 1 }, do { return @a[0, 2] } } },    2 ],
  72  [ sub { for my $i (1 .. 4) { return @h{qw<a b>} } },                    2 ],
  73  [ sub { for (my $i; $i < 10; ++$i) { return 1, @a[do{return 2, 3}] } }, 2 ],
  74  [ sub { return 1, 2 for 1 .. 4 },                                       2 ],
  75
  76  [ sub { while (1) { return } },                 0 ],
  77  [ sub { while (1) { } return 1, 2 },            2 ],
  78  [ sub { while (1) { return 1, 2 } },            2 ],
  79  [ sub { while (1) { return 1, 2 if $x } },      'list' ],
  80  [ sub { while (1) { last; return 1, 2 } },      2 ],
  81  [ sub { return 1, 2 while 1 },                  2 ],
  82  [ sub { while (do { return 2, 3 }) { } },       2 ],
  83  [ sub { while (do { return 2, 3 if $x }) { } }, 'list' ],
  84
  85  [ sub { eval { return } },                         0 ],
  86  [ sub { eval { return 1, 2 } },                    2 ],
  87  [ sub { eval { return 1, 2; 3, 4, 5 } },           2 ],
  88  [ sub { eval { }; return $x, 2 },                  2 ],
  89  [ sub { return eval { 1, $x }; },                  2 ],
  90  [ sub { return 1, eval { $x, eval { $h{foo} } } }, 3 ],
  91  [ sub { return eval { return $x, eval { $y } } },  2 ],
  92  [ sub { return eval { do { eval { @a } } } },      'list' ],
  93
  94  [ sub { eval 'return 1, 2' }, 'list' ],
  95 );
  96
  97 my $i = 1;
  98 for (@tests) {
  99  my $r = $sn->nary($_->[0]);
 100  my $exp = ref $_->[1] ? $_->[1] : { $_->[1] => 1 };
 101  is_deeply($r, $exp, 'return test ' . $i);
 102  ++$i;
 103 }