lib/LaTeX/TikZ/Formatter.pm

   1 package LaTeX::TikZ::Formatter;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 LaTeX::TikZ::Formatter - LaTeX::TikZ formatter object.
   9
  10 =head1 VERSION
  11
  12 Version 0.01
  13
  14 =cut
  15
  16 our $VERSION = '0.01';
  17
  18 use Sub::Name ();
  19
  20 use LaTeX::TikZ::Tools;
  21
  22 use Any::Moose;
  23 use Any::Moose 'Util::TypeConstraints';
  24
  25 has 'unit' => (
  26  is      => 'ro',
  27  isa     => enum([ qw/cm pt/ ]),
  28  default => 'cm',
  29 );
  30
  31 has 'format' => (
  32  is      => 'ro',
  33  isa     => 'Str',
  34  default => '%s',
  35 );
  36
  37 has 'scale' => (
  38  is      => 'ro',
  39  isa     => 'Num',
  40  default => 1,
  41 );
  42
  43 has 'width' => (
  44  is  => 'ro',
  45  isa => 'Maybe[Num]',
  46 );
  47
  48 has 'height' => (
  49  is  => 'ro',
  50  isa => 'Maybe[Num]',
  51 );
  52
  53 has 'origin' => (
  54  is   => 'ro',
  55  does => 'Maybe[LaTeX::TikZ::Point]',
  56 );
  57
  58 my $find_mods;
  59 $find_mods = do {
  60  no warnings 'recursion';
  61
  62  Sub::Name::subname('find_mods' => sub {
  63   my ($set, $layers, $others) = @_;
  64
  65   if ($set->isa('LaTeX::TikZ::Set::Mod')) {
  66    for ($set->mods) {
  67     if ($_->isa('LaTeX::TikZ::Mod::Layer')) {
  68      push @$layers, $_;
  69     } else {
  70      push @$others, $_;
  71     }
  72    }
  73   }
  74
  75   my @subsets = $set->isa('LaTeX::TikZ::Set::Sequence')
  76                 ? $set->kids
  77                 : $set->isa('LaTeX::TikZ::Set::Path')
  78                   ? $set->ops
  79                   : ();
  80
  81   $find_mods->($_, $layers, $others) for @subsets;
  82  })
  83 };
  84
  85 sub render {
  86  my $tikz = shift;
  87
  88  my $seq = LaTeX::TikZ::Set::Sequence->new(
  89   kids => \@_,
  90  );
  91
  92  my (@layers, @other_mods);
  93  $find_mods->($seq, \@layers, \@other_mods);
  94
  95  my $o = $tikz->origin;
  96  $seq  = $seq->translate($o) if defined $o;
  97
  98  my $w = $tikz->width;
  99  my $h = $tikz->height;
 100  my $canvas = '';
 101  if (defined $w and defined $h) {
 102   $seq->clip(Tikz->rectangle(Tikz->point(0) => [ $w, $h ]));
 103   $_ = $tikz->len($_) for $w, $h;
 104   $canvas = ",papersize={$w,$h},body={$w,$h}";
 105  }
 106
 107  my @header = (
 108   "\\usepackage[pdftex,hcentering,vcentering$canvas]{geometry}",
 109   "\\usepackage{tikz}",
 110   "\\usetikzlibrary{patterns}",
 111  );
 112
 113  my @decls;
 114  push @decls, LaTeX::TikZ::Mod::Layer->declare(@layers) if  @layers;
 115  push @decls, $_->declare($tikz)                        for @other_mods;
 116
 117  my @content = (
 118   "\\begin{tikzpicture}",
 119   @{ $seq->draw($tikz) },
 120   "\\end{tikzpicture}",
 121  );
 122
 123  return \@header, \@decls, \@content;
 124 }
 125
 126 sub len {
 127  my ($tikz, $len) = @_;
 128
 129  $len = 0 if LaTeX::TikZ::Tools::numeq($len, 0);
 130
 131  sprintf $tikz->format . $tikz->unit, $len * $tikz->scale;
 132 }
 133
 134 sub angle {
 135  my ($tikz, $a) = @_;
 136
 137  $a = ($a * 180) / CORE::atan2(0, -1);
 138  $a += 360 if LaTeX::TikZ::Tools::numcmp($a, 0) < 0;
 139
 140  require POSIX;
 141  sprintf $tikz->format, POSIX::ceil($a);
 142 }
 143
 144 sub label {
 145  my ($tikz, $name, $pos) = @_;
 146
 147  my $scale = sprintf '%0.2f', $tikz->scale / 5;
 148
 149  "node[scale=$scale,$pos] {\$$name\$}";
 150 }
 151
 152 sub thickness {
 153  my ($tikz, $width) = @_;
 154
 155  # width=1 is 0.4 points for a scale of 2.5
 156  0.8 * $width * ($tikz->scale / 5);
 157 }
 158
 159 __PACKAGE__->meta->make_immutable;
 160
 161 =head1 AUTHOR
 162
 163 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 164
 165 You can contact me by mail or on C<irc.perl.org> (vincent).
 166
 167 =head1 BUGS
 168
 169 Please report any bugs or feature requests to C<bug-latex-tikz at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=LaTeX-TikZ>.
 170 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 171
 172 =head1 SUPPORT
 173
 174 You can find documentation for this module with the perldoc command.
 175
 176     perldoc LaTeX::TikZ
 177
 178 =head1 COPYRIGHT & LICENSE
 179
 180 Copyright 2010 Vincent Pit, all rights reserved.
 181
 182 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 183
 184 =cut
 185
 186 1; # End of LaTeX::TikZ::Formatter