lib/Sub/Nary.pm

   1 package Sub::Nary;
   2
   3 use 5.008001;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp qw/croak/;
   9 use List::Util qw/reduce/;
  10
  11 use B qw/class ppname svref_2object OPf_KIDS/;
  12
  13 use Test::More; use Data::Dumper;
  14
  15 =head1 NAME
  16
  17 Sub::Nary - Try to count how many elements a subroutine can return in list context.
  18
  19 =head1 VERSION
  20
  21 Version 0.02
  22
  23 =cut
  24
  25 our $VERSION;
  26 BEGIN {
  27  $VERSION  = '0.02';
  28 }
  29
  30 our $DEBUG = 0;
  31
  32 =head1 SYNOPSIS
  33
  34     use Sub::Nary;
  35
  36     my $sn = Sub::Nary->new();
  37     my $r  = $sn->nary(\&hlagh);
  38
  39 =head1 DESCRIPTION
  40
  41 This module uses the L<B> framework to walk into subroutines and try to guess how many scalars are likely to be returned in list context. It's not always possible to give a definitive answer to this question at compile time, so the results are given in terms of "probability of return" (to be understood in a sense described below).
  42
  43 =head1 METHODS
  44
  45 =head2 C<new>
  46
  47 The usual constructor. Currently takes no argument.
  48
  49 =head2 C<nary $coderef>
  50
  51 Takes a code reference to a named or anonymous subroutine, and returns a hash reference whose keys are the possible numbers of returning scalars, and the corresponding values the "probability" to get them. The special key C<'list'> is used to denote a possibly infinite number of returned arguments. The return value hence would look at
  52
  53     { 1 => 0.2, 2 => 0.4, 4 => 0.3, list => 0.1 }
  54
  55 that is, we should get C<1> scalar C<1> time over C<5> and so on. The sum of all values is C<1>. The returned result, and all the results obtained from intermediate subs, are cached into the object.
  56
  57 =head2 C<flush>
  58
  59 Flushes the L<Sub::Nary> object cache. Returns the object itself.
  60
  61 =head1 PROBABILITY OF RETURN
  62
  63 The probability is computed as such :
  64
  65 =over 4
  66
  67 =item * When branching, each branch is considered equally possible.
  68
  69 For example, the subroutine
  70
  71     sub simple {
  72      if (rand < 0.1) {
  73       return 1;
  74      } else {
  75       return 2, 3;
  76      }
  77     }
  78
  79 is seen returning one or two arguments each with probability C<1/2>.
  80 As for
  81
  82     sub hlagh {
  83      my $x = rand;
  84      if ($x < 0.1) {
  85       return 1, 2, 3;
  86      } elsif ($x > 0.9) {
  87       return 4, 5;
  88      }
  89     }
  90
  91 it is considered to return C<3> scalars with probability C<1/2>, C<2> with probability C<1/2 * 1/2 = 1/4> and C<1> (when the two tests fail, the last computed value is returned, which here is C<< $x > 0.9 >> evaluated in the scalar context of the test) with remaining probability C<1/4>.
  92
  93 =item * The total probability law for a given returning point is the convolution product of the probabilities of its list elements.
  94
  95 As such,
  96
  97     sub notsosimple {
  98      return 1, simple(), 2
  99     }
 100
 101 returns C<3> or C<4> arguments with probability C<1/2> ; and
 102
 103     sub double {
 104      return simple(), simple()
 105     }
 106
 107 never returns C<1> argument but returns C<2> with probability C<1/2 * 1/2 = 1/4>, C<3> with probability C<1/2 * 1/2 + 1/2 * 1/2 = 1/2> and C<4> with probability C<1/4> too.
 108
 109 =item * If a core function may return different numbers of scalars, each kind is considered equally possible.
 110
 111 For example, C<stat> returns C<13> elements on success and C<0> on error. The according probability will then be C<< { 0 => 0.5, 13 => 0.5 } >>.
 112
 113 =item * The C<list> state is absorbing in regard of all the other ones.
 114
 115 This is just a pedantic way to say that "list + fixed length = list".
 116 That's why
 117
 118     sub listy {
 119      return 1, simple(), @_
 120     }
 121
 122 is considered as always returning an unbounded list.
 123
 124 Also, the convolution law does not behave the same when C<list> elements are involved : in the following example,
 125
 126     sub oneorlist {
 127      if (rand < 0.1) {
 128       return 1
 129      } else {
 130       return @_
 131      }
 132     }
 133
 134     sub composed {
 135      return oneorlist(), oneorlist()
 136     }
 137
 138 C<composed> returns C<2> scalars with probability C<1/2 * 1/2 = 1/4> and a C<list> with probability C<3/4>.
 139
 140 =back
 141
 142 =cut
 143
 144 BEGIN {
 145  require XSLoader;
 146  XSLoader::load(__PACKAGE__, $VERSION);
 147 }
 148
 149 sub _check_self {
 150  croak 'First argument isn\'t a valid ' . __PACKAGE__ . ' object'
 151   unless ref $_[0] and $_[0]->isa(__PACKAGE__);
 152 }
 153
 154 sub new {
 155  my $class = shift;
 156  $class = ref($class) || $class || __PACKAGE__;
 157  bless { cache => { } }, $class;
 158 }
 159
 160 sub flush {
 161  my $self = shift;
 162  _check_self($self);
 163  $self->{cache} = { };
 164  $self;
 165 }
 166
 167 sub nary {
 168  my $self = shift;
 169  my $sub  = shift;
 170
 171  $self->{cv} = [ ];
 172  return ($self->enter(svref_2object($sub)))[1];
 173 }
 174
 175 sub name ($) {
 176  local $SIG{__DIE__} = \&Carp::confess;
 177  my $n = $_[0]->name;
 178  $n eq 'null' ? substr(ppname($_[0]->targ), 3) : $n
 179 }
 180
 181 sub scale {
 182  my ($c, $r) = @_;
 183  return unless defined $r;
 184  return (ref $r) ? { map { $_ => $r->{$_} * $c } keys %$r } : { $r => $c };
 185 }
 186
 187 sub combine {
 188  reduce {{
 189   my %res;
 190   my $la = delete $a->{list};
 191   my $lb = delete $b->{list};
 192   if (defined $la || defined $lb) {
 193    $la ||= 0;
 194    $lb ||= 0;
 195    $res{list} = $la + $lb - $la * $lb;
 196   }
 197   while (my ($ka, $va) = each %$a) {
 198    $ka = int $ka;
 199    while (my ($kb, $vb) = each %$b) {
 200     my $key = $ka + int $kb;
 201     $res{$key} += $va * $vb;
 202    }
 203   }
 204   \%res
 205  }} map { (ref) ? $_ : { $_ => 1 } } grep defined, @_;
 206 }
 207
 208 sub power {
 209  my ($p, $n, $c) = @_;
 210  return unless defined $p;
 211  return { 0 => $c } unless $n;
 212  if ($n eq 'list') {
 213   my $z = delete $p->{0};
 214   return { 'list' => $c } unless $z;
 215   return { 0      => $c } if $z == 1;
 216   return { 0 => $c * $z, list => $c * (1 - $z) };
 217  }
 218  my $r = combine map { { %$p } } 1 .. $n;
 219  $r->{$_} *= $c for keys %$r;
 220  return $r;
 221 }
 222
 223 sub add {
 224  reduce {
 225   $a->{$_} += $b->{$_} for keys %$b;
 226   $a
 227  } map { (ref) ? $_ : { $_ => 1 } } grep defined, @_;
 228 }
 229
 230 my %ops;
 231
 232 $ops{$_} = 1      for scalops;
 233 $ops{$_} = 0      for qw/stub nextstate pushmark iter unstack/;
 234 $ops{$_} = 1      for qw/padsv/;
 235 $ops{$_} = 'list' for qw/padav/;
 236 $ops{$_} = 'list' for qw/padhv rv2hv/;
 237 $ops{$_} = 'list' for qw/padany/;
 238 $ops{$_} = 'list' for qw/match entereval readline/;
 239
 240 $ops{each}      = { 0 => 0.5, 2 => 0.5 };
 241 $ops{stat}      = { 0 => 0.5, 13 => 0.5 };
 242
 243 $ops{caller}    = sub { my @a = caller 0; scalar @a }->();
 244 $ops{localtime} = do { my @a = localtime; scalar @a };
 245 $ops{gmtime}    = do { my @a = gmtime; scalar @a };
 246
 247 $ops{$_} = { 0 => 0.5, 10 => 0.5 } for map "gpw$_", qw/nam uid ent/;
 248 $ops{$_} = { 0 => 0.5, 4 => 0.5 }  for map "ggr$_", qw/nam gid ent/;
 249 $ops{$_} = 'list'                  for qw/ghbyname ghbyaddr ghostent/;
 250 $ops{$_} = { 0 => 0.5, 4 => 0.5 }  for qw/gnbyname gnbyaddr gnetent/;
 251 $ops{$_} = { 0 => 0.5, 3 => 0.5 }  for qw/gpbyname gpbynumber gprotoent/;
 252 $ops{$_} = { 0 => 0.5, 4 => 0.5 }  for qw/gsbyname gsbyport gservent/;
 253
 254 sub enter {
 255  my ($self, $cv) = @_;
 256
 257  return undef, 'list' if class($cv) ne 'CV';
 258  my $op  = $cv->ROOT;
 259  my $tag = tag($op);
 260
 261  return undef, { %{$self->{cache}->{$tag}} } if exists $self->{cache}->{$tag};
 262
 263  # Anything can happen with recursion
 264  for (@{$self->{cv}}) {
 265   return undef, 'list' if $tag == tag($_->ROOT);
 266  }
 267
 268  unshift @{$self->{cv}}, $cv;
 269  my $r = add $self->inspect($op->first);
 270  shift @{$self->{cv}};
 271
 272  $r = { $r => 1 } unless ref $r;
 273  $self->{cache}->{$tag} = { %$r };
 274  return undef, $r;
 275 }
 276
 277 sub inspect {
 278  my ($self, $op) = @_;
 279
 280  my $n = name($op);
 281  diag "@ $n" if $DEBUG;
 282  return add($self->inspect_kids($op)), undef if $n eq 'return';
 283
 284  my $meth = $self->can('pp_' . $n);
 285  return $self->$meth($op) if $meth;
 286
 287  if (exists $ops{$n}) {
 288   my $l = $ops{$n};
 289   $l = { %$l } if ref $l;
 290   return undef, $l;
 291  }
 292
 293  if (class($op) eq 'LOGOP' and not null $op->first) {
 294   my @res;
 295
 296   diag "? logop\n" if $DEBUG;
 297
 298   my $op = $op->first;
 299   my ($r1, $l1) = $self->inspect($op);
 300   return $r1, $l1 if $r1 and zero $l1;
 301   my $c = count $l1;
 302
 303   $op = $op->sibling;
 304   my ($r2, $l2) = $self->inspect($op);
 305
 306   $op = $op->sibling;
 307   my ($r3, $l3);
 308   if (null $op) {
 309    # If the logop has no else branch, it can also return the *scalar* result of
 310    # the conditional
 311    $l3 = { 1 => $c };
 312   } else {
 313    ($r3, $l3) = $self->inspect($op);
 314   }
 315
 316   my $r = add $r1, scale $c / 2, add $r2, $r3;
 317   my $l = scale $c / 2, add $l2, $l3;
 318   return $r, $l
 319  }
 320
 321  return $self->inspect_kids($op);
 322 }
 323
 324 sub inspect_kids {
 325  my ($self, $op) = @_;
 326
 327  return undef, 0 unless $op->flags & OPf_KIDS;
 328
 329  $op = $op->first;
 330  return undef, 0 if null $op;
 331  if (name($op) eq 'pushmark') {
 332   $op = $op->sibling;
 333   return undef, 0 if null $op;
 334  }
 335
 336  my ($r, @l);
 337  my $c = 1;
 338  for (; not null $op; $op = $op->sibling) {
 339   my $n = name($op);
 340   if ($n eq 'nextstate') {
 341    @l  = ();
 342    next;
 343   }
 344   if ($n eq 'lineseq') {
 345    @l  = ();
 346    $op = $op->first;
 347    redo;
 348   }
 349   diag "> $n ($c)" if $DEBUG;
 350   my ($rc, $lc) = $self->inspect($op);
 351   $r = add $r, scale $c, $rc if defined $rc;
 352   if ($rc and not defined $lc) {
 353    @l = ();
 354    last;
 355   }
 356   push @l, scale $c, $lc;
 357   $c *= count $lc if defined $lc;
 358  }
 359
 360  my $l = combine @l;
 361
 362  return $r, $l;
 363 }
 364
 365 # Stolen from B::Deparse
 366
 367 sub padval { $_[0]->{cv}->[0]->PADLIST->ARRAYelt(1)->ARRAYelt($_[1]) }
 368
 369 sub gv_or_padgv {
 370  my ($self, $op) = @_;
 371  if (class($op) eq 'PADOP') {
 372   return $self->padval($op->padix)
 373  } else { # class($op) eq "SVOP"
 374   return $op->gv;
 375  }
 376 }
 377
 378 sub const_sv {
 379  my ($self, $op) = @_;
 380  my $sv = $op->sv;
 381  # the constant could be in the pad (under useithreads)
 382  $sv = $self->padval($op->targ) unless $$sv;
 383  return $sv;
 384 }
 385
 386 sub pp_entersub {
 387  my ($self, $op) = @_;
 388
 389  $op = $op->first while $op->flags & OPf_KIDS;
 390  return undef, 0 if null $op;
 391  if (name($op) eq 'pushmark') {
 392   $op = $op->sibling;
 393   return undef, 0 if null $op;
 394  }
 395
 396  my $r;
 397  my $c = 1;
 398  for (; not null $op->sibling; $op = $op->sibling) {
 399   my $n = name($op);
 400   next if $n eq 'nextstate';
 401   diag "* $n" if $DEBUG;
 402   my ($rc, $lc) = $self->inspect($op);
 403   $r = add $r, scale $c, $rc if defined $rc;
 404   if (zero $lc) {
 405    $c = 1 - count $r;
 406    return $r, $c ? { 0 => $c } : undef
 407   }
 408   $c *= count $lc;
 409  }
 410
 411  if (name($op) eq 'rv2cv') {
 412   my $n;
 413   do {
 414    $op = $op->first;
 415    my $next = $op->sibling;
 416    while (not null $next) {
 417     $op   = $next;
 418     $next = $next->sibling;
 419    }
 420    $n  = name($op)
 421   } while ($op->flags & OPf_KIDS and { map { $_ => 1 } qw/null leave/ }->{$n});
 422   return 'list', undef unless { map { $_ => 1 } qw/gv refgen/ }->{$n};
 423   local $self->{sub} = 1;
 424   my ($rc, $lc) = $self->inspect($op);
 425   return $r, scale $c, $lc;
 426  } else {
 427   # Method call ?
 428   return $r, { 'list' => $c };
 429  }
 430 }
 431
 432 sub pp_gv {
 433  my ($self, $op) = @_;
 434
 435  return $self->{sub} ? $self->enter($self->gv_or_padgv($op)->CV) : (undef, 1)
 436 }
 437
 438 sub pp_anoncode {
 439  my ($self, $op) = @_;
 440
 441  return $self->{sub} ? $self->enter($self->const_sv($op)) : (undef, 1)
 442 }
 443
 444 sub pp_goto {
 445  my ($self, $op) = @_;
 446
 447  my $n = name($op);
 448  while ($op->flags & OPf_KIDS) {
 449   my $nop = $op->first;
 450   my $nn  = name($nop);
 451   if ($nn eq 'pushmark') {
 452    $nop = $nop->sibling;
 453    $nn  = name($nop);
 454   }
 455   if ($n eq 'rv2cv' and $nn eq 'gv') {
 456    return $self->enter($self->gv_or_padgv($nop)->CV);
 457   }
 458   $op = $nop;
 459   $n  = $nn;
 460  }
 461
 462  return undef, 'list';
 463 }
 464
 465 sub pp_const {
 466  my ($self, $op) = @_;
 467
 468  return undef, 0 unless $op->isa('B::SVOP');
 469
 470  my $sv = $self->const_sv($op);
 471  my $n  = 1;
 472  my $c  = class($sv);
 473  if ($c eq 'AV') {
 474   $n = $sv->FILL + 1
 475  } elsif ($c eq 'HV') {
 476   $n = 2 * $sv->FILL
 477  }
 478
 479  return undef, $n
 480 }
 481
 482 sub pp_aslice { $_[0]->inspect($_[1]->first->sibling) }
 483
 484 sub pp_hslice;
 485 *pp_hslice = *pp_aslice{CODE};
 486
 487 sub pp_lslice { $_[0]->inspect($_[1]->first) }
 488
 489 sub pp_rv2av {
 490  my ($self, $op) = @_;
 491  $op = $op->first;
 492
 493  my ($r, $l) = $self->inspect($op);
 494  if (name($op) ne 'const') {
 495   my $c = 1 - count $r;
 496   $l = $c ? { list => $c } : 0;
 497  }
 498  return $r, $l;
 499 }
 500
 501 sub pp_aassign {
 502  my ($self, $op) = @_;
 503
 504  $op = $op->first;
 505
 506  # Can't assign to return
 507  my $l = ($self->inspect($op->sibling))[1];
 508  return undef, $l if not exists $l->{list};
 509
 510  $self->inspect($op);
 511 }
 512
 513 sub pp_leaveloop {
 514  my ($self, $op) = @_;
 515
 516  diag "* leaveloop" if $DEBUG;
 517
 518  $op = $op->first;
 519  my ($r1, $l1);
 520  if (name($op) eq 'enteriter') {
 521   ($r1, $l1) = $self->inspect($op);
 522   return $r1, $l1 if $r1 and zero $l1;
 523  }
 524
 525  $op = $op->sibling;
 526  my $r = (name($op->first) eq 'and') ? ($self->inspect($op->first->first->sibling))[0]
 527                                      : ($self->inspect($op))[0];
 528  my $c = 1 - count $r;
 529  diag "& leaveloop" if $DEBUG;
 530  return $r, $c ? { 0 => $c } : undef;
 531 }
 532
 533 sub pp_flip {
 534  my ($self, $op) = @_;
 535
 536  $op = $op->first;
 537  return $self->inspect($op) if name($op) ne 'range';
 538
 539  my ($r, $l);
 540  my $begin = $op->first;
 541  if (name($begin) eq 'const') {
 542   my $end = $begin->sibling;
 543   if (name($end) eq 'const') {
 544    $begin = $self->const_sv($begin);
 545    $end   = $self->const_sv($end);
 546    {
 547     no warnings 'numeric';
 548     $begin = int ${$begin->object_2svref};
 549     $end   = int ${$end->object_2svref};
 550    }
 551    return undef, $end - $begin + 1;
 552   } else {
 553    ($r, $l) = $self->inspect($end);
 554   }
 555  } else {
 556   ($r, $l) = $self->inspect($begin);
 557  }
 558
 559  my $c = 1 - count $r;
 560  return $r, ($l && $c) ? { 'list' => $c } : undef
 561 }
 562
 563 sub pp_grepwhile {
 564  my ($self, $op) = @_;
 565
 566  $op = $op->first;
 567  return $self->inspect($op) if name($op) ne 'grepstart';
 568  $op = $op->first->sibling;
 569
 570  my ($r2, $l2) = $self->inspect($op->sibling);
 571  return $r2, $l2 if $r2 and zero $l2;
 572  diag Dumper [ $r2, $l2 ] if $DEBUG;
 573  my $c = count $l2; # First one to happen
 574
 575  my ($r1, $l1) = $self->inspect($op);
 576  diag Dumper [ $r1, $l1 ] if $DEBUG;
 577  return (add $r2, scale $c, $r1), undef if $r1 and zero $l1 and not zero $l2;
 578  return { 'list' => 1 }, undef if list $l2;
 579
 580  $l2 = { $l2 => 1 } unless ref $l2;
 581  my $r = add $r2, scale $c,
 582                    normalize
 583                     add map { power $r1, $_, $l2->{$_} } keys %$l2;
 584  $c = 1 - count $r;
 585  return $r, $c ? { ((zero $l2) ? 0 : 'list') => $c } : undef;
 586 }
 587
 588 sub pp_mapwhile {
 589  my ($self, $op) = @_;
 590
 591  $op = $op->first;
 592  return $self->inspect($op) if name($op) ne 'mapstart';
 593  $op = $op->first->sibling;
 594
 595  my ($r2, $l2) = $self->inspect($op->sibling);
 596  return $r2, $l2 if $r2 and zero $l2;
 597  my $c = count $l2; # First one to happen
 598
 599  my ($r1, $l1) = $self->inspect($op);
 600  return (add $r2, scale $c, $r1), undef if $r1 and zero $l1 and not zero $l2;
 601  diag Dumper [ [ $r1, $l1 ], [ $r2, $l2 ] ] if $DEBUG;
 602
 603  $l2 = { $l2 => 1 } unless ref $l2;
 604  my $r = add $r2, scale $c,
 605                    normalize
 606                     add map { power $r1, $_, $l2->{$_} } keys %$l2;
 607  $c = 1 - count $r;
 608  my $l = scale $c, normalize add map { power $l1, $_, $l2->{$_} } keys %$l2;
 609  return $r, $l;
 610 }
 611
 612 =head1 EXPORT
 613
 614 An object-oriented module shouldn't export any function, and so does this one.
 615
 616 =head1 CAVEATS
 617
 618 The algorithm may be pessimistic (things seen as C<list> while they are of fixed length) but not optimistic (the opposite, duh).
 619
 620 C<wantarray> isn't specialized when encountered in the optree.
 621
 622 =head1 DEPENDENCIES
 623
 624 L<perl> 5.8.1.
 625
 626 L<Carp> (standard since perl 5), L<B> (since perl 5.005), L<XSLoader> (since perl 5.006) and L<List::Util> (since perl 5.007003).
 627
 628 =head1 AUTHOR
 629
 630 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 631
 632 You can contact me by mail or on #perl @ FreeNode (vincent or Prof_Vince).
 633
 634 =head1 BUGS
 635
 636 Please report any bugs or feature requests to C<bug-b-nary at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Sub-Nary>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 637
 638 =head1 SUPPORT
 639
 640 You can find documentation for this module with the perldoc command.
 641
 642     perldoc Sub::Nary
 643
 644 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Sub-Nary>.
 645
 646 =head1 ACKNOWLEDGEMENTS
 647
 648 Thanks to Sebastien Aperghis-Tramoni for helping to name this module.
 649
 650 =head1 COPYRIGHT & LICENSE
 651
 652 Copyright 2008 Vincent Pit, all rights reserved.
 653
 654 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 655
 656 =cut
 657
 658 1; # End of Sub::Nary