lib/LaTeX/TikZ/Set/Polyline.pm

   1 package LaTeX::TikZ::Set::Polyline;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 LaTeX::TikZ::Set::Polyline - A set object representing a possibly closed path composed of contiguous lines.
   9
  10 =head1 VERSION
  11
  12 Version 0.02
  13
  14 =cut
  15
  16 our $VERSION = '0.02';
  17
  18 use LaTeX::TikZ::Set::Point;
  19
  20 use LaTeX::TikZ::Interface;
  21 use LaTeX::TikZ::Functor;
  22
  23 use Any::Moose;
  24 use Any::Moose 'Util::TypeConstraints';
  25
  26 =head1 RELATIONSHIPS
  27
  28 This class consumes the L<LaTeX::TikZ::Set::Path> role, and as such implements the L</path> method.
  29
  30 =cut
  31
  32 with 'LaTeX::TikZ::Set::Path';
  33
  34 subtype 'LaTeX::TikZ::Set::Polyline::Vertices'
  35      => as 'ArrayRef[LaTeX::TikZ::Set::Point]'
  36      => where { @$_ >= 2 }
  37      => message { 'at least two LaTeX::TikZ::Set::Point objects are needed in order to build a polyline' };
  38
  39 coerce 'LaTeX::TikZ::Set::Polyline::Vertices'
  40     => from 'ArrayRef[Any]'
  41     => via { [ map LaTeX::TikZ::Set::Point->new(point => $_), @$_ ] };
  42
  43 =head1 ATTRIBUTES
  44
  45 =head2 C<points>
  46
  47 The list of the successive vertices of the path.
  48
  49 =cut
  50
  51 has '_points' => (
  52  is       => 'ro',
  53  isa      => 'LaTeX::TikZ::Set::Polyline::Vertices',
  54  init_arg => 'points',
  55  required => 1,
  56  coerce   => 1,
  57 );
  58
  59 sub points { @{$_[0]->_points} }
  60
  61 =head2 C<closed>
  62
  63 A boolean that indicates whether the path is closed or not.
  64
  65 =cut
  66
  67 has 'closed' => (
  68  is      => 'ro',
  69  isa     => 'Bool',
  70  default => 0,
  71 );
  72
  73 =head1 METHODS
  74
  75 =head2 C<path>
  76
  77 =cut
  78
  79 sub path {
  80  my $set = shift;
  81
  82  join ' -- ', map($_->path(@_), $set->points),
  83               ($set->closed ? 'cycle' : ());
  84 }
  85
  86 =head2 C<begin>
  87
  88 =cut
  89
  90 sub begin {
  91  my $set = shift;
  92
  93  my @points = $set->points;
  94  return undef unless @points;
  95
  96  $points[0]->begin;
  97 }
  98
  99 =head2 C<end>
 100
 101 =cut
 102
 103 sub end {
 104  my $set = shift;
 105
 106  my @points = $set->points;
 107  return undef unless @points;
 108
 109  $points[-1]->end;
 110 }
 111
 112 LaTeX::TikZ::Interface->register(
 113  polyline => sub {
 114   shift;
 115
 116   __PACKAGE__->new(points => \@_);
 117  },
 118  closed_polyline => sub {
 119   shift;
 120
 121   __PACKAGE__->new(points => \@_, closed => 1);
 122  },
 123 );
 124
 125 LaTeX::TikZ::Functor->default_rule(
 126  (__PACKAGE__) => sub {
 127   my ($functor, $set, @args) = @_;
 128   $set->new(
 129    points => [ map $_->$functor(@args), $set->points ],
 130    closed => $set->closed,
 131   );
 132  }
 133 );
 134
 135 __PACKAGE__->meta->make_immutable;
 136
 137 =head1 SEE ALSO
 138
 139 L<LaTeX::TikZ>, L<LaTeX::TikZ::Set::Path>.
 140
 141 =head1 AUTHOR
 142
 143 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 144
 145 You can contact me by mail or on C<irc.perl.org> (vincent).
 146
 147 =head1 BUGS
 148
 149 Please report any bugs or feature requests to C<bug-latex-tikz at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=LaTeX-TikZ>.
 150 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 151
 152 =head1 SUPPORT
 153
 154 You can find documentation for this module with the perldoc command.
 155
 156     perldoc LaTeX::TikZ
 157
 158 =head1 COPYRIGHT & LICENSE
 159
 160 Copyright 2010 Vincent Pit, all rights reserved.
 161
 162 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 163
 164 =cut
 165
 166 1; # End of LaTeX::TikZ::Set::Polyline