lib/LaTeX/TikZ/Functor.pm

   1 package LaTeX::TikZ::Functor;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 LaTeX::TikZ::Functor - Build functor methods that recursively visit nodes of a LaTeX::TikZ::Set tree.
   9
  10 =head1 VERSION
  11
  12 Version 0.01
  13
  14 =cut
  15
  16 our $VERSION = '0.01';
  17
  18 =head1 DESCRIPTION
  19
  20 A functor takes a L<LaTeX::TikZ::Set> tree and clones it according to certain rules.
  21
  22 =cut
  23
  24 use Carp ();
  25
  26 use Sub::Name ();
  27
  28 use LaTeX::TikZ::Interface;
  29
  30 use LaTeX::TikZ::Tools;
  31
  32 use Any::Moose 'Util' => [ 'does_role' ];
  33
  34 my $lts_tc = LaTeX::TikZ::Tools::type_constraint('LaTeX::TikZ::Set');
  35
  36 my @default_set_rules;
  37 my @default_mod_rules;
  38
  39 my ($validate_rule, $insert_rule);
  40 BEGIN {
  41  $validate_rule = Sub::Name::subname('validate_rule' => sub {
  42   my ($target, $handler) = @_;
  43
  44   unless (defined $target and ref $target eq ''
  45           and $target =~ /[A-Za-z][A-Za-z0-9_]*(?:::[A-Za-z][A-Za-z0-9_]*)*/) {
  46    Carp::confess("Invalid target $target");
  47   }
  48
  49   (my $pm = $target) =~ s{::}{/}g;
  50   $pm .= '.pm';
  51   require $pm;
  52
  53   my $is_set;
  54   if (does_role($target, 'LaTeX::TikZ::Set')) {
  55    $is_set = 1;
  56   } elsif (does_role($target, 'LaTeX::TikZ::Mod')) {
  57    $is_set = 0;
  58   } else {
  59    Carp::confess("Target $target is neither a set nor a mod");
  60   }
  61
  62   Carp::confess("Invalid handler for target $target")
  63                                                   unless ref $handler eq 'CODE';
  64
  65   return [ $target, $handler, $is_set ];
  66  });
  67
  68  $insert_rule = Sub::Name::subname('insert_rule' => sub {
  69   my ($rule, $list) = @_;
  70
  71   my $spec = $rule->[0];
  72   for my $i (0 .. $#$list) {
  73    my $old_spec = $list->[$i]->[0];
  74    if ($old_spec->isa($spec) or does_role($old_spec, $spec)) {
  75     splice @$list, $i, 1, $rule;
  76     return 1;
  77    }
  78   }
  79
  80   push @$list, $rule;
  81   return $#$list;
  82  });
  83 }
  84
  85 =head1 METHODS
  86
  87 =head2 C<default_rule>
  88
  89 =cut
  90
  91 sub default_rule {
  92  shift;
  93
  94  my $rule = $validate_rule->(@_);
  95
  96  $insert_rule->($rule, $rule->[2] ? \@default_set_rules : \@default_mod_rules);
  97 }
  98
  99 =head2 C<< new rules => [ $class_name => sub { ... }, ... ] >>
 100
 101 =cut
 102
 103 sub new {
 104  my ($class, %args) = @_;
 105
 106  my @set_rules = @default_set_rules;
 107  my @mod_rules = @default_mod_rules;
 108
 109  my @user_rules = @{$args{rules} || []};
 110  while (@user_rules) {
 111   my ($target, $handler) = splice @user_rules, 0, 2;
 112
 113   my $rule = $validate_rule->($target, $handler);
 114
 115   $insert_rule->($rule, $rule->[2] ? \@set_rules : \@mod_rules);
 116  }
 117
 118  my %dispatch  = map { $_->[0] => $_ } @set_rules, @mod_rules;
 119
 120  my $self;
 121
 122  $self = bless sub {
 123   my $set = shift;
 124
 125   $lts_tc->assert_valid($set);
 126
 127   my $rule = $dispatch{ref($set)};
 128   unless ($rule) {
 129    ($set->isa($_->[0]) or $set->does($_->[0])) and $rule = $_ for @set_rules;
 130    $rule = [ undef, sub { $_[1] } ] unless $rule;
 131   }
 132   my $new_set = $rule->[1]->($self, $set, @_);
 133   my $is_new  = $new_set ne $set;
 134
 135   my @new_mods;
 136 MOD:
 137   for my $mod ($set->mods) {
 138    my $rule = $dispatch{ref($mod)};
 139    unless ($rule) {
 140     ($mod->isa($_->[0]) or $mod->does($_->[0])) and $rule = $_ for @mod_rules;
 141     unless ($rule) {
 142      push @new_mods, $mod;
 143      next MOD;
 144     }
 145    }
 146    push @new_mods, $rule->[1]->($self, $mod, @_);
 147   }
 148
 149   $new_set->mod(@new_mods) if $is_new;
 150
 151   return $new_set;
 152  }, $class;
 153 }
 154
 155 LaTeX::TikZ::Interface->register(
 156  functor => sub {
 157   shift;
 158
 159   __PACKAGE__->new(rules => \@_);
 160  },
 161 );
 162
 163 =head1 AUTHOR
 164
 165 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 166
 167 You can contact me by mail or on C<irc.perl.org> (vincent).
 168
 169 =head1 BUGS
 170
 171 Please report any bugs or feature requests to C<bug-latex-tikz at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=LaTeX-TikZ>.
 172 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 173
 174 =head1 SUPPORT
 175
 176 You can find documentation for this module with the perldoc command.
 177
 178     perldoc LaTeX::TikZ
 179
 180 =head1 COPYRIGHT & LICENSE
 181
 182 Copyright 2010 Vincent Pit, all rights reserved.
 183
 184 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 185
 186 =cut
 187
 188 1; # End of LaTeX::TikZ::Functor