lib/Sub/Nary.pm

   1 package Sub::Nary;
   2
   3 use 5.008001;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp qw/croak/;
   9 use List::Util qw/reduce/;
  10
  11 use B qw/class ppname svref_2object OPf_KIDS/;
  12
  13 use Test::More; use Data::Dumper;
  14
  15 =head1 NAME
  16
  17 Sub::Nary - Try to count how many elements a subroutine can return in list context.
  18
  19 =head1 VERSION
  20
  21 Version 0.02
  22
  23 =cut
  24
  25 our $VERSION;
  26 BEGIN {
  27  $VERSION  = '0.02';
  28 }
  29
  30 our $DEBUG = 0;
  31
  32 =head1 SYNOPSIS
  33
  34     use Sub::Nary;
  35
  36     my $sn = Sub::Nary->new();
  37     my $r  = $sn->nary(\&hlagh);
  38
  39 =head1 DESCRIPTION
  40
  41 This module uses the L<B> framework to walk into subroutines and try to guess how many scalars are likely to be returned in list context. It's not always possible to give a definitive answer to this question at compile time, so the results are given in terms of "probability of return" (to be understood in a sense described below).
  42
  43 =head1 METHODS
  44
  45 =head2 C<new>
  46
  47 The usual constructor. Currently takes no argument.
  48
  49 =head2 C<nary $coderef>
  50
  51 Takes a code reference to a named or anonymous subroutine, and returns a hash reference whose keys are the possible numbers of returning scalars, and the corresponding values the "probability" to get them. The special key C<'list'> is used to denote a possibly infinite number of returned arguments. The return value hence would look at
  52
  53     { 1 => 0.2, 2 => 0.4, 4 => 0.3, list => 0.1 }
  54
  55 that is, we should get C<1> scalar C<1> time over C<5> and so on. The sum of all values is C<1>. The returned result, and all the results obtained from intermediate subs, are cached into the object.
  56
  57 =head2 C<flush>
  58
  59 Flushes the L<Sub::Nary> object cache. Returns the object itself.
  60
  61 =head1 PROBABILITY OF RETURN
  62
  63 The probability is computed as such :
  64
  65 =over 4
  66
  67 =item * When branching, each branch is considered equally possible.
  68
  69 For example, the subroutine
  70
  71     sub simple {
  72      if (rand < 0.1) {
  73       return 1;
  74      } else {
  75       return 2, 3;
  76      }
  77     }
  78
  79 is seen returning one or two arguments each with probability C<1/2>.
  80 As for
  81
  82     sub hlagh {
  83      my $x = rand;
  84      if ($x < 0.1) {
  85       return 1, 2, 3;
  86      } elsif ($x > 0.9) {
  87       return 4, 5;
  88      }
  89     }
  90
  91 it is considered to return C<3> scalars with probability C<1/2>, C<2> with probability C<1/2 * 1/2 = 1/4> and C<1> (when the two tests fail, the last computed value is returned, which here is C<< $x > 0.9 >> evaluated in the scalar context of the test) with remaining probability C<1/4>.
  92
  93 =item * The total probability law for a given returning point is the convolution product of the probabilities of its list elements.
  94
  95 As such,
  96
  97     sub notsosimple {
  98      return 1, simple(), 2
  99     }
 100
 101 returns C<3> or C<4> arguments with probability C<1/2> ; and
 102
 103     sub double {
 104      return simple(), simple()
 105     }
 106
 107 never returns C<1> argument but returns C<2> with probability C<1/2 * 1/2 = 1/4>, C<3> with probability C<1/2 * 1/2 + 1/2 * 1/2 = 1/2> and C<4> with probability C<1/4> too.
 108
 109 =item * If a core function may return different numbers of scalars, each kind is considered equally possible.
 110
 111 For example, C<stat> returns C<13> elements on success and C<0> on error. The according probability will then be C<< { 0 => 0.5, 13 => 0.5 } >>.
 112
 113 =item * The C<list> state is absorbing in regard of all the other ones.
 114
 115 This is just a pedantic way to say that "list + fixed length = list".
 116 That's why
 117
 118     sub listy {
 119      return 1, simple(), @_
 120     }
 121
 122 is considered as always returning an unbounded list.
 123
 124 Also, the convolution law does not behave the same when C<list> elements are involved : in the following example,
 125
 126     sub oneorlist {
 127      if (rand < 0.1) {
 128       return 1
 129      } else {
 130       return @_
 131      }
 132     }
 133
 134     sub composed {
 135      return oneorlist(), oneorlist()
 136     }
 137
 138 C<composed> returns C<2> scalars with probability C<1/2 * 1/2 = 1/4> and a C<list> with probability C<3/4>.
 139
 140 =back
 141
 142 =cut
 143
 144 BEGIN {
 145  require XSLoader;
 146  XSLoader::load(__PACKAGE__, $VERSION);
 147 }
 148
 149 sub _check_self {
 150  croak 'First argument isn\'t a valid ' . __PACKAGE__ . ' object'
 151   unless ref $_[0] and $_[0]->isa(__PACKAGE__);
 152 }
 153
 154 sub new {
 155  my $class = shift;
 156  $class = ref($class) || $class || __PACKAGE__;
 157  bless { cache => { } }, $class;
 158 }
 159
 160 sub flush {
 161  my $self = shift;
 162  _check_self($self);
 163  $self->{cache} = { };
 164  $self;
 165 }
 166
 167 sub nary {
 168  my $self = shift;
 169  my $sub  = shift;
 170
 171  $self->{cv} = [ ];
 172  return ($self->enter(svref_2object($sub)))[1];
 173 }
 174
 175 sub name ($) {
 176  local $SIG{__DIE__} = \&Carp::confess;
 177  my $n = $_[0]->name;
 178  $n eq 'null' ? substr(ppname($_[0]->targ), 3) : $n
 179 }
 180
 181 sub list ($) {
 182  my $r = $_[0];
 183  return 0 unless defined $r;
 184  return $r eq 'list' unless ref $r;
 185  return $r->{list} and 1 == scalar keys %$r;
 186 }
 187
 188 sub normalize ($) {
 189  my $r = $_[0];
 190  return unless defined $r;
 191  return { 0 => 1 } unless keys %$r;
 192  my $total = count $r;
 193  return { map { $_ => $r->{$_} / $total } keys %$r };
 194 }
 195
 196 sub scale {
 197  my ($c, $r) = @_;
 198  return unless defined $r;
 199  return (ref $r) ? { map { $_ => $r->{$_} * $c } keys %$r } : { $r => $c };
 200 }
 201
 202 sub combine {
 203  reduce {{
 204   my %res;
 205   my $la = delete $a->{list};
 206   my $lb = delete $b->{list};
 207   if (defined $la || defined $lb) {
 208    $la ||= 0;
 209    $lb ||= 0;
 210    $res{list} = $la + $lb - $la * $lb;
 211   }
 212   while (my ($ka, $va) = each %$a) {
 213    $ka = int $ka;
 214    while (my ($kb, $vb) = each %$b) {
 215     my $key = $ka + int $kb;
 216     $res{$key} += $va * $vb;
 217    }
 218   }
 219   \%res
 220  }} map { (ref) ? $_ : { $_ => 1 } } grep defined, @_;
 221 }
 222
 223 sub power {
 224  my ($p, $n, $c) = @_;
 225  return unless defined $p;
 226  return { 0 => $c } unless $n;
 227  if ($n eq 'list') {
 228   my $z = delete $p->{0};
 229   return { 'list' => $c } unless $z;
 230   return { 0      => $c } if $z == 1;
 231   return { 0 => $c * $z, list => $c * (1 - $z) };
 232  }
 233  my $r = combine map { { %$p } } 1 .. $n;
 234  $r->{$_} *= $c for keys %$r;
 235  return $r;
 236 }
 237
 238 sub add {
 239  reduce {
 240   $a->{$_} += $b->{$_} for keys %$b;
 241   $a
 242  } map { (ref) ? $_ : { $_ => 1 } } grep defined, @_;
 243 }
 244
 245 my %ops;
 246
 247 $ops{$_} = 1      for scalops;
 248 $ops{$_} = 0      for qw/stub nextstate pushmark iter unstack/;
 249 $ops{$_} = 1      for qw/padsv/;
 250 $ops{$_} = 'list' for qw/padav/;
 251 $ops{$_} = 'list' for qw/padhv rv2hv/;
 252 $ops{$_} = 'list' for qw/padany/;
 253 $ops{$_} = 'list' for qw/match entereval readline/;
 254
 255 $ops{each}      = { 0 => 0.5, 2 => 0.5 };
 256 $ops{stat}      = { 0 => 0.5, 13 => 0.5 };
 257
 258 $ops{caller}    = sub { my @a = caller 0; scalar @a }->();
 259 $ops{localtime} = do { my @a = localtime; scalar @a };
 260 $ops{gmtime}    = do { my @a = gmtime; scalar @a };
 261
 262 $ops{$_} = { 0 => 0.5, 10 => 0.5 } for map "gpw$_", qw/nam uid ent/;
 263 $ops{$_} = { 0 => 0.5, 4 => 0.5 }  for map "ggr$_", qw/nam gid ent/;
 264 $ops{$_} = 'list'                  for qw/ghbyname ghbyaddr ghostent/;
 265 $ops{$_} = { 0 => 0.5, 4 => 0.5 }  for qw/gnbyname gnbyaddr gnetent/;
 266 $ops{$_} = { 0 => 0.5, 3 => 0.5 }  for qw/gpbyname gpbynumber gprotoent/;
 267 $ops{$_} = { 0 => 0.5, 4 => 0.5 }  for qw/gsbyname gsbyport gservent/;
 268
 269 sub enter {
 270  my ($self, $cv) = @_;
 271
 272  return undef, 'list' if class($cv) ne 'CV';
 273  my $op  = $cv->ROOT;
 274  my $tag = tag($op);
 275
 276  return undef, { %{$self->{cache}->{$tag}} } if exists $self->{cache}->{$tag};
 277
 278  # Anything can happen with recursion
 279  for (@{$self->{cv}}) {
 280   return undef, 'list' if $tag == tag($_->ROOT);
 281  }
 282
 283  unshift @{$self->{cv}}, $cv;
 284  my $r = add $self->inspect($op->first);
 285  shift @{$self->{cv}};
 286
 287  $r = { $r => 1 } unless ref $r;
 288  $self->{cache}->{$tag} = { %$r };
 289  return undef, $r;
 290 }
 291
 292 sub inspect {
 293  my ($self, $op) = @_;
 294
 295  my $n = name($op);
 296  diag "@ $n" if $DEBUG;
 297  return add($self->inspect_kids($op)), undef if $n eq 'return';
 298
 299  my $meth = $self->can('pp_' . $n);
 300  return $self->$meth($op) if $meth;
 301
 302  if (exists $ops{$n}) {
 303   my $l = $ops{$n};
 304   $l = { %$l } if ref $l;
 305   return undef, $l;
 306  }
 307
 308  if (class($op) eq 'LOGOP' and not null $op->first) {
 309   my @res;
 310
 311   diag "? logop\n" if $DEBUG;
 312
 313   my $op = $op->first;
 314   my ($r1, $l1) = $self->inspect($op);
 315   return $r1, $l1 if $r1 and zero $l1;
 316   my $c = count $l1;
 317
 318   $op = $op->sibling;
 319   my ($r2, $l2) = $self->inspect($op);
 320
 321   $op = $op->sibling;
 322   my ($r3, $l3);
 323   if (null $op) {
 324    # If the logop has no else branch, it can also return the *scalar* result of
 325    # the conditional
 326    $l3 = { 1 => $c };
 327   } else {
 328    ($r3, $l3) = $self->inspect($op);
 329   }
 330
 331   my $r = add $r1, scale $c / 2, add $r2, $r3;
 332   my $l = scale $c / 2, add $l2, $l3;
 333   return $r, $l
 334  }
 335
 336  return $self->inspect_kids($op);
 337 }
 338
 339 sub inspect_kids {
 340  my ($self, $op) = @_;
 341
 342  return undef, 0 unless $op->flags & OPf_KIDS;
 343
 344  $op = $op->first;
 345  return undef, 0 if null $op;
 346  if (name($op) eq 'pushmark') {
 347   $op = $op->sibling;
 348   return undef, 0 if null $op;
 349  }
 350
 351  my ($r, @l);
 352  my $c = 1;
 353  for (; not null $op; $op = $op->sibling) {
 354   my $n = name($op);
 355   if ($n eq 'nextstate') {
 356    @l  = ();
 357    next;
 358   }
 359   if ($n eq 'lineseq') {
 360    @l  = ();
 361    $op = $op->first;
 362    redo;
 363   }
 364   diag "> $n ($c)" if $DEBUG;
 365   my ($rc, $lc) = $self->inspect($op);
 366   $r = add $r, scale $c, $rc if defined $rc;
 367   if ($rc and not defined $lc) {
 368    @l = ();
 369    last;
 370   }
 371   push @l, scale $c, $lc;
 372   $c *= count $lc if defined $lc;
 373  }
 374
 375  my $l = combine @l;
 376
 377  return $r, $l;
 378 }
 379
 380 # Stolen from B::Deparse
 381
 382 sub padval { $_[0]->{cv}->[0]->PADLIST->ARRAYelt(1)->ARRAYelt($_[1]) }
 383
 384 sub gv_or_padgv {
 385  my ($self, $op) = @_;
 386  if (class($op) eq 'PADOP') {
 387   return $self->padval($op->padix)
 388  } else { # class($op) eq "SVOP"
 389   return $op->gv;
 390  }
 391 }
 392
 393 sub const_sv {
 394  my ($self, $op) = @_;
 395  my $sv = $op->sv;
 396  # the constant could be in the pad (under useithreads)
 397  $sv = $self->padval($op->targ) unless $$sv;
 398  return $sv;
 399 }
 400
 401 sub pp_entersub {
 402  my ($self, $op) = @_;
 403
 404  $op = $op->first while $op->flags & OPf_KIDS;
 405  return undef, 0 if null $op;
 406  if (name($op) eq 'pushmark') {
 407   $op = $op->sibling;
 408   return undef, 0 if null $op;
 409  }
 410
 411  my $r;
 412  my $c = 1;
 413  for (; not null $op->sibling; $op = $op->sibling) {
 414   my $n = name($op);
 415   next if $n eq 'nextstate';
 416   diag "* $n" if $DEBUG;
 417   my ($rc, $lc) = $self->inspect($op);
 418   $r = add $r, scale $c, $rc if defined $rc;
 419   if (zero $lc) {
 420    $c = 1 - count $r;
 421    return $r, $c ? { 0 => $c } : undef
 422   }
 423   $c *= count $lc;
 424  }
 425
 426  if (name($op) eq 'rv2cv') {
 427   my $n;
 428   do {
 429    $op = $op->first;
 430    my $next = $op->sibling;
 431    while (not null $next) {
 432     $op   = $next;
 433     $next = $next->sibling;
 434    }
 435    $n  = name($op)
 436   } while ($op->flags & OPf_KIDS and { map { $_ => 1 } qw/null leave/ }->{$n});
 437   return 'list', undef unless { map { $_ => 1 } qw/gv refgen/ }->{$n};
 438   local $self->{sub} = 1;
 439   my ($rc, $lc) = $self->inspect($op);
 440   return $r, scale $c, $lc;
 441  } else {
 442   # Method call ?
 443   return $r, { 'list' => $c };
 444  }
 445 }
 446
 447 sub pp_gv {
 448  my ($self, $op) = @_;
 449
 450  return $self->{sub} ? $self->enter($self->gv_or_padgv($op)->CV) : (undef, 1)
 451 }
 452
 453 sub pp_anoncode {
 454  my ($self, $op) = @_;
 455
 456  return $self->{sub} ? $self->enter($self->const_sv($op)) : (undef, 1)
 457 }
 458
 459 sub pp_goto {
 460  my ($self, $op) = @_;
 461
 462  my $n = name($op);
 463  while ($op->flags & OPf_KIDS) {
 464   my $nop = $op->first;
 465   my $nn  = name($nop);
 466   if ($nn eq 'pushmark') {
 467    $nop = $nop->sibling;
 468    $nn  = name($nop);
 469   }
 470   if ($n eq 'rv2cv' and $nn eq 'gv') {
 471    return $self->enter($self->gv_or_padgv($nop)->CV);
 472   }
 473   $op = $nop;
 474   $n  = $nn;
 475  }
 476
 477  return undef, 'list';
 478 }
 479
 480 sub pp_const {
 481  my ($self, $op) = @_;
 482
 483  return undef, 0 unless $op->isa('B::SVOP');
 484
 485  my $sv = $self->const_sv($op);
 486  my $n  = 1;
 487  my $c  = class($sv);
 488  if ($c eq 'AV') {
 489   $n = $sv->FILL + 1
 490  } elsif ($c eq 'HV') {
 491   $n = 2 * $sv->FILL
 492  }
 493
 494  return undef, $n
 495 }
 496
 497 sub pp_aslice { $_[0]->inspect($_[1]->first->sibling) }
 498
 499 sub pp_hslice;
 500 *pp_hslice = *pp_aslice{CODE};
 501
 502 sub pp_lslice { $_[0]->inspect($_[1]->first) }
 503
 504 sub pp_rv2av {
 505  my ($self, $op) = @_;
 506  $op = $op->first;
 507
 508  my ($r, $l) = $self->inspect($op);
 509  if (name($op) ne 'const') {
 510   my $c = 1 - count $r;
 511   $l = $c ? { list => $c } : 0;
 512  }
 513  return $r, $l;
 514 }
 515
 516 sub pp_aassign {
 517  my ($self, $op) = @_;
 518
 519  $op = $op->first;
 520
 521  # Can't assign to return
 522  my $l = ($self->inspect($op->sibling))[1];
 523  return undef, $l if not exists $l->{list};
 524
 525  $self->inspect($op);
 526 }
 527
 528 sub pp_leaveloop {
 529  my ($self, $op) = @_;
 530
 531  diag "* leaveloop" if $DEBUG;
 532
 533  $op = $op->first;
 534  my ($r1, $l1);
 535  if (name($op) eq 'enteriter') {
 536   ($r1, $l1) = $self->inspect($op);
 537   return $r1, $l1 if $r1 and zero $l1;
 538  }
 539
 540  $op = $op->sibling;
 541  my $r = (name($op->first) eq 'and') ? ($self->inspect($op->first->first->sibling))[0]
 542                                      : ($self->inspect($op))[0];
 543  my $c = 1 - count $r;
 544  diag "& leaveloop" if $DEBUG;
 545  return $r, $c ? { 0 => $c } : undef;
 546 }
 547
 548 sub pp_flip {
 549  my ($self, $op) = @_;
 550
 551  $op = $op->first;
 552  return $self->inspect($op) if name($op) ne 'range';
 553
 554  my ($r, $l);
 555  my $begin = $op->first;
 556  if (name($begin) eq 'const') {
 557   my $end = $begin->sibling;
 558   if (name($end) eq 'const') {
 559    $begin = $self->const_sv($begin);
 560    $end   = $self->const_sv($end);
 561    {
 562     no warnings 'numeric';
 563     $begin = int ${$begin->object_2svref};
 564     $end   = int ${$end->object_2svref};
 565    }
 566    return undef, $end - $begin + 1;
 567   } else {
 568    ($r, $l) = $self->inspect($end);
 569   }
 570  } else {
 571   ($r, $l) = $self->inspect($begin);
 572  }
 573
 574  my $c = 1 - count $r;
 575  return $r, ($l && $c) ? { 'list' => $c } : undef
 576 }
 577
 578 sub pp_grepwhile {
 579  my ($self, $op) = @_;
 580
 581  $op = $op->first;
 582  return $self->inspect($op) if name($op) ne 'grepstart';
 583  $op = $op->first->sibling;
 584
 585  my ($r2, $l2) = $self->inspect($op->sibling);
 586  return $r2, $l2 if $r2 and zero $l2;
 587  diag Dumper [ $r2, $l2 ] if $DEBUG;
 588  my $c = count $l2; # First one to happen
 589
 590  my ($r1, $l1) = $self->inspect($op);
 591  diag Dumper [ $r1, $l1 ] if $DEBUG;
 592  return (add $r2, scale $c, $r1), undef if $r1 and zero $l1 and not zero $l2;
 593  return { 'list' => 1 }, undef if list $l2;
 594
 595  $l2 = { $l2 => 1 } unless ref $l2;
 596  my $r = add $r2, scale $c,
 597                    normalize
 598                     add map { power $r1, $_, $l2->{$_} } keys %$l2;
 599  $c = 1 - count $r;
 600  return $r, $c ? { ((zero $l2) ? 0 : 'list') => $c } : undef;
 601 }
 602
 603 sub pp_mapwhile {
 604  my ($self, $op) = @_;
 605
 606  $op = $op->first;
 607  return $self->inspect($op) if name($op) ne 'mapstart';
 608  $op = $op->first->sibling;
 609
 610  my ($r2, $l2) = $self->inspect($op->sibling);
 611  return $r2, $l2 if $r2 and zero $l2;
 612  my $c = count $l2; # First one to happen
 613
 614  my ($r1, $l1) = $self->inspect($op);
 615  return (add $r2, scale $c, $r1), undef if $r1 and zero $l1 and not zero $l2;
 616  diag Dumper [ [ $r1, $l1 ], [ $r2, $l2 ] ] if $DEBUG;
 617
 618  $l2 = { $l2 => 1 } unless ref $l2;
 619  my $r = add $r2, scale $c,
 620                    normalize
 621                     add map { power $r1, $_, $l2->{$_} } keys %$l2;
 622  $c = 1 - count $r;
 623  my $l = scale $c, normalize add map { power $l1, $_, $l2->{$_} } keys %$l2;
 624  return $r, $l;
 625 }
 626
 627 =head1 EXPORT
 628
 629 An object-oriented module shouldn't export any function, and so does this one.
 630
 631 =head1 CAVEATS
 632
 633 The algorithm may be pessimistic (things seen as C<list> while they are of fixed length) but not optimistic (the opposite, duh).
 634
 635 C<wantarray> isn't specialized when encountered in the optree.
 636
 637 =head1 DEPENDENCIES
 638
 639 L<perl> 5.8.1.
 640
 641 L<Carp> (standard since perl 5), L<B> (since perl 5.005), L<XSLoader> (since perl 5.006) and L<List::Util> (since perl 5.007003).
 642
 643 =head1 AUTHOR
 644
 645 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 646
 647 You can contact me by mail or on #perl @ FreeNode (vincent or Prof_Vince).
 648
 649 =head1 BUGS
 650
 651 Please report any bugs or feature requests to C<bug-b-nary at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Sub-Nary>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 652
 653 =head1 SUPPORT
 654
 655 You can find documentation for this module with the perldoc command.
 656
 657     perldoc Sub::Nary
 658
 659 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Sub-Nary>.
 660
 661 =head1 ACKNOWLEDGEMENTS
 662
 663 Thanks to Sebastien Aperghis-Tramoni for helping to name this module.
 664
 665 =head1 COPYRIGHT & LICENSE
 666
 667 Copyright 2008 Vincent Pit, all rights reserved.
 668
 669 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 670
 671 =cut
 672
 673 1; # End of Sub::Nary