t/50-vrot.t

   1 #!perl -T
   2
   3 use strict;
   4 use warnings;
   5
   6 use lib 't/lib';
   7 use Test::Leaner 'no_plan';
   8
   9 use Scalar::Vec::Util qw/vrot vcopy SVU_SIZE/;
  10
  11 for ([ 1, 'offset', -1 ], [ 2, 'length', '-1' ]) {
  12  my @args  = ('1') x 4;
  13  $args[$_->[0]] = $_->[2];
  14  eval { &vrot(@args) }; my $line = __LINE__;
  15  like $@, qr/^Invalid\s+negative\s+$_->[1]\s+at\s+\Q$0\E\s+line\s+$line/;
  16 }
  17
  18 my $p = SVU_SIZE;
  19 $p = 8 if $p < 8;
  20 my $n = 3 * $p;
  21 my $q = 2;
  22
  23 *myfill = *Scalar::Vec::Util::vfill_pp;
  24 *myeq   = *Scalar::Vec::Util::veq_pp;
  25
  26 sub rst { myfill($_[0], 0, $n, 0); $_[0] = '' }
  27
  28 sub pat {
  29  (undef, my $a, my $b, my $c, my $x) = @_;
  30  $_[0] = '';
  31  myfill($_[0], 0,            $a,                  $x);
  32  myfill($_[0], $a,           $b,                  1 - $x);
  33  myfill($_[0], $a + $b,      $c,                  $x);
  34  myfill($_[0], $a + $b + $c, $n - ($a + $b + $c), 1 - $x);
  35 }
  36
  37 sub expected {
  38  (undef, my $s, my $l, my $b, my $left) = @_;
  39  unless ($l) {
  40   myfill($_[0], 0,  $s,      0);
  41   myfill($_[0], $s, $n - $s, 1);
  42   return;
  43  }
  44  my $lx = int($l / 2);
  45  my $ly = $l - $lx;
  46  $b %= $l;
  47  $_[0] = '';
  48  myfill($_[0], 0, $s, 0);
  49  if ($left) {
  50   if ($b <= $ly) {
  51    myfill($_[0], $s,            $b,            0);
  52    myfill($_[0], $s + $b,       $lx,           1);
  53    myfill($_[0], $s + $b + $lx, $l - $lx - $b, 0);
  54   } else {
  55    myfill($_[0], $s,            $b - $ly, 1);
  56    myfill($_[0], $s + $b - $ly, $ly,      0);
  57    myfill($_[0], $s + $b,       $l - $b,  1);
  58   }
  59  } else {
  60   if ($b <= $lx) {
  61    myfill($_[0], $s,            $lx - $b, 1);
  62    myfill($_[0], $s + $lx - $b, $l - $lx, 0);
  63    myfill($_[0], $s + $l  - $b, $b,       1);
  64   } else {
  65    myfill($_[0], $s,                 $ly - ($b - $lx), 0);
  66    myfill($_[0], $s + $l - $b,       $lx,              1);
  67    myfill($_[0], $s + $l + $lx - $b, $b - $lx,         0);
  68   }
  69  }
  70  myfill($_[0], $s + $l, $n - $s - $l, 1);
  71 }
  72
  73 sub prnt {
  74  (undef, my $n, my $desc) = @_;
  75  my $i = 0;
  76  my $s;
  77  $s .= vec($_[0], $i++, 1) while $i < $n;
  78  diag "$desc: $s";
  79 }
  80
  81 my ($v, $v0, $c) = ('', '') x 2;
  82
  83 sub try {
  84  my ($left) = @_;
  85  my @s = ($p - $q) .. ($p + $q);
  86  for my $s (@s) {
  87   for my $l (0 .. $n - 1) {
  88    last if $s + $l > $n;
  89    my $l2 = int($l/2);
  90    rst $v0;
  91    pat $v0, $s, $l2, $l - $l2, 0;
  92    my @b = (0, 3, 5, 7, 11, 13, 17, $l2, $l2 + 1, $l + 1);
  93    @b = do { my %seen; ++$seen{$_} for @b; sort keys %seen };
  94    for my $b (@b) {
  95     $v = $v0;
  96     expected $c, $s, $l, $b, $left;
  97     $b = -$b unless $left;
  98     vrot $v, $s, $l, $b;
  99     ok(myeq($v, 0, $c, 0, $n), "vrot $s, $l, $b") or do {
 100      diag "n = $n, s = $s, l = $l, l2 = $l2";
 101      prnt $v0, $n, 'original';
 102      prnt $v, $n,  'got     ';
 103      prnt $c, $n,  'expected';
 104     };
 105     is(length $v, length $c, "vrot $s, $l, $b length");
 106    }
 107   }
 108  }
 109 }
 110
 111 try 1;
 112 try 0;