lib/IPC/MorseSignals/Emitter.pm

   1 package IPC::MorseSignals::Emitter;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Carp qw/croak/;
   7 use POSIX qw/SIGUSR1 SIGUSR2/;
   8 use Time::HiRes qw/usleep/;
   9
  10 use Bit::MorseSignals::Emitter;
  11 use base qw/Bit::MorseSignals::Emitter/;
  12
  13 =head1 NAME
  14
  15 IPC::MorseSignals::Emitter - Base class for IPC::MorseSignals emitters.
  16
  17 =head1 VERSION
  18
  19 Version 0.11
  20
  21 =cut
  22
  23 our $VERSION = '0.11';
  24
  25 =head1 SYNOPSIS
  26
  27     use IPC::MorseSignals::Emitter;
  28
  29     my $deuce = new IPC::MorseSignals::Emitter speed => 1024;
  30     $deuce->post('HLAGH') for 1 .. 3;
  31     $deuce->send($pid);
  32
  33 =head1 DESCRIPTION
  34
  35 This module sends messages processed by a L<Bit::MorseSignal> emitter to another process as C<SIGUSR1> (for bits 0) and C<SIGUSR2> (for 1) signals.
  36
  37 =cut
  38
  39 sub _check_self {
  40  croak 'First argument isn\'t a valid ' . __PACKAGE__ . ' object'
  41   unless ref $_[0] and $_[0]->isa(__PACKAGE__);
  42 }
  43
  44 =head1 METHODS
  45
  46 =head2 C<< new < delay => $seconds, speed => $bauds, %bme_options > >>
  47
  48 Creates a new emitter object. C<delay> specifies the delay between two sends, in seconds, while C<speed> is the number of bits sent per second. The delay value has priority over the speed. Extra arguments are passed to L<Bit::MorseSignals::Emitter/new>.
  49
  50 =cut
  51
  52 sub new {
  53  my $class = shift;
  54  $class = ref $class || $class || return;
  55  croak 'Optional arguments must be passed as key => value pairs' if @_ % 2;
  56  my %opts = @_;
  57  # delay supersedes speed
  58  my $delay = delete $opts{delay};       # fractional seconds
  59  if (!defined $delay) {
  60   my $speed = delete $opts{speed} || 0; # bauds
  61   $speed = int $speed;
  62   $delay = abs(1 / $speed) if $speed;
  63  }
  64  my $self = $class->SUPER::new(%opts);
  65  $self->{delay} = abs($delay || 1 + 0.0);
  66  bless $self, $class;
  67 }
  68
  69 =head2 C<send $pid>
  70
  71 Sends messages enqueued with L<Bit::MorseSignals::Emitter/post> to the process C<$pid> (or to all the C<@$pid> if C<$pid> is an array reference).
  72
  73 =cut
  74
  75 sub send {
  76  my ($self, $dest) = @_;
  77  _check_self($self);
  78  return unless defined $dest;
  79  my @dests = grep $_ > 0, ref $dest eq 'ARRAY' ? map int, grep defined, @$dest
  80                                                : int $dest;
  81  while (defined(my $bit = $self->pop)) {
  82   my @sigs = (SIGUSR1, SIGUSR2);
  83   my $d = $self->{delay} * 1_000_000;
  84   $d -= usleep $d while $d > 0;
  85   kill $sigs[$bit] => @dests;
  86  }
  87  return unless @dests;
  88 }
  89
  90 =head2 C<< delay < $seconds > >>
  91
  92 Returns the current delay in seconds, or set it if an argument is provided.
  93
  94 =cut
  95
  96 sub delay {
  97  my ($self, $delay) = @_;
  98  _check_self($self);
  99  $self->{delay} = abs $delay if $delay and $delay += 0.0;
 100  return $self->{delay};
 101 }
 102
 103 =head2 C<< speed < $bauds > >>
 104
 105 Returns the current speed in bauds, or set it if an argument is provided.
 106
 107 =cut
 108
 109 sub speed {
 110  my ($self, $speed) = @_;
 111  _check_self($self);
 112  $self->{delay} = 1 / (abs $speed) if $speed and $speed = int $speed;
 113  return int(1 / $self->{delay});
 114 }
 115
 116 =pod
 117
 118 IPC::MorseSignals::Emitter objects also inherit methods from L<Bit::MorseSignals::Emitter>.
 119
 120 =head1 EXPORT
 121
 122 An object module shouldn't export any function, and so does this one.
 123
 124 =head1 DEPENDENCIES
 125
 126 L<Bit::MorseSignals::Emitter>.
 127
 128 L<Carp> (standard since perl 5), L<POSIX> (idem) and L<Time::HiRes> (since perl 5.7.3) are required.
 129
 130 =head1 SEE ALSO
 131
 132 L<IPC::MorseSignals>, L<IPC::MorseSignals::Receiver>.
 133
 134 L<Bit::MorseSignals>, L<Bit::MorseSignals::Emitter>, L<Bit::MorseSignals::Receiver>.
 135
 136 L<perlipc> for information about signals in perl.
 137
 138 For truly useful IPC, search for shared memory, pipes and semaphores.
 139
 140 =head1 AUTHOR
 141
 142 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 143
 144 You can contact me by mail or on #perl @ FreeNode (vincent or Prof_Vince).
 145
 146 =head1 BUGS
 147
 148 Please report any bugs or feature requests to C<bug-ipc-morsesignals-emitter at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=IPC-MorseSignals>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 149
 150 =head1 SUPPORT
 151
 152 You can find documentation for this module with the perldoc command.
 153
 154     perldoc IPC::MorseSignals::Emitter
 155
 156 =head1 COPYRIGHT & LICENSE
 157
 158 Copyright 2007-2008 Vincent Pit, all rights reserved.
 159
 160 This program is free software; you can redistribute it and/or modify it
 161 under the same terms as Perl itself.
 162
 163 =cut
 164
 165 1; # End of IPC::MorseSignals::Emitter