lib/Sub/Nary.pm

   1 package Sub::Nary;
   2
   3 use 5.008001;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp qw/croak/;
   9 use List::Util qw/reduce sum/;
  10
  11 use B qw/class ppname svref_2object OPf_KIDS/;
  12
  13 =head1 NAME
  14
  15 Sub::Nary - Try to count how many elements a subroutine can return in list context.
  16
  17 =head1 VERSION
  18
  19 Version 0.01
  20
  21 =cut
  22
  23 our $VERSION;
  24 BEGIN {
  25  $VERSION  = '0.01';
  26 }
  27
  28 =head1 SYNOPSIS
  29
  30     use Sub::Nary;
  31
  32     my $sn = Sub::Nary->new();
  33     my $r  = $sn->nary(\&hlagh);
  34
  35 =head1 DESCRIPTION
  36
  37 This module uses the L<B> framework to walk into subroutines and try to guess how many scalars are likely to be returned in list context. It's not always possible to give a definitive answer to this question at compile time, so the results are given in terms of "probability of return" (to be understood in a sense described below).
  38
  39 =head1 METHODS
  40
  41 =head2 C<new>
  42
  43 The usual constructor. Currently takes no argument.
  44
  45 =head2 C<nary $coderef>
  46
  47 Takes a code reference to a named or anonymous subroutine, and returns a hash reference whose keys are the possible numbers of returning scalars, and the corresponding values the "probability" to get them. The special key C<'list'> is used to denote a possibly infinite number of returned arguments. The return value hence would look at
  48
  49     { 1 => 0.2, 2 => 0.4, 4 => 0.3, list => 0.1 }
  50
  51 that is, we should get C<1> scalar C<1> time over C<5> and so on. The sum of all values is C<1>. The returned result, and all the results obtained from intermediate subs, are cached into the object.
  52
  53 =head2 C<flush>
  54
  55 Flushes the L<Sub::Nary> object cache. Returns the object itself.
  56
  57 =head1 PROBABILITY OF RETURN
  58
  59 The probability is computed as such :
  60
  61 =over 4
  62
  63 =item * All the returning points in the same subroutine (i.e. all the explicit C<return> and the last computed value) are considered equally possible.
  64
  65 For example, the subroutine
  66
  67     sub simple {
  68      if (rand < 0.1) {
  69       return 1;
  70      } else {
  71       return 2, 3;
  72      }
  73     }
  74
  75 is seen returning one or two arguments each with probability C<1/2>.
  76 As for
  77
  78     sub hlagh {
  79      my $x = rand;
  80      if ($x < 0.1) {
  81       return 1, 2, 3;
  82      } elsif ($x > 0.9) {
  83       return 4, 5;
  84      }
  85     }
  86
  87 it is considered to return C<1> (when the two tests fail, the last computed value is returned, which here is C<< $x > 0.9 >> evaluated in the scalar context of the test), C<2> or C<3> arguments each with probability C<1/3>.
  88
  89 =item * The total probability law for a given returning point is the convolution product of the probabilities of its list elements.
  90
  91 As such,
  92
  93     sub notsosimple {
  94      return 1, simple(), 2
  95     }
  96
  97 returns C<3> or C<4> arguments with probability C<1/2> ; and
  98
  99     sub double {
 100      return simple(), simple()
 101     }
 102
 103 never returns C<1> argument but returns C<2> with probability C<1/2 * 1/2 = 1/4>, C<3> with probability C<1/2 * 1/2 + 1/2 * 1/2 = 1/2> and C<4> with probability C<1/4> too.
 104
 105 =item * The C<list> state is absorbing in regard of all the other ones.
 106
 107 This is just a pedantic way to say that "list + fixed length = list".
 108 That's why
 109
 110     sub listy {
 111      return 1, simple(), @_
 112     }
 113
 114 is considered as always returning an unbounded list.
 115
 116 Also, the convolution law does not behave the same when C<list> elements are involved : in the following example,
 117
 118     sub oneorlist {
 119      if (rand < 0.1) {
 120       return 1
 121      } else {
 122       return @_
 123      }
 124     }
 125
 126     sub composed {
 127      return oneorlist(), oneorlist()
 128     }
 129
 130 C<composed> returns C<2> scalars with probability C<1/2 * 1/2 = 1/4> and a C<list> with probability C<3/4>.
 131
 132 =back
 133
 134 =cut
 135
 136 BEGIN {
 137  require XSLoader;
 138  XSLoader::load(__PACKAGE__, $VERSION);
 139 }
 140
 141 sub _check_self {
 142  croak 'First argument isn\'t a valid ' . __PACKAGE__ . ' object'
 143   unless ref $_[0] and $_[0]->isa(__PACKAGE__);
 144 }
 145
 146 sub new {
 147  my $class = shift;
 148  $class = ref($class) || $class || __PACKAGE__;
 149  bless { cache => { } }, $class;
 150 }
 151
 152 sub flush {
 153  my $self = shift;
 154  _check_self($self);
 155  $self->{cache} = { };
 156  $self;
 157 }
 158
 159 sub nary {
 160  my $self = shift;
 161  my $sub  = shift;
 162
 163  $self->{cv} = [ ];
 164  return $self->enter(svref_2object($sub));
 165 }
 166
 167 sub name ($) {
 168  my $n = $_[0]->name;
 169  $n eq 'null' ? substr(ppname($_[0]->targ), 3) : $n
 170 }
 171
 172 sub combine {
 173  reduce {{
 174   my %res;
 175   my $la = delete $a->{list};
 176   my $lb = delete $b->{list};
 177   if (defined $la || defined $lb) {
 178    $la ||= 0;
 179    $lb ||= 0;
 180    $res{list} = $la + $lb - $la * $lb;
 181   }
 182   while (my ($ka, $va) = each %$a) {
 183    $ka = int $ka;
 184    while (my ($kb, $vb) = each %$b) {
 185     my $key = $ka + int $kb;
 186     $res{$key} += $va * $vb;
 187    }
 188   }
 189   \%res
 190  }} map { (ref) ? $_ : { $_ => 1 } } grep defined, @_;
 191 }
 192
 193 sub add {
 194  reduce {
 195   $a->{$_} += $b->{$_} for keys %$b;
 196   $a
 197  } map { (ref) ? $_ : { $_ => 1 } } grep defined, @_;
 198 }
 199
 200 my %ops;
 201 $ops{$_} = 1      for scalops;
 202 $ops{$_} = 0      for qw/stub nextstate/;
 203 $ops{$_} = 1      for qw/padsv/;
 204 $ops{$_} = 'list' for qw/padav/;
 205 $ops{$_} = 'list' for qw/padhv rv2hv/;
 206 $ops{$_} = 'list' for qw/padany flip match entereval readline/;
 207 $ops{caller}    = sub { my @a = caller 0; scalar @a }->();
 208 $ops{localtime} = do { my @a = localtime; scalar @a };
 209
 210 sub enter {
 211  my ($self, $cv) = @_;
 212
 213  return 'list' if class($cv) ne 'CV';
 214  my $op  = $cv->ROOT;
 215  my $tag = tag($op);
 216
 217  return { %{$self->{cache}->{$tag}} } if exists $self->{cache}->{$tag};
 218
 219  # Anything can happen with recursion
 220  for (@{$self->{cv}}) {
 221   return 'list' if $tag == tag($_->ROOT);
 222  }
 223
 224  unshift @{$self->{cv}}, $cv;
 225  (my $r, undef) = $self->expect_any($op->first);
 226  shift @{$self->{cv}};
 227
 228  $r = { $r => 1} unless ref $r;
 229  my $total = sum values %$r;
 230  $r = { map { $_ => $r->{$_} / $total } keys %$r };
 231  $self->{cache}->{$tag} = { %$r };
 232  return $r;
 233 }
 234
 235 sub expect_return {
 236  my ($self, $op) = @_;
 237
 238  return ($self->expect_list($op))[0] => 1 if name($op) eq 'return';
 239
 240  if ($op->flags & OPf_KIDS) {
 241   for ($op = $op->first; not null $op; $op = $op->sibling) {
 242    my ($p, $r) = $self->expect_return($op);
 243    return $p => 1 if $r;
 244   }
 245  }
 246
 247  return;
 248 }
 249
 250 sub expect_list {
 251  my ($self, $op) = @_;
 252
 253  my $n = name($op);
 254  my $meth = $self->can('pp_' . $n);
 255  return $self->$meth($op) if $meth;
 256  return $ops{$n} => 0 if exists $ops{$n};
 257
 258  if ($op->flags & OPf_KIDS) {
 259   my @res = (0);
 260   my ($p, $r);
 261   for ($op = $op->first; not null $op; $op = $op->sibling) {
 262    my $n = name($op);
 263    next if $n eq 'pushmark';
 264    if ($n eq 'nextstate'
 265        and not null(($op = $op->sibling)->sibling)) {
 266     ($p, $r) = $self->expect_return($op);
 267     return $p => 1 if $r;
 268    } else {
 269     ($p, $r) = $self->expect_any($op);
 270     return $p => 1 if $r;
 271     push @res, $p;
 272    }
 273   }
 274   return (combine @res) => 0;
 275  }
 276
 277  return;
 278 }
 279
 280 sub expect_any {
 281  my ($self, $op) = @_;
 282
 283  return ($self->expect_list($op))[0] => 1 if name($op) eq 'return';
 284
 285  if (class($op) eq 'LOGOP' and not null $op->first) {
 286   my @res;
 287   my ($p, $r);
 288
 289   my $op   = $op->first;
 290   ($p, $r) = $self->expect_return($op);
 291   return $p => 1 if $r;
 292
 293   $op = $op->sibling;
 294   push @res, ($self->expect_any($op))[0];
 295
 296   # If the logop has no else branch, it can also return the *scalar* result of
 297   # the conditional
 298   $op = $op->sibling;
 299   if (null $op) {
 300    push @res, 1;
 301   } else {
 302    push @res, ($self->expect_any($op))[0];
 303   }
 304
 305   return (add @res) => 0;
 306  }
 307
 308  return $self->expect_list($op);
 309 }
 310
 311 # Stolen from B::Deparse
 312
 313 sub padval { $_[0]->{cv}->[0]->PADLIST->ARRAYelt(1)->ARRAYelt($_[1]) }
 314
 315 sub gv_or_padgv {
 316  my ($self, $op) = @_;
 317  if (class($op) eq 'PADOP') {
 318   return $self->padval($op->padix)
 319  } else { # class($op) eq "SVOP"
 320   return $op->gv;
 321  }
 322 }
 323
 324 sub const_sv {
 325  my ($self, $op) = @_;
 326  my $sv = $op->sv;
 327  # the constant could be in the pad (under useithreads)
 328  $sv = $self->padval($op->targ) unless $$sv;
 329  return $sv;
 330 }
 331
 332 sub pp_entersub {
 333  my ($self, $op, $exp) = @_;
 334
 335  my $next = $op;
 336  while ($next->flags & OPf_KIDS) {
 337   $next = $next->first;
 338  }
 339  while (not null $next) {
 340   $op = $next;
 341   my ($p, $r) = $self->expect_return($op, $exp);
 342   return $p => 1 if $r;
 343   $next = $op->sibling;
 344  }
 345
 346  if (name($op) eq 'rv2cv') {
 347   my $n;
 348   do {
 349    $op = $op->first;
 350    my $next = $op->sibling;
 351    while (not null $next) {
 352     $op   = $next;
 353     $next = $next->sibling;
 354    }
 355    $n  = name($op)
 356   } while ($op->flags & OPf_KIDS and { map { $_ => 1 } qw/null leave/ }->{$n});
 357   return 'list' unless { map { $_ => 1 } qw/gv refgen/ }->{$n};
 358   local $self->{sub} = 1;
 359   return $self->expect_any($op, $exp);
 360  } else {
 361   # Method call ?
 362   return 'list';
 363  }
 364 }
 365
 366 sub pp_gv {
 367  my ($self, $op) = @_;
 368
 369  return $self->{sub} ? $self->enter($self->gv_or_padgv($op)->CV) : 1
 370 }
 371
 372 sub pp_anoncode {
 373  my ($self, $op) = @_;
 374
 375  return $self->{sub} ? $self->enter($self->const_sv($op)) : 1
 376 }
 377
 378 sub pp_goto {
 379  my ($self, $op) = @_;
 380
 381  my $n = name($op);
 382  while ($op->flags & OPf_KIDS) {
 383   my $nop = $op->first;
 384   my $nn  = name($nop);
 385   if ($nn eq 'pushmark') {
 386    $nop = $nop->sibling;
 387    $nn  = name($nop);
 388   }
 389   if ($n eq 'rv2cv' and $nn eq 'gv') {
 390    return $self->enter($self->gv_or_padgv($nop)->CV);
 391   }
 392   $op = $nop;
 393   $n  = $nn;
 394  }
 395
 396  return 'list';
 397 }
 398
 399 sub pp_const {
 400  my ($self, $op) = @_;
 401
 402  if (class($op) eq 'SVOP' and (my $sv = $self->const_sv($op))) {
 403   my $c = class($sv);
 404   if ($c eq 'AV') {
 405    return $sv->FILL + 1;
 406   } elsif ($c eq 'HV') {
 407    return 2 * $sv->FILL;
 408   }
 409  }
 410
 411  return 1;
 412 }
 413
 414 sub pp_aslice { $_[0]->expect_any($_[1]->first->sibling) }
 415
 416 sub pp_hslice;
 417 *pp_hslice = *pp_aslice{CODE};
 418
 419 sub pp_lslice { $_[0]->expect_any($_[1]->first) }
 420
 421 sub pp_rv2av {
 422  my ($self, $op) = @_;
 423  $op = $op->first;
 424
 425  return (name($op) eq 'const') ? $self->expect_any($op) : 'list';
 426 }
 427
 428 sub pp_aassign { $_[0]->expect_any($_[1]->first) }
 429
 430 sub pp_leaveloop { $_[0]->expect_return($_[1]->first->sibling) }
 431
 432 =head1 EXPORT
 433
 434 An object-oriented module shouldn't export any function, and so does this one.
 435
 436 =head1 CAVEATS
 437
 438 The algorithm may be pessimistic (things seen as C<list> while they are of fixed length) but not optimistic (the opposite, duh).
 439
 440 C<wantarray> isn't specialized when encountered in the optree.
 441
 442 =head1 DEPENDENCIES
 443
 444 L<perl> 5.8.1.
 445
 446 L<Carp> (standard since perl 5), L<B> (since perl 5.005), L<XSLoader> (since perl 5.006) and L<List::Util> (since perl 5.007003).
 447
 448 =head1 AUTHOR
 449
 450 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 451
 452 You can contact me by mail or on #perl @ FreeNode (vincent or Prof_Vince).
 453
 454 =head1 BUGS
 455
 456 Please report any bugs or feature requests to C<bug-b-nary at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Sub-Nary>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 457
 458 =head1 SUPPORT
 459
 460 You can find documentation for this module with the perldoc command.
 461
 462     perldoc Sub::Nary
 463
 464 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Sub-Nary>.
 465
 466 =head1 ACKNOWLEDGEMENTS
 467
 468 Thanks to Sebastien Aperghis-Tramoni for helping to name this module.
 469
 470 =head1 COPYRIGHT & LICENSE
 471
 472 Copyright 2008 Vincent Pit, all rights reserved.
 473
 474 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 475
 476 =cut
 477
 478 1; # End of Sub::Nary