lib/LaTeX/TikZ/Interface.pm

   1 package LaTeX::TikZ::Interface;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 LaTeX::TikZ::Interface - LaTeX::TikZ public interface register and loader.
   9
  10 =head1 VERSION
  11
  12 Version 0.01
  13
  14 =cut
  15
  16 our $VERSION = '0.01';
  17
  18 use Sub::Name ();
  19
  20 =head1 METHODS
  21
  22 =head2 C<< register $keyword => $code >>
  23
  24 Registers C<$code> to be available with C<< Tikz->$keyword >>.
  25
  26 =cut
  27
  28 sub register {
  29  shift;
  30
  31  while (@_ >= 2) {
  32   my ($name, $code) = splice @_, 0, 2;
  33
  34   unless (defined $name and $name =~ /^[a-z_][a-z0-9_]+$/i) {
  35    require Carp;
  36    Carp::confess('Invalid interface name');
  37   }
  38
  39   if (do { no strict 'refs'; defined &{__PACKAGE__."::$name"} }) {
  40    require Carp;
  41    Carp::confess("'$name' is already defined in the interface");
  42   }
  43
  44   unless (defined $code and ref $code eq 'CODE') {
  45    require Carp;
  46    Carp::confess('Invalid code reference');
  47   }
  48
  49   Sub::Name::subname($name => $code);
  50
  51   {
  52    no strict 'refs';
  53    *{__PACKAGE__.'::'.$name} = $code;
  54   }
  55  }
  56
  57  return;
  58 }
  59
  60 =head2 C<load>
  61
  62 Load all the modules of the L<LaTeX::TikZ> official suite that register a keyword in the interface.
  63
  64 =cut
  65
  66 sub load {
  67  require LaTeX::TikZ::Formatter;      # formatter
  68  require LaTeX::TikZ::Functor;        # functor
  69
  70  require LaTeX::TikZ::Set::Raw;       # raw
  71
  72  require LaTeX::TikZ::Set::Path;      # path
  73  require LaTeX::TikZ::Set::Sequence;  # seq
  74
  75  require LaTeX::TikZ::Set::Point;     # point
  76  require LaTeX::TikZ::Set::Line;      # line
  77  require LaTeX::TikZ::Set::Polyline;  # polyline, closed_polyline
  78  require LaTeX::TikZ::Set::Rectangle; # rectangle
  79  require LaTeX::TikZ::Set::Circle;    # circle
  80  require LaTeX::TikZ::Set::Arc;       # arc
  81  require LaTeX::TikZ::Set::Arrow;     # arrow
  82
  83  require LaTeX::TikZ::Mod::Raw;       # raw_mod
  84
  85  require LaTeX::TikZ::Mod::Clip;      # clip
  86  require LaTeX::TikZ::Mod::Layer;     # layer
  87
  88  require LaTeX::TikZ::Mod::Width;     # width
  89  require LaTeX::TikZ::Mod::Color;     # color
  90  require LaTeX::TikZ::Mod::Fill;      # fill
  91  require LaTeX::TikZ::Mod::Pattern;   # pattern
  92 }
  93
  94 =head1 AUTHOR
  95
  96 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
  97
  98 You can contact me by mail or on C<irc.perl.org> (vincent).
  99
 100 =head1 BUGS
 101
 102 Please report any bugs or feature requests to C<bug-latex-tikz at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=LaTeX-TikZ>.
 103 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 104
 105 =head1 SUPPORT
 106
 107 You can find documentation for this module with the perldoc command.
 108
 109     perldoc LaTeX::TikZ
 110
 111 =head1 COPYRIGHT & LICENSE
 112
 113 Copyright 2010 Vincent Pit, all rights reserved.
 114
 115 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 116
 117 =cut
 118
 119 1; # End of LaTeX::TikZ::Interface