t/31-vcopy-copy.t

   1 #!perl -T
   2
   3 use strict;
   4 use warnings;
   5
   6 use lib 't/lib';
   7 use Test::Leaner 'no_plan';
   8
   9 use Scalar::Vec::Util qw<vcopy SVU_SIZE>;
  10
  11 BEGIN {
  12  *myfill = *Scalar::Vec::Util::vfill_pp;
  13  *myeq   = *Scalar::Vec::Util::veq_pp;
  14 }
  15
  16 for ([ 1, 'offset', -1 ], [ 3, 'offset', -1 ], [ 4, 'length', -1 ]) {
  17  my @args  = (~0) x 5;
  18  $args[$_->[0]] = $_->[2];
  19  local $@;
  20  eval { &vcopy(@args) };
  21  my $err  = $@;
  22  my $line = __LINE__-2;
  23  like $err, qr/^Invalid\s+negative\s+$_->[1]\s+at\s+\Q$0\E\s+line\s+$line/,
  24       "vcopy(@args) failed";
  25 }
  26
  27 my $p = SVU_SIZE;
  28 $p    = 8 if $p < 8;
  29 my $n = 3 * $p;
  30 my $q = 1;
  31
  32 sub rst {
  33  myfill $_[0], 0, $n, 0;
  34  $_[0] = '';
  35 }
  36
  37 sub pat {
  38  my (undef, $a, $b, $x) = @_;
  39  $_[0] = '';
  40  if ($b) {
  41   myfill $_[0], 0,  $a, $x;
  42   myfill $_[0], $a, $b, 1 - $x;
  43  }
  44 }
  45
  46 my ($f, $t, $c) = ('') x 3;
  47
  48 my @s = ($p - $q) .. ($p + $q);
  49 for my $s1 (@s) {
  50  for my $s2 (@s) {
  51   for my $l (0 .. $n - 1) {
  52    last if $s1 + $l > $n or $s2 + $l > $n;
  53    my $desc = "vcopy $s1, $s2, $l";
  54    pat $f, $s1, $l, 0;
  55    rst $t;
  56    pat $c, $s2, $l, 0;
  57    vcopy $f => $s1, $t => $s2, $l;
  58    is length $t, length $c,   "$desc: length";
  59    ok myeq($t, 0, $c, 0, $n), "$desc: bits";
  60   }
  61  }
  62 }