t/11-veq.t

   1 #!perl -T
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More 'no_plan';
   7
   8 use Scalar::Vec::Util qw<veq SVU_SIZE>;
   9
  10 for ([ 1, 'offset', -1 ], [ 3, 'offset', '-1' ], [ 4, 'length', -1 ]) {
  11  my @args  = ('1') x 5;
  12  $args[$_->[0]] = $_->[2];
  13  eval { &veq(@args) }; my $line = __LINE__;
  14  like $@, qr/^Invalid\s+negative\s+$_->[1]\s+at\s+\Q$0\E\s+line\s+$line/;
  15 }
  16
  17 my $p = SVU_SIZE;
  18 $p = 8 if $p < 8;
  19 my $n = 3 * $p;
  20 my $q = 1;
  21
  22 sub myfill {
  23  (undef, my $s, my $l, my $x) = @_;
  24  $x = 1 if $x;
  25  vec($_[0], $_, 1) = $x for $s .. $s + $l - 1;
  26 }
  27
  28 sub rst { myfill($_[0], 0, $n, 0) }
  29
  30 sub pat {
  31  (undef, my $a, my $b, my $x) = @_;
  32  myfill($_[0], 0, $a, $x);
  33  myfill($_[0], $a, $b, 1 - $x);
  34  myfill($_[0], $a + $b, $n - ($a + $b) , $x);
  35 }
  36
  37 my ($v1, $v2) = ('') x 2;
  38
  39 my @s = ($p - $q) .. ($p + $q);
  40 for my $s1 (@s) {
  41  for my $s2 (@s) {
  42   for my $l (0 .. $n - 1) {
  43    last if $s1 + $l > $n or $s2 + $l > $n;
  44    pat $v1, $s1, $l, 0;
  45    pat $v2, $s2, $l, 0;
  46    ok(veq($v1 => $s1, $v2 => $s2, $l), "veq $s1, $s2, $l");
  47    ok(!veq($v1 => $s1 - 1, $v2 => $s2, $l), 'not veq ' . ($s1 - 1) . ", $s2, $l") if $l > 0;
  48    ok(!veq($v1 => $s1 + 1, $v2 => $s2, $l), 'not veq ' . ($s1 + 1) . ", $s2, $l") if $l > 0;
  49   }
  50  }
  51 }