t/40-vshift.t

   1 #!perl -T
   2
   3 use strict;
   4 use warnings;
   5
   6 use lib 't/lib';
   7 use Test::Leaner 'no_plan';
   8
   9 use Scalar::Vec::Util qw/vshift SVU_SIZE/;
  10
  11 for ([ 1, 'offset', -1 ], [ 2, 'length', '-1' ]) {
  12  my @args  = ('1') x 4;
  13  $args[$_->[0]] = $_->[2];
  14  eval { &vshift(@args) }; my $line = __LINE__;
  15  like $@, qr/^Invalid\s+negative\s+$_->[1]\s+at\s+\Q$0\E\s+line\s+$line/;
  16 }
  17
  18 my $p = SVU_SIZE;
  19 $p = 8 if $p < 8;
  20 my $n = 3 * $p;
  21 my $q = 2;
  22
  23 *myfill = *Scalar::Vec::Util::vfill_pp;
  24 *myeq   = *Scalar::Vec::Util::veq_pp;
  25
  26 sub rst { myfill($_[0], 0, $n, 0); $_[0] = '' }
  27
  28 sub pat {
  29  (undef, my $a, my $b, my $x) = @_;
  30  $_[0] = '';
  31  $x = $x ? 1 : 0;
  32  if (defined $b) {
  33   myfill($_[0], 0, $a, $x);
  34   myfill($_[0], $a, $b, 1 - $x);
  35  }
  36 }
  37
  38 sub expect {
  39  (undef, my $s, my $l, my $b, my $left, my $insert) = @_;
  40  myfill($_[0], 0, $s, 0);
  41  if ($b < $l) {
  42   if ($left) {
  43    myfill($_[0], $s,      $b,      defined $insert ? $insert : 1);
  44    myfill($_[0], $s + $b, $l - $b, 1);
  45   } else {
  46    myfill($_[0], $s,           $l - $b, 1);
  47    myfill($_[0], $s + $l - $b, $b,      defined $insert ? $insert : 1);
  48   }
  49  } else {
  50   myfill($_[0], $s, $l, defined $insert ? $insert : 1);
  51  }
  52 }
  53
  54 my ($v, $v0, $c) = ('', '') x 2;
  55
  56 sub try {
  57  my ($left, $insert) = @_;
  58  my @s = ($p - $q) .. ($p + $q);
  59  for my $s (@s) {
  60   for my $l (0 .. $n - 1) {
  61    last if $s + $l > $n;
  62    rst $v0;
  63    pat $v0, $s, $l, 0;
  64    my @b = (0);
  65    my $l2 = int($l/2);
  66    push @b, $l2 if $l2 != $l;
  67    push @b, $l + 1;
  68    for my $b (@b) {
  69     $v = $v0;
  70     rst $c;
  71     expect $c, $s, $l, $b, $left, $insert;
  72     $b = -$b unless $left;
  73     vshift $v, $s, $l => $b, $insert;
  74     my $i = defined $insert ? $insert : 'undef';
  75     ok(myeq($v, 0, $c, 0, $n), "vshift $s, $l, $b, $i");
  76     is(length $v, length $c, "vshift $s, $l, $b, $i length");
  77    }
  78   }
  79  }
  80 }
  81
  82 try 1;
  83 try 1, 0;
  84 try 1, 1;
  85 try 0;
  86 try 0, 0;
  87 try 0, 1;