t/30-functor.t

   1 #!perl -T
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More tests => 10 + 2 * 7;
   7
   8 use LaTeX::TikZ;
   9
  10 my $tikz = Tikz->formatter(
  11  format => '%d',
  12 );
  13
  14 sub check {
  15  my ($set, $desc, $exp) = @_;
  16
  17  local $Test::Builder::Level = $Test::Builder::Level + 1;
  18
  19  my ($head, $decl, $body) = eval {
  20   $tikz->render(ref $set eq 'ARRAY' ? @$set : $set);
  21  };
  22  is $@, '', "$desc: no error";
  23
  24  unless (ref $exp eq 'ARRAY') {
  25   $exp = [ split /\n/, $exp ];
  26  }
  27  unshift @$exp, '\begin{tikzpicture}';
  28  push    @$exp, '\end{tikzpicture}';
  29
  30  is_deeply $body, $exp, $desc;
  31 }
  32
  33 my $translate = eval {
  34  Tikz->functor(
  35   'LaTeX::TikZ::Set::Point' => sub {
  36    my ($functor, $set, $v) = @_;
  37
  38    $set->new(
  39     point => [
  40      $set->x + $v->x,
  41      $set->y + $v->y,
  42     ],
  43     label => $set->label,
  44     pos   => $set->pos,
  45    );
  46   },
  47  );
  48 };
  49 is $@, '', 'creating a translator doesn\'t croak';
  50
  51 my $seq = Tikz->seq(
  52                  Tikz->point,
  53                  Tikz->raw('foo'),
  54                  Tikz->point(2),
  55                  Tikz->line(-1 => 3)
  56                      ->clip(Tikz->circle(1, 1))
  57                 )
  58               ->clip(Tikz->rectangle([0, -1] => [2, 3]));
  59
  60 my $seq2 = eval {
  61  $seq->$translate(Tikz->point(-1, 1));
  62 };
  63 is $@, '', 'translating a sequence doesn\'t croak';
  64
  65 check $seq, 'the original sequence', <<'RES';
  66 \begin{scope}
  67 \clip (0cm,-1cm) rectangle (2cm,3cm) ;
  68 \draw (0cm,0cm) ;
  69 \draw foo ;
  70 \draw (2cm,0cm) ;
  71 \begin{scope}
  72 \clip (1cm,0cm) circle (1cm) ;
  73 \draw (-1cm,0cm) -- (3cm,0cm) ;
  74 \end{scope}
  75 \end{scope}
  76 RES
  77
  78 check $seq2, 'the translated sequence', <<'RES';
  79 \begin{scope}
  80 \clip (-1cm,0cm) rectangle (1cm,4cm) ;
  81 \draw (-1cm,1cm) ;
  82 \draw foo ;
  83 \draw (1cm,1cm) ;
  84 \begin{scope}
  85 \clip (0cm,1cm) circle (1cm) ;
  86 \draw (-2cm,1cm) -- (2cm,1cm) ;
  87 \end{scope}
  88 \end{scope}
  89 RES
  90
  91 my $strip = eval {
  92  Tikz->functor(
  93   '+LaTeX::TikZ::Mod' => sub { return },
  94  );
  95 };
  96 is $@, '', 'creating a stripper doesn\'t croak';
  97
  98 $_->mod(Tikz->color('red')) for $seq2->kids;
  99
 100 my $seq3 = eval {
 101  $seq2->$strip;
 102 };
 103 is $@, '', 'stripping a sequence doesn\'t croak';
 104
 105 check $seq2, 'the original sequence', <<'RES';
 106 \begin{scope} [color=red]
 107 \clip (-1cm,0cm) rectangle (1cm,4cm) ;
 108 \draw (-1cm,1cm) ;
 109 \draw foo ;
 110 \draw (1cm,1cm) ;
 111 \begin{scope}
 112 \clip (0cm,1cm) circle (1cm) ;
 113 \draw (-2cm,1cm) -- (2cm,1cm) ;
 114 \end{scope}
 115 \end{scope}
 116 RES
 117
 118 check $seq3, 'the stripped sequence', <<'RES';
 119 \draw (-1cm,1cm) ;
 120 \draw foo ;
 121 \draw (1cm,1cm) ;
 122 \draw (-2cm,1cm) -- (2cm,1cm) ;
 123 RES
 124
 125 my $special = eval {
 126  Tikz->functor(
 127   '+LaTeX::TikZ::Mod' => sub { die "mod\n" },
 128   '+LaTeX::TikZ::Set' => sub { die "set\n" },
 129  );
 130 };
 131 is $@, '', 'creating a special functor with + rules doesn\'t croak';
 132
 133 eval { $seq->$special };
 134 is $@, "set\n", 'special functor with + rules eats everything properly';
 135
 136 $special = eval {
 137  Tikz->functor(
 138   '+LaTeX::TikZ::Mod'       => sub { die "mod\n" },
 139   '+LaTeX::TikZ::Set'       => sub { die "set\n" },
 140   'LaTeX::TikZ::Set::Point' => sub { Tikz->point(7) },
 141   'LaTeX::TikZ::Set::Op'    => sub { Tikz->raw('moo') },
 142  );
 143 };
 144 is $@, '', 'creating a special functor with + and normal rules doesn\'t croak';
 145
 146 my $res = eval { Tikz->point(3, 4)->$special };
 147 is $@, '', 'special functor with + and normal rules orders its rules properly';
 148
 149 check $res, 'the result of the special functor', <<'RES';
 150 \draw (7cm,0cm) ;
 151 RES
 152
 153 $res = eval { Tikz->raw('hlagh')->$special };
 154 is $@, '',
 155       'special functor with + and normal rules orders its rules properly again';
 156
 157 check $res, 'the result of the special functor', <<'RES';
 158 \draw moo ;
 159 RES
 160
 161 $tikz = eval {
 162  Tikz->formatter(
 163   origin => [ -1, 1 ],
 164  );
 165 };
 166 is $@, '', 'creating a formatter object with an origin doesn\'t croak';
 167
 168 check $seq, 'a sequence translated by an origin', <<'RES';
 169 \begin{scope}
 170 \clip (-1cm,0cm) rectangle (1cm,4cm) ;
 171 \draw (-1cm,1cm) ;
 172 \draw foo ;
 173 \draw (1cm,1cm) ;
 174 \begin{scope}
 175 \clip (0cm,1cm) circle (1cm) ;
 176 \draw (-2cm,1cm) -- (2cm,1cm) ;
 177 \end{scope}
 178 \end{scope}
 179 RES