lib/CPANPLUS/Dist/Gentoo/Maps.pm

   1 package CPANPLUS::Dist::Gentoo::Maps;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 CPANPLUS::Dist::Gentoo::Maps - Map CPAN objects to Gentoo and vice versa.
   9
  10 =head1 VERSION
  11
  12 Version 0.09
  13
  14 =cut
  15
  16 our $VERSION = '0.09';
  17
  18 =head1 DESCRPITON
  19
  20 This is an helper package to L<CPANPLUS::Dist::Gentoo>.
  21
  22 =cut
  23
  24 our %gentooisms;
  25
  26 /^\s*([\w-]+)\s+([\w-]+)\s*$/ and $gentooisms{$1} = $2 while <DATA>;
  27
  28 close DATA;
  29
  30 =head1 FUNCTIONS
  31
  32 =head2 C<name_c2g $name>
  33
  34 Maps a CPAN distribution name to its Gentoo counterpart.
  35
  36 =cut
  37
  38 sub name_c2g {
  39  my ($name) = @_;
  40  return $gentooisms{$name} || $name;
  41 }
  42
  43 =head2 C<license_c2g @licenses>
  44
  45 Maps F<META.yml> C<license> tag values to the corresponding list of Gentoo licenses identifiers.
  46 Duplicates are stripped off.
  47
  48 The included data was gathered from L<Module::Install> and L<Software::License>.
  49
  50 =cut
  51
  52 my %licenses = (
  53  apache     => [ 'Apache-2.0' ],
  54  artistic   => [ 'Artistic' ],
  55  artistic_2 => [ 'Artistic-2' ],
  56  bsd        => [ 'BSD' ],
  57  gpl        => [ 'GPL-1' ],
  58  gpl2       => [ 'GPL-2' ],
  59  gpl3       => [ 'GPL-3' ],
  60  lgpl       => [ 'LGPL-2.1' ],
  61  lgpl2      => [ 'LGPL-2.1' ],
  62  lgpl3      => [ 'LGPL-3' ],
  63  mit        => [ 'MIT' ],
  64  mozilla    => [ 'MPL-1.1' ],
  65  perl       => [ 'Artistic', 'GPL-2' ],
  66 );
  67
  68 sub license_c2g {
  69  my %seen;
  70  grep !$seen{$_}++, map @{$licenses{+lc} || []}, @_;
  71 }
  72
  73 =head2 C<version_c2g $version>
  74
  75 Converts a CPAN version to a Gentoo version.
  76
  77 =cut
  78
  79 sub version_c2g {
  80  my ($v) = @_;
  81
  82  return unless defined $v;
  83
  84  $v =~ y/-/_/;
  85  $v =~ y/0-9._//cd;
  86
  87  $v =~ s/^[._]*//;
  88  $v =~ s/[._]*$//;
  89  $v =~ s/([._])[._]*/$1/g;
  90
  91  ($v, my $patch, my @rest) = split /_/, $v;
  92  $v .= '_p' . $patch if defined $patch;
  93  $v .= join('.', '', @rest) if @rest;
  94
  95  return $v;
  96 }
  97
  98 =head1 SEE ALSO
  99
 100 L<CPANPLUS::Dist::Gentoo>.
 101
 102 =head1 AUTHOR
 103
 104 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 105
 106 You can contact me by mail or on C<irc.perl.org> (vincent).
 107
 108 =head1 BUGS
 109
 110 Please report any bugs or feature requests to C<bug-cpanplus-dist-gentoo at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=CPANPLUS-Dist-Gentoo>.
 111 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 112
 113 =head1 SUPPORT
 114
 115 You can find documentation for this module with the perldoc command.
 116
 117     perldoc CPANPLUS::Dist::Gentoo
 118
 119 =head1 COPYRIGHT & LICENSE
 120
 121 Copyright 2009,2010 Vincent Pit, all rights reserved.
 122
 123 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 124
 125 =cut
 126
 127 1; # End of CPANPLUS::Dist::Gentoo::Maps
 128
 129 __DATA__
 130 ANSIColor               Term-ANSIColor
 131 AcePerl                 Ace
 132 Audio-CD                Audio-CD-disc-cover
 133 CGI-Simple              Cgi-Simple
 134 Cache-Mmap              cache-mmap
 135 Class-Loader            class-loader
 136 Class-ReturnValue       class-returnvalue
 137 Config-General          config-general
 138 Convert-ASCII-Armour    convert-ascii-armour
 139 Convert-PEM             convert-pem
 140 Crypt-CBC               crypt-cbc
 141 Crypt-DES_EDE3          crypt-des-ede3
 142 Crypt-DH                crypt-dh
 143 Crypt-DSA               crypt-dsa
 144 Crypt-IDEA              crypt-idea
 145 Crypt-Primes            crypt-primes
 146 Crypt-RSA               crypt-rsa
 147 Crypt-Random            crypt-random
 148 DBIx-SearchBuilder      dbix-searchbuilder
 149 Data-Buffer             data-buffer
 150 Date-Manip              DateManip
 151 Digest                  digest-base
 152 Digest-BubbleBabble     digest-bubblebabble
 153 Digest-MD2              digest-md2
 154 ExtUtils-Depends        extutils-depends
 155 ExtUtils-PkgConfig      extutils-pkgconfig
 156 Frontier-RPC            frontier-rpc
 157 Gimp                    gimp-perl
 158 Glib                    glib-perl
 159 Gnome2-Canvas           gnome2-canvas
 160 Gnome2-GConf            gnome2-gconf
 161 Gnome2-Print            gnome2-print
 162 Gnome2-VFS              gnome2-vfs-perl
 163 Gnome2-Wnck             gnome2-wnck
 164 Gtk2                    gtk2-perl
 165 Gtk2-Ex-FormFactory     gtk2-ex-formfactory
 166 Gtk2-GladeXML           gtk2-gladexml
 167 Gtk2-Spell              gtk2-spell
 168 Gtk2-TrayIcon           gtk2-trayicon
 169 Gtk2-TrayManager        gtk2-traymanager
 170 Gtk2Fu                  gtk2-fu
 171 I18N-LangTags           i18n-langtags
 172 Image-Info              ImageInfo
 173 Image-Size              ImageSize
 174 Inline-Files            inline-files
 175 Locale-Maketext         locale-maketext
 176 Locale-Maketext-Fuzzy   locale-maketext-fuzzy
 177 Locale-Maketext-Lexicon locale-maketext-lexicon
 178 Log-Dispatch            log-dispatch
 179 Math-Pari               math-pari
 180 Module-Info             module-info
 181 NTLM                    Authen-NTLM
 182 Net-Ping                net-ping
 183 Net-SFTP                net-sftp
 184 Net-SSH-Perl            net-ssh-perl
 185 Net-Server              net-server
 186 OLE-Storage_Lite        OLE-StorageLite
 187 Ogg-Vorbis-Header       ogg-vorbis-header
 188 PathTools               File-Spec
 189 Perl-Tidy               perltidy
 190 Pod-Parser              PodParser
 191 Regexp-Common           regexp-common
 192 SDL_Perl                sdl-perl
 193 Set-Scalar              set-scalar
 194 String-CRC32            string-crc32
 195 Text-Autoformat         text-autoformat
 196 Text-Reform             text-reform
 197 Text-Template           text-template
 198 Text-Wrapper            text-wrapper
 199 Tie-EncryptedHash       tie-encryptedhash
 200 Tk                      perl-tk
 201 Wx                      wxperl
 202 YAML                    yaml
 203 gettext                 Locale-gettext
 204 txt2html                TextToHTML