lib/LaTeX/TikZ/Interface.pm

   1 package LaTeX::TikZ::Interface;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 LaTeX::TikZ::Interface - LaTeX::TikZ public interface register and loader.
   9
  10 =head1 VERSION
  11
  12 Version 0.02
  13
  14 =cut
  15
  16 our $VERSION = '0.02';
  17
  18 use Sub::Name ();
  19
  20 =head1 METHODS
  21
  22 =head2 C<register>
  23
  24     LaTeX::Tikz::Interface->register($keyword => $code)
  25
  26 Registers C<$code> to be available with C<< Tikz->$keyword >>.
  27
  28 =cut
  29
  30 sub register {
  31  shift;
  32
  33  while (@_ >= 2) {
  34   my ($name, $code) = splice @_, 0, 2;
  35
  36   unless (defined $name and $name =~ /^[a-z_][a-z0-9_]+$/i) {
  37    require Carp;
  38    Carp::confess('Invalid interface name');
  39   }
  40
  41   if (do { no strict 'refs'; defined &{__PACKAGE__."::$name"} }) {
  42    require Carp;
  43    Carp::confess("'$name' is already defined in the interface");
  44   }
  45
  46   unless (defined $code and ref $code eq 'CODE') {
  47    require Carp;
  48    Carp::confess('Invalid code reference');
  49   }
  50
  51   Sub::Name::subname($name => $code);
  52
  53   {
  54    no strict 'refs';
  55    *{__PACKAGE__.'::'.$name} = $code;
  56   }
  57  }
  58
  59  return;
  60 }
  61
  62 =head2 C<load>
  63
  64 Load all the modules of the L<LaTeX::TikZ> official suite that register a keyword in the interface.
  65
  66 =cut
  67
  68 sub load {
  69  require LaTeX::TikZ::Formatter;      # formatter
  70  require LaTeX::TikZ::Functor;        # functor
  71
  72  require LaTeX::TikZ::Set::Raw;       # raw
  73
  74  require LaTeX::TikZ::Set::Union;     # union
  75  require LaTeX::TikZ::Set::Sequence;  # seq
  76  require LaTeX::TikZ::Set::Chain;     # chain, join
  77
  78  require LaTeX::TikZ::Set::Point;     # point
  79  require LaTeX::TikZ::Set::Line;      # line
  80  require LaTeX::TikZ::Set::Polyline;  # polyline, closed_polyline
  81  require LaTeX::TikZ::Set::Rectangle; # rectangle
  82  require LaTeX::TikZ::Set::Circle;    # circle
  83  require LaTeX::TikZ::Set::Arc;       # arc
  84  require LaTeX::TikZ::Set::Arrow;     # arrow
  85
  86  require LaTeX::TikZ::Mod::Raw;       # raw_mod
  87
  88  require LaTeX::TikZ::Mod::Clip;      # clip
  89  require LaTeX::TikZ::Mod::Layer;     # layer
  90
  91  require LaTeX::TikZ::Mod::Scale;     # scale
  92  require LaTeX::TikZ::Mod::Width;     # width
  93  require LaTeX::TikZ::Mod::Color;     # color
  94  require LaTeX::TikZ::Mod::Fill;      # fill
  95  require LaTeX::TikZ::Mod::Pattern;   # pattern
  96 }
  97
  98 =head1 SEE ALSO
  99
 100 L<LaTeX::TikZ>.
 101
 102 =head1 AUTHOR
 103
 104 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 105
 106 You can contact me by mail or on C<irc.perl.org> (vincent).
 107
 108 =head1 BUGS
 109
 110 Please report any bugs or feature requests to C<bug-latex-tikz at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=LaTeX-TikZ>.
 111 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 112
 113 =head1 SUPPORT
 114
 115 You can find documentation for this module with the perldoc command.
 116
 117     perldoc LaTeX::TikZ
 118
 119 =head1 COPYRIGHT & LICENSE
 120
 121 Copyright 2010,2011,2012,2013,2014,2015 Vincent Pit, all rights reserved.
 122
 123 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 124
 125 =cut
 126
 127 1; # End of LaTeX::TikZ::Interface