lib/Scalar/Vec/Util.pm

   1 package Scalar::Vec::Util;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Carp qw/croak/;
   7
   8 =head1 NAME
   9
  10 Scalar::Vec::Util - Utility routines for vec strings.
  11
  12 =head1 VERSION
  13
  14 Version 0.05
  15
  16 =cut
  17
  18 our $VERSION;
  19 BEGIN {
  20  $VERSION = '0.05';
  21  eval {
  22   require XSLoader;
  23   XSLoader::load(__PACKAGE__, $VERSION);
  24   1;
  25  } or do {
  26   *SVU_PP   = sub () { 1 };
  27   *SVU_SIZE = sub () { 1 };
  28   *vfill    = *vfill_pp;
  29   *vcopy    = *vcopy_pp;
  30   *veq      = *veq_pp;
  31  }
  32 }
  33
  34 =head1 SYNOPSIS
  35
  36     use Scalar::Vec::Util qw/vfill vcopy veq/;
  37
  38     my $s;
  39     vfill $s, 0, 100, 1; # Fill with 100 bits 1 starting at 0.
  40     my $t;
  41     vcopy $s, 20, $t, 10, 30; # Copy 30 bits from $s, starting at 20,
  42                               #                to $t, starting at 10.
  43     vcopy $t, 10, $t, 20, 30; # Overalapping areas DWIM.
  44     if (veq $t, 10, $t, 20, 30) { ... } # Yes, they are equal now.
  45
  46 =head1 DESCRIPTION
  47
  48 A set of utilities to manipulate bits in vec strings.
  49 Highly optimized XS routines are used when available, but straightforward pure perl replacements are also provided for platforms without a C compiler.
  50
  51 This module doesn't reimplement bit vectors.
  52 It can be used on the very same scalars that C<vec> builds, or actually on any Perl string (C<SVt_PV>).
  53
  54 =head1 CONSTANTS
  55
  56 =head2 C<SVU_PP>
  57
  58 True when pure perl fallbacks are used instead of XS functions.
  59
  60 =head2 C<SVU_SIZE>
  61
  62 Size in bits of the unit used for moves.
  63 The higher this value is, the faster the XS functions are.
  64 It's usually C<CHAR_BIT * $Config{alignbytes}>, except on non-little-endian architectures where it currently falls back to C<CHAR_BIT> (e.g. SPARC).
  65
  66 =head1 FUNCTIONS
  67
  68 =head2 C<vfill $vec, $start, $length, $bit>
  69
  70 Starting at C<$start> in C<$vec>, fills C<$length> bits with C<$bit>.
  71 Grows C<$vec> if necessary.
  72
  73 =cut
  74
  75 sub _alldef {
  76  for (@_) { return 0 unless defined }
  77  return 1;
  78 }
  79
  80 sub vfill_pp {
  81  (undef, my $s, my $l, my $x) = @_;
  82  croak "Invalid argument" unless _alldef @_;
  83  return unless $l;
  84  $x = ~0 if $x;
  85  my $SIZE = 32;
  86  my $t = int($s / $SIZE) + 1;
  87  my $u = int(($s + $l) / $SIZE);
  88  if ($SIZE * $t < $s + $l and $t <= $u) {
  89   vec($_[0], $_, 1)     = $x for $s .. $SIZE * $t - 1;
  90   vec($_[0], $_, $SIZE) = $x for $t .. $u - 1;
  91   vec($_[0], $_, 1)     = $x for $SIZE * $u .. $s + $l - 1;
  92  } else {
  93   vec($_[0], $_, 1) = $x for $s .. $s + $l - 1;
  94  }
  95 }
  96
  97 =head2 C<< vcopy $from => $from_start, $to => $to_start, $length >>
  98
  99 Copies C<$length> bits starting at C<$from_start> in C<$from> to C<$to_start> in C<$to>.
 100 If C<$from_start + $length> is too long for C<$from>, zeros are copied past C<$length>.
 101 Grows C<$to> if necessary.
 102 Doesn't need to allocate any extra memory.
 103
 104 =cut
 105
 106 sub vcopy_pp {
 107  my ($fs, $ts, $l) = @_[1, 3, 4];
 108  croak "Invalid argument" unless _alldef @_;
 109  return unless $l;
 110  my $step = $ts - $fs;
 111  if ($step <= 0) {
 112   vec($_[2], $_ + $step, 1) = vec($_[0], $_, 1) for $fs .. $fs + $l - 1;
 113  } else { # There's a risk of overwriting if $_[0] and $_[2] are the same SV.
 114   vec($_[2], $_ + $step, 1) = vec($_[0], $_, 1) for reverse $fs .. $fs + $l - 1;
 115  }
 116 }
 117
 118 =head2 C<< vshift $v, $start, $length => $bits [, $insert ] >>
 119
 120 In the area starting at C<$start> and of length C<$length> in C<$v>, shift bits C<abs $bits> positions left if C<< $bits > 0 >> and right otherwise.
 121 If C<$insert> is defined, also fills the resulting gap with ones if C<$insert> is true and zeros if it's false.
 122 Bits outside of the specified area are left untouched.
 123 Doesn't need to allocate any extra memory.
 124
 125 =cut
 126
 127 sub vshift {
 128  my ($start, $length, $bits, $insert) = @_[1 .. 4];
 129  return unless $bits;
 130  my $left = 1;
 131  if ($bits < 0) {
 132   $left = 0;
 133   $bits = -$bits;
 134  }
 135  $bits    = $length if $bits > $length;
 136  $length -= $bits;
 137  if ($left) {
 138   vcopy($_[0], $start, $_[0], $start + $bits, $length);
 139   vfill($_[0], $start, $bits, $insert) if defined $insert;
 140  } else {
 141   vcopy($_[0], $start + $bits, $_[0], $start, $length);
 142   vfill($_[0], $start + $length, $bits, $insert) if defined $insert;
 143  }
 144 }
 145
 146 =head2 C<< veq $v1 => $v1_start, $v2 => $v2_start, $length >>
 147
 148 Returns true if the C<$length> bits starting at C<$v1_start> in C<$v1> and C<$v2_start> in C<$v2> are equal, and false otherwise.
 149 If needed, C<$length> is decreased to fit inside C<$v1> and C<$v2> boundaries.
 150
 151 =cut
 152
 153 sub veq_pp {
 154  my ($s1, $s2, $l) = @_[1, 3, 4];
 155  croak "Invalid argument" unless _alldef @_;
 156  my $i = 0;
 157  while ($i < $l) {
 158   return 0 if vec($_[0], $s1 + $i, 1) != vec($_[2], $s2 + $i, 1);
 159   ++$i;
 160  }
 161  return 1;
 162 }
 163
 164 =head1 EXPORT
 165
 166 The functions L</vfill>, L</vcopy>, L</vshift> and L</veq> are only exported on request.
 167 All of them are exported by the tags C<':funcs'> and C<':all'>.
 168
 169 The constants L</SVU_PP> and L</SVU_SIZE> are also only exported on request.
 170 They are all exported by the tags C<':consts'> and C<':all'>.
 171
 172 =cut
 173
 174 use base qw/Exporter/;
 175
 176 our @EXPORT         = ();
 177 our %EXPORT_TAGS    = (
 178  'funcs'  => [ qw/vfill vcopy vshift veq/ ],
 179  'consts' => [ qw/SVU_PP SVU_SIZE/ ]
 180 );
 181 our @EXPORT_OK      = map { @$_ } values %EXPORT_TAGS;
 182 $EXPORT_TAGS{'all'} = [ @EXPORT_OK ];
 183
 184 =head1 BENCHMARKS
 185
 186 The following timings were obtained by running the C<samples/bench.pl> script.
 187 The C<_pp> entries are the pure Perl versions, whereas C<_bv> are L<Bit::Vector> versions.
 188
 189 =over 4
 190
 191 =item This is for perl 5.8.8 on a Core 2 Duo 2.66GHz machine (unit is 64 bits).
 192
 193     Filling bits at a given position :
 194                   Rate vfill_pp vfill_bv    vfill
 195     vfill_pp    80.3/s       --    -100%    -100%
 196     vfill_bv 1053399/s 1312401%       --     -11%
 197     vfill    1180792/s 1471129%      12%       --
 198
 199     Copying bits from a bit vector to a different one :
 200                  Rate vcopy_pp vcopy_bv    vcopy
 201     vcopy_pp    112/s       --    -100%    -100%
 202     vcopy_bv  62599/s   55622%       --     -89%
 203     vcopy    558491/s  497036%     792%       --
 204
 205     Moving bits in the same bit vector from a given position to a different one :
 206                  Rate vmove_pp vmove_bv    vmove
 207     vmove_pp   64.8/s       --    -100%    -100%
 208     vmove_bv  64742/s   99751%       --     -88%
 209     vmove    547980/s  845043%     746%       --
 210
 211     Testing bit equality from different positions of different bit vectors :
 212                Rate  veq_pp  veq_bv     veq
 213     veq_pp   92.7/s      --   -100%   -100%
 214     veq_bv  32777/s  35241%      --    -94%
 215     veq    505828/s 545300%   1443%      --
 216
 217 =item This is for perl 5.10.0 on a Pentium 4 3.0GHz (unit is 32 bits).
 218
 219                  Rate vfill_pp vfill_bv    vfill
 220     vfill_pp    185/s       --    -100%    -100%
 221     vfill_bv 407979/s  220068%       --     -16%
 222     vfill    486022/s  262184%      19%       --
 223
 224                  Rate vcopy_pp vcopy_bv    vcopy
 225     vcopy_pp   61.5/s       --    -100%    -100%
 226     vcopy_bv  32548/s   52853%       --     -83%
 227     vcopy    187360/s  304724%     476%       --
 228
 229                  Rate vmove_pp vmove_bv    vmove
 230     vmove_pp   63.1/s       --    -100%    -100%
 231     vmove_bv  32829/s   51933%       --     -83%
 232     vmove    188572/s  298787%     474%       --
 233
 234                Rate  veq_pp  veq_bv     veq
 235     veq_pp   34.2/s      --   -100%   -100%
 236     veq_bv  17518/s  51190%      --    -91%
 237     veq    192181/s 562591%    997%      --
 238
 239 =item This is for perl 5.10.0 on an UltraSPARC-IIi (unit is 8 bits).
 240
 241                 Rate vfill_pp    vfill vfill_bv
 242     vfill_pp  4.23/s       --    -100%    -100%
 243     vfill    30039/s  709283%       --     -17%
 244     vfill_bv 36022/s  850568%      20%       --
 245
 246                 Rate vcopy_pp vcopy_bv    vcopy
 247     vcopy_pp  2.74/s       --    -100%    -100%
 248     vcopy_bv  8146/s  297694%       --     -60%
 249     vcopy    20266/s  740740%     149%       --
 250
 251                 Rate vmove_pp vmove_bv    vmove
 252     vmove_pp  2.66/s       --    -100%    -100%
 253     vmove_bv  8274/s  311196%       --     -59%
 254     vmove    20287/s  763190%     145%       --
 255
 256               Rate  veq_pp  veq_bv     veq
 257     veq_pp  7.33/s      --   -100%   -100%
 258     veq_bv  2499/s  33978%      --    -87%
 259     veq    19675/s 268193%    687%      --
 260
 261 =back
 262
 263 =head1 CAVEATS
 264
 265 Please report architectures where we can't use the alignment as the move unit.
 266 I'll add exceptions for them.
 267
 268 =head1 DEPENDENCIES
 269
 270 L<Carp>, L<Exporter> (core modules since perl 5), L<XSLoader> (since perl 5.006).
 271
 272 =head1 SEE ALSO
 273
 274 L<Bit::Vector> gives a complete reimplementation of bit vectors.
 275
 276 =head1 AUTHOR
 277
 278 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 279
 280 You can contact me by mail or on C<irc.perl.org> (vincent).
 281
 282 =head1 BUGS
 283
 284 Please report any bugs or feature requests to C<bug-scalar-vec-util at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Scalar-Vec-Util>.
 285 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 286
 287 =head1 SUPPORT
 288
 289 You can find documentation for this module with the perldoc command.
 290
 291     perldoc Scalar::Vec::Util
 292
 293 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Scalar-Vec-Util>.
 294
 295 =head1 COPYRIGHT & LICENSE
 296
 297 Copyright 2008 Vincent Pit, all rights reserved.
 298
 299 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 300
 301 =cut
 302
 303 1; # End of Scalar::Vec::Util