lib/Sub/Nary.pm

   1 package Sub::Nary;
   2
   3 use 5.008001;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp qw/croak/;
   9
  10 use B qw/class ppname svref_2object OPf_KIDS/;
  11
  12 =head1 NAME
  13
  14 Sub::Nary - Try to count how many elements a subroutine can return in list context.
  15
  16 =head1 VERSION
  17
  18 Version 0.03
  19
  20 =cut
  21
  22 our $VERSION;
  23 BEGIN {
  24  $VERSION  = '0.03';
  25 }
  26
  27 =head1 SYNOPSIS
  28
  29     use Sub::Nary;
  30
  31     my $sn = Sub::Nary->new();
  32     my $r  = $sn->nary(\&hlagh);
  33
  34 =head1 DESCRIPTION
  35
  36 This module uses the L<B> framework to walk into subroutines and try to guess how many scalars are likely to be returned in list context. It's not always possible to give a definitive answer to this question at compile time, so the results are given in terms of "probability of return" (to be understood in a sense described below).
  37
  38 =head1 METHODS
  39
  40 =head2 C<new>
  41
  42 The usual constructor. Currently takes no argument.
  43
  44 =head2 C<nary $coderef>
  45
  46 Takes a code reference to a named or anonymous subroutine, and returns a hash reference whose keys are the possible numbers of returning scalars, and the corresponding values the "probability" to get them. The special key C<'list'> is used to denote a possibly infinite number of returned arguments. The return value hence would look at
  47
  48     { 1 => 0.2, 2 => 0.4, 4 => 0.3, list => 0.1 }
  49
  50 that is, we should get C<1> scalar C<1> time over C<5> and so on. The sum of all values is C<1>. The returned result, and all the results obtained from intermediate subs, are cached into the object.
  51
  52 =head2 C<flush>
  53
  54 Flushes the L<Sub::Nary> object cache. Returns the object itself.
  55
  56 =head1 PROBABILITY OF RETURN
  57
  58 The probability is computed as such :
  59
  60 =over 4
  61
  62 =item * When branching, each branch is considered equally possible.
  63
  64 For example, the subroutine
  65
  66     sub simple {
  67      if (rand < 0.1) {
  68       return 1;
  69      } else {
  70       return 2, 3;
  71      }
  72     }
  73
  74 is seen returning one or two arguments each with probability C<1/2>.
  75 As for
  76
  77     sub hlagh {
  78      my $x = rand;
  79      if ($x < 0.1) {
  80       return 1, 2, 3;
  81      } elsif ($x > 0.9) {
  82       return 4, 5;
  83      }
  84     }
  85
  86 it is considered to return C<3> scalars with probability C<1/2>, C<2> with probability C<1/2 * 1/2 = 1/4> and C<1> (when the two tests fail, the last computed value is returned, which here is C<< $x > 0.9 >> evaluated in the scalar context of the test) with remaining probability C<1/4>.
  87
  88 =item * The total probability law for a given returning point is the convolution product of the probabilities of its list elements.
  89
  90 As such,
  91
  92     sub notsosimple {
  93      return 1, simple(), 2
  94     }
  95
  96 returns C<3> or C<4> arguments with probability C<1/2> ; and
  97
  98     sub double {
  99      return simple(), simple()
 100     }
 101
 102 never returns C<1> argument but returns C<2> with probability C<1/2 * 1/2 = 1/4>, C<3> with probability C<1/2 * 1/2 + 1/2 * 1/2 = 1/2> and C<4> with probability C<1/4> too.
 103
 104 =item * If a core function may return different numbers of scalars, each kind is considered equally possible.
 105
 106 For example, C<stat> returns C<13> elements on success and C<0> on error. The according probability will then be C<< { 0 => 0.5, 13 => 0.5 } >>.
 107
 108 =item * The C<list> state is absorbing in regard of all the other ones.
 109
 110 This is just a pedantic way to say that "list + fixed length = list".
 111 That's why
 112
 113     sub listy {
 114      return 1, simple(), @_
 115     }
 116
 117 is considered as always returning an unbounded list.
 118
 119 Also, the convolution law does not behave the same when C<list> elements are involved : in the following example,
 120
 121     sub oneorlist {
 122      if (rand < 0.1) {
 123       return 1
 124      } else {
 125       return @_
 126      }
 127     }
 128
 129     sub composed {
 130      return oneorlist(), oneorlist()
 131     }
 132
 133 C<composed> returns C<2> scalars with probability C<1/2 * 1/2 = 1/4> and a C<list> with probability C<3/4>.
 134
 135 =back
 136
 137 =cut
 138
 139 BEGIN {
 140  require XSLoader;
 141  XSLoader::load(__PACKAGE__, $VERSION);
 142 }
 143
 144 sub _check_self {
 145  croak 'First argument isn\'t a valid ' . __PACKAGE__ . ' object'
 146   unless ref $_[0] and $_[0]->isa(__PACKAGE__);
 147 }
 148
 149 sub new {
 150  my $class = shift;
 151  $class = ref($class) || $class || __PACKAGE__;
 152  bless { cache => { } }, $class;
 153 }
 154
 155 sub flush {
 156  my $self = shift;
 157  _check_self($self);
 158  $self->{cache} = { };
 159  $self;
 160 }
 161
 162 sub nary {
 163  my $self = shift;
 164  my $sub  = shift;
 165
 166  $self->{cv} = [ ];
 167  return ($self->enter(svref_2object($sub)))[1];
 168 }
 169
 170 sub name ($) {
 171  local $SIG{__DIE__} = \&Carp::confess;
 172  my $n = $_[0]->name;
 173  $n eq 'null' ? substr(ppname($_[0]->targ), 3) : $n
 174 }
 175
 176 sub power {
 177  my ($p, $n, $c) = @_;
 178  return unless defined $p;
 179  return { 0 => $c } unless $n;
 180  if ($n eq 'list') {
 181   my $z = delete $p->{0};
 182   return { 'list' => $c } unless $z;
 183   return { 0      => $c } if $z == 1;
 184   return { 0 => $c * $z, list => $c * (1 - $z) };
 185  }
 186  my $r = combine map { { %$p } } 1 .. $n;
 187  $r->{$_} *= $c for keys %$r;
 188  return $r;
 189 }
 190
 191 my %ops;
 192
 193 $ops{$_} = 1      for scalops;
 194 $ops{$_} = 0      for qw/stub nextstate pushmark iter unstack/;
 195 $ops{$_} = 1      for qw/padsv/;
 196 $ops{$_} = 'list' for qw/padav/;
 197 $ops{$_} = 'list' for qw/padhv rv2hv/;
 198 $ops{$_} = 'list' for qw/padany/;
 199 $ops{$_} = 'list' for qw/match entereval readline/;
 200
 201 $ops{each}      = { 0 => 0.5, 2 => 0.5 };
 202 $ops{stat}      = { 0 => 0.5, 13 => 0.5 };
 203
 204 $ops{caller}    = sub { my @a = caller 0; scalar @a }->();
 205 $ops{localtime} = do { my @a = localtime; scalar @a };
 206 $ops{gmtime}    = do { my @a = gmtime; scalar @a };
 207
 208 $ops{$_} = { 0 => 0.5, 10 => 0.5 } for map "gpw$_", qw/nam uid ent/;
 209 $ops{$_} = { 0 => 0.5, 4 => 0.5 }  for map "ggr$_", qw/nam gid ent/;
 210 $ops{$_} = 'list'                  for qw/ghbyname ghbyaddr ghostent/;
 211 $ops{$_} = { 0 => 0.5, 4 => 0.5 }  for qw/gnbyname gnbyaddr gnetent/;
 212 $ops{$_} = { 0 => 0.5, 3 => 0.5 }  for qw/gpbyname gpbynumber gprotoent/;
 213 $ops{$_} = { 0 => 0.5, 4 => 0.5 }  for qw/gsbyname gsbyport gservent/;
 214
 215 sub enter {
 216  my ($self, $cv) = @_;
 217
 218  return undef, 'list' if class($cv) ne 'CV';
 219  my $op  = $cv->ROOT;
 220  my $tag = tag($op);
 221
 222  return undef, { %{$self->{cache}->{$tag}} } if exists $self->{cache}->{$tag};
 223
 224  # Anything can happen with recursion
 225  for (@{$self->{cv}}) {
 226   return undef, 'list' if $tag == tag($_->ROOT);
 227  }
 228
 229  unshift @{$self->{cv}}, $cv;
 230  my $r = add $self->inspect($op->first);
 231  shift @{$self->{cv}};
 232
 233  $r = { $r => 1 } unless ref $r;
 234  $self->{cache}->{$tag} = { %$r };
 235  return undef, $r;
 236 }
 237
 238 sub inspect {
 239  my ($self, $op) = @_;
 240
 241  my $n = name($op);
 242  return add($self->inspect_kids($op)), undef if $n eq 'return';
 243
 244  my $meth = $self->can('pp_' . $n);
 245  return $self->$meth($op) if $meth;
 246
 247  if (exists $ops{$n}) {
 248   my $l = $ops{$n};
 249   $l = { %$l } if ref $l;
 250   return undef, $l;
 251  }
 252
 253  if (class($op) eq 'LOGOP' and not null $op->first) {
 254   my @res;
 255
 256   my $op = $op->first;
 257   my ($r1, $l1) = $self->inspect($op);
 258   return $r1, $l1 if defined $r1 and zero $l1;
 259   my $c = count $l1;
 260
 261   $op = $op->sibling;
 262   my ($r2, $l2) = $self->inspect($op);
 263
 264   $op = $op->sibling;
 265   my ($r3, $l3);
 266   if (null $op) {
 267    # If the logop has no else branch, it can also return the *scalar* result of
 268    # the conditional
 269    $l3 = { 1 => 1 };
 270   } else {
 271    ($r3, $l3) = $self->inspect($op);
 272   }
 273
 274   my $r = add $r1, scale $c / 2, add $r2, $r3;
 275   my $l = scale $c / 2, add $l2, $l3;
 276   return $r, $l
 277  }
 278
 279  return $self->inspect_kids($op);
 280 }
 281
 282 sub inspect_kids {
 283  my ($self, $op) = @_;
 284
 285  return undef, 0 unless $op->flags & OPf_KIDS;
 286
 287  $op = $op->first;
 288  return undef, 0 if null $op;
 289  if (name($op) eq 'pushmark') {
 290   $op = $op->sibling;
 291   return undef, 0 if null $op;
 292  }
 293
 294  my ($r, @l);
 295  my $c = 1;
 296  for (; not null $op; $op = $op->sibling) {
 297   my $n = name($op);
 298   if ($n eq 'nextstate') {
 299    @l  = ();
 300    next;
 301   }
 302   if ($n eq 'lineseq') {
 303    @l  = ();
 304    $op = $op->first;
 305    redo;
 306   }
 307   my ($rc, $lc) = $self->inspect($op);
 308   $c = 1 - count $r;
 309   $r = add $r, scale $c, $rc if defined $rc;
 310   if (not defined $lc) {
 311    @l = ();
 312    last;
 313   }
 314   push @l, scale $c, $lc;
 315  }
 316
 317  my $l = scale +(1 - count $r), normalize combine @l;
 318
 319  return $r, $l;
 320 }
 321
 322 # Stolen from B::Deparse
 323
 324 sub padval { $_[0]->{cv}->[0]->PADLIST->ARRAYelt(1)->ARRAYelt($_[1]) }
 325
 326 sub gv_or_padgv {
 327  my ($self, $op) = @_;
 328  if (class($op) eq 'PADOP') {
 329   return $self->padval($op->padix)
 330  } else { # class($op) eq "SVOP"
 331   return $op->gv;
 332  }
 333 }
 334
 335 sub const_sv {
 336  my ($self, $op) = @_;
 337  my $sv = $op->sv;
 338  # the constant could be in the pad (under useithreads)
 339  $sv = $self->padval($op->targ) unless $$sv;
 340  return $sv;
 341 }
 342
 343 sub pp_entersub {
 344  my ($self, $op) = @_;
 345
 346  $op = $op->first while $op->flags & OPf_KIDS;
 347  return undef, 0 if null $op;
 348  if (name($op) eq 'pushmark') {
 349   $op = $op->sibling;
 350   return undef, 0 if null $op;
 351  }
 352
 353  my $r;
 354  my $c = 1;
 355  for (; not null $op->sibling; $op = $op->sibling) {
 356   my ($rc, $lc) = $self->inspect($op);
 357   return $rc, $lc if defined $rc and not defined $lc;
 358   $r = add $r, scale $c, $rc;
 359   $c *= count $lc;
 360  }
 361
 362  if (name($op) eq 'rv2cv') {
 363   my $n;
 364   do {
 365    $op = $op->first;
 366    my $next = $op->sibling;
 367    while (not null $next) {
 368     $op   = $next;
 369     $next = $next->sibling;
 370    }
 371    $n  = name($op)
 372   } while ($op->flags & OPf_KIDS and { map { $_ => 1 } qw/null leave/ }->{$n});
 373   return 'list', undef unless { map { $_ => 1 } qw/gv refgen/ }->{$n};
 374   local $self->{sub} = 1;
 375   my ($rc, $lc) = $self->inspect($op);
 376   return $r, scale $c, $lc;
 377  } else {
 378   # Method call ?
 379   return $r, { 'list' => $c };
 380  }
 381 }
 382
 383 sub pp_gv {
 384  my ($self, $op) = @_;
 385
 386  return $self->{sub} ? $self->enter($self->gv_or_padgv($op)->CV) : (undef, 1)
 387 }
 388
 389 sub pp_anoncode {
 390  my ($self, $op) = @_;
 391
 392  return $self->{sub} ? $self->enter($self->const_sv($op)) : (undef, 1)
 393 }
 394
 395 sub pp_goto {
 396  my ($self, $op) = @_;
 397
 398  my $n = name($op);
 399  while ($op->flags & OPf_KIDS) {
 400   my $nop = $op->first;
 401   my $nn  = name($nop);
 402   if ($nn eq 'pushmark') {
 403    $nop = $nop->sibling;
 404    $nn  = name($nop);
 405   }
 406   if ($n eq 'rv2cv' and $nn eq 'gv') {
 407    return $self->enter($self->gv_or_padgv($nop)->CV);
 408   }
 409   $op = $nop;
 410   $n  = $nn;
 411  }
 412
 413  return undef, 'list';
 414 }
 415
 416 sub pp_const {
 417  my ($self, $op) = @_;
 418
 419  return undef, 0 unless $op->isa('B::SVOP');
 420
 421  my $sv = $self->const_sv($op);
 422  my $n  = 1;
 423  my $c  = class($sv);
 424  if ($c eq 'AV') {
 425   $n = $sv->FILL + 1
 426  } elsif ($c eq 'HV') {
 427   $n = 2 * $sv->KEYS
 428  }
 429
 430  return undef, $n
 431 }
 432
 433 sub pp_aslice { $_[0]->inspect($_[1]->first->sibling) }
 434
 435 sub pp_hslice;
 436 *pp_hslice = *pp_aslice{CODE};
 437
 438 sub pp_lslice { $_[0]->inspect($_[1]->first) }
 439
 440 sub pp_rv2av {
 441  my ($self, $op) = @_;
 442  $op = $op->first;
 443
 444  if (name($op) eq 'gv') {
 445   return undef, { list => 1 };
 446  }
 447
 448  $self->inspect($op);
 449 }
 450
 451 sub pp_sassign {
 452  my ($self, $op) = @_;
 453
 454  my $r = ($self->inspect($op->first))[0];
 455
 456  my $c = 1 - count $r;
 457  return $r, $c ? { 1 => $c } : undef
 458 }
 459
 460 sub pp_aassign {
 461  my ($self, $op) = @_;
 462
 463  $op = $op->first;
 464
 465  # Can't assign to return
 466  my $l = ($self->inspect($op->sibling))[1];
 467  return undef, $l if not exists $l->{list};
 468
 469  $self->inspect($op);
 470 }
 471
 472 sub pp_leaveloop {
 473  my ($self, $op) = @_;
 474
 475  $op = $op->first;
 476  my ($r1, $l1);
 477  my $for;
 478  if (name($op) eq 'enteriter') { # for loop ?
 479   $for = 1;
 480   ($r1, $l1) = $self->inspect($op);
 481   return $r1, $l1 if defined $r1 and zero $l1;
 482  }
 483
 484  $op = $op->sibling;
 485  my ($r2, $l2);
 486  if (name($op->first) eq 'and') {
 487   ($r2, $l2) = $self->inspect($op->first->first);
 488   return $r2, $l2 if defined $r2 and zero $l2;
 489   my $c = count $l2;
 490   return { list => 1 }, undef if !$for and defined $r2;
 491   my ($r3, $l3) = $self->inspect($op->first->first->sibling);
 492   return { list => 1 }, undef if defined $r3 and defined $l3;
 493   $r2 = add $r2, scale $c, $r3;
 494  } else {
 495   ($r2, $l2) = $self->inspect($op);
 496   return { list => 1 }, undef if defined $r2 and defined $l2;
 497  }
 498
 499  my $r = (defined $r1) ? add $r1, scale +(1 - count $r1), $r2
 500                        : $r2;
 501  my $c = 1 - count $r;
 502  return $r, $c ? { 0 => $c } : undef;
 503 }
 504
 505 sub pp_flip {
 506  my ($self, $op) = @_;
 507
 508  $op = $op->first;
 509  return $self->inspect($op) if name($op) ne 'range';
 510
 511  my ($r, $l);
 512  my $begin = $op->first;
 513  if (name($begin) eq 'const') {
 514   my $end = $begin->sibling;
 515   if (name($end) eq 'const') {
 516    $begin = $self->const_sv($begin);
 517    $end   = $self->const_sv($end);
 518    {
 519     no warnings 'numeric';
 520     $begin = int ${$begin->object_2svref};
 521     $end   = int ${$end->object_2svref};
 522    }
 523    return undef, $end - $begin + 1;
 524   } else {
 525    ($r, $l) = $self->inspect($end);
 526   }
 527  } else {
 528   ($r, $l) = $self->inspect($begin);
 529  }
 530
 531  my $c = 1 - count $r;
 532  return $r, $c ? { 'list' => $c } : undef
 533 }
 534
 535 sub pp_grepwhile {
 536  my ($self, $op) = @_;
 537
 538  $op = $op->first;
 539  return $self->inspect($op) if name($op) ne 'grepstart';
 540  $op = $op->first->sibling;
 541
 542  my ($r2, $l2) = $self->inspect($op->sibling);
 543  return $r2, $l2 if defined $r2 and zero $l2;
 544  my $c2 = count $l2; # First one to happen
 545
 546  my ($r1, $l1) = $self->inspect($op);
 547  return (add $r2, scale $c2, $r1), undef if defined $r1 and zero $l1
 548                                                         and not zero $l2;
 549  my $c1 = count $l1;
 550
 551  $l2 = { $l2 => 1 } unless ref $l2;
 552  my $r = add $r2,
 553           scale $c2,
 554             add map { scale $l2->{$_}, cumulate $r1, $_, $c1 } keys %$l2;
 555  my $c = 1 - count $r;
 556  return $r, $c ? { ((zero $l2) ? 0 : 'list') => $c } : undef;
 557 }
 558
 559 sub pp_mapwhile {
 560  my ($self, $op) = @_;
 561
 562  $op = $op->first;
 563  return $self->inspect($op) if name($op) ne 'mapstart';
 564  $op = $op->first->sibling;
 565
 566  my ($r2, $l2) = $self->inspect($op->sibling);
 567  return $r2, $l2 if defined $r2 and zero $l2;
 568  my $c2 = count $l2; # First one to happen
 569
 570  my ($r1, $l1) = $self->inspect($op);
 571  return (add $r2, scale $c2, $r1), undef if defined $r1 and zero $l1
 572                                                         and not zero $l2;
 573  my $c1 = count $l1;
 574
 575  $l2 = { $l2 => 1 } unless ref $l2;
 576  my $r = add $r2,
 577           scale $c2,
 578             add map { scale $l2->{$_}, cumulate $r1, $_, $c1 } keys %$l2;
 579  my $c = 1 - count $r;
 580  my $l = scale $c, normalize add map { power $l1, $_, $l2->{$_} } keys %$l2;
 581  return $r, $l;
 582 }
 583
 584 =head1 EXPORT
 585
 586 An object-oriented module shouldn't export any function, and so does this one.
 587
 588 =head1 CAVEATS
 589
 590 The algorithm may be pessimistic (things seen as C<list> while they are of fixed length) but not optimistic (the opposite, duh).
 591
 592 C<wantarray> isn't specialized when encountered in the optree.
 593
 594 =head1 DEPENDENCIES
 595
 596 L<perl> 5.8.1.
 597
 598 L<Carp> (standard since perl 5), L<B> (since perl 5.005) and L<XSLoader> (since perl 5.006).
 599
 600 =head1 AUTHOR
 601
 602 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 603
 604 You can contact me by mail or on #perl @ FreeNode (vincent or Prof_Vince).
 605
 606 =head1 BUGS
 607
 608 Please report any bugs or feature requests to C<bug-sub-nary at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Sub-Nary>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 609
 610 =head1 SUPPORT
 611
 612 You can find documentation for this module with the perldoc command.
 613
 614     perldoc Sub::Nary
 615
 616 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Sub-Nary>.
 617
 618 =head1 ACKNOWLEDGEMENTS
 619
 620 Thanks to Sebastien Aperghis-Tramoni for helping to name this module.
 621
 622 =head1 COPYRIGHT & LICENSE
 623
 624 Copyright 2008 Vincent Pit, all rights reserved.
 625
 626 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 627
 628 =cut
 629
 630 1; # End of Sub::Nary